diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/All In One NPC Recorder and Player.prj b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/All In One NPC Recorder and Player.prj
index 14808e62..7d409470 100644
--- a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/All In One NPC Recorder and Player.prj	
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/All In One NPC Recorder and Player.prj	
@@ -1,5 +1,5 @@
 <Project name="All In One NPC Recorder and Player" guid="4f083be4-b9ae-4962-a3aa-e9d1c7e09e56">
-	<Object name="Object" guid="d971c37c-79d7-4705-82bf-f4312af560e8" active="true">
+	<Object name="Object" guid="d971c37c-79d7-4705-82bf-f4312af560e8" active="true" description="key=00000000-0000-0000-0000-000000000000">
 		<Notecard name="!Appearance.txt" guid="b3be600d-c3d5-43dd-9fbb-e95c441f4c33">
 		</Notecard>
 		<Notecard name="!Appearance2.txt" guid="cb7435a2-5194-495a-852f-d977ae709d33">
@@ -28,6 +28,18 @@
 		</Script>
 		<Script name="NPC Recorder Script v 4.0.lsl" guid="83d1368e-2074-4b14-ac62-e2d6f3823c69">
 		</Script>
+		<Script name="NPC Recorder Script v 4.1.lsl" guid="f8bb755f-1411-4d43-aded-39aeb0031546">
+		</Script>
+		<Script name="NPC Recorder Script v 4.2.lsl" guid="247429f3-3a16-4775-ade5-98fce4d5eb47">
+		</Script>
+		<Script name="NPC Recorder Script v 4.3.lsl" guid="4270a4c6-ff41-4c4b-a44b-be773fabb190">
+		</Script>
+		<Script name="NPC Recorder Script v 4.4.lsl" guid="4db0dc60-da65-4375-b78f-99a1dcdf766a">
+		</Script>
+		<Script name="NPC Recorder Script v 4.5.lsl" guid="9f75ecf5-880f-4514-bdd8-62406fa3d138">
+		</Script>
+		<Script name="NPC Recorder Script v 4.6.lsl" guid="e5924259-8d43-4144-85f6-4f5dea58c5c2">
+		</Script>
 	</Object>
 	<Object name="Test Object" guid="add040bc-55a8-42bb-a41a-d7cde2b0ae86">
 		<Script name="Chat commands.lsl" guid="7b7ecdbf-dd55-4e2c-be27-e7047ed30aee">
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/LSLEditor fake NPC commands.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/LSLEditor fake NPC commands.lsl
index 0bd2483b..f6aed04b 100644
--- a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/LSLEditor fake NPC commands.lsl	
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/LSLEditor fake NPC commands.lsl	
@@ -4,10 +4,10 @@
 // :AUTHOR:Ferd Frederix
 // :KEYWORDS:
 // :CREATED:2013-09-08 18:27:47
-// :EDITED:2015-08-02  21:09:13
+// :EDITED:2015-09-24  13:25:15
 // :ID:27
 // :NUM:1603
-// :REV:1.3
+// :REV:1.4
 // :WORLD:OpenSim
 // :DESCRIPTION:
 // All in one NPC recorder player set of debug functions. Add these ONLY if you are compileing in LSLEditor.
@@ -79,7 +79,7 @@ osNpcRemove (key  target) {
     llSay(0,"NPC removed");
 }
 list osGetAvatarList () {
-    list lStuff = [(key) "12345000-0000-0000-0000-0000000000002", vDestPos, "Digit Gorilla"];
+    list lStuff = [(key) "12345000-0000-0000-0000-0000000000002", <1,2,3>, "Digit Gorilla"];
     return lStuff;
 }
 osMakeNotecard(string notecardName, string contents) {
@@ -132,8 +132,9 @@ osForceAttachToOtherAvatarFromInventory(key npc, string inventory, integer point
     llSay(0,"attach " + inventory  + " to " + (string) point);
 }
 
+osTeleportAgent( key avi, string name, vector dest, vector lookat) {;}
 
 // END commented code for OpenSim vs Editor environments
 //*******************************************************************//
 // comment this out, is only here for testing in LSLEditor.
-// default {}
+ default {}
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 3.3.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 3.3.lsl
index 405f947b..a38e1f6e 100644
--- a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 3.3.lsl	
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 3.3.lsl	
@@ -4,6 +4,7 @@
 // :AUTHOR:Ferd Frederix
 // :KEYWORDS:NPC, Puppeteer
 // :CREATED:2013-09-08 18:27:47
+// :EDITED:2015-09-17  08:21:19
 // :ID:27
 // :NUM:1812
 // :REV:3.3
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.1.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.1.lsl
new file mode 100644
index 00000000..27260abf
--- /dev/null
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.1.lsl	
@@ -0,0 +1,1650 @@
+// :SHOW:1
+// :CATEGORY:NPC
+// :NAME:All In One NPC Recorder and Player
+// :AUTHOR:Ferd Frederix
+// :KEYWORDS:NPC, Puppeteer
+// :CREATED:2015-08-28 23:27:03
+// :EDITED:2015-09-23  12:06:52
+// :ID:27
+// :NUM:1826
+// :REV:4.1
+// :WORLD:OpenSim
+// :DESCRIPTION:
+// All in one NPC recorder player.
+// Supports both absolute and relative paths and many new commands
+// Add animations named "Fly, Walk, Stand and Run"
+// Click Prim to use.
+// Should be worn as a HUD to record.
+// Put it on the ground and click Sensor or Start NPC when done.
+// :CODE:
+// This is Rev 4.1  09/20/2015
+
+// Revision History
+// Rev 1.1 10-2-2014 @Sit did not work.  Minor tweaks to casting for lslEditor
+// Rev 1.2 10-14-2014 @ sit had wrong type.
+// Rev 1.3 relative movement fixed for @fly
+// Rev 1.4 4-3-2014 allow anyone to use this, non owners and non group members can only start and stop.
+// Rev 1.5 5-17-2014 set sensor to auto start on reboot of sim
+// Rev 1.6 5-24-2014 move menu so you can get it by touching, removed many of the KeyValues to RAM for efficiency
+// Rev 1.7 CHANGED_REGION_START, not CHANGED_REGION_START (Opensim difference)
+// Rev 1.8 tuned up Kill NPC, added more flexible upgrader
+// Rev 1.9 Better script injection by link message// Rev 2.0 Added osSetSpeed so you can speed up or slow down an NPC.
+// Rev 2.1 No laggy sensor used exept to sit on stuff
+// Rev 2.2 Various sensor fixes
+// Rev 2.3 Sets No Sensor in menu, must be started by hand
+// Rev 2.4 - reserved for patches to 2.3 if needed
+// Rev 3.0 Refactor out into subs, not states to make command injection easier
+//            New command: @appearance=Notecardname so you can switch to a new notecard on the fly
+//            New command: @speed=1.0  which slows up  ( < 1 )  or speeds up ( > 1)
+// Rev 3.1 Commands are not interruptible by Link Message
+// Rev 3.2 Sensor patches for consistency in removing the NPC
+// Rev 3.3 Added Touch command by Neo.Cortex@hbase42/hopto/org:8002
+//         Added Menu 3 for notecard and appearance commands
+// Rev 3.4 animation timer cannot be zero or it shuts off timer tweaked
+//         solves the NPC starting up when no sensor is set.
+// Rev 3.5 fixes saving to !Path  notecard
+// Rev 3.6 08-11-2015 @delete acts like @stop. TYjhe NPC now rezzes after an @go back in where it was deleted 
+// Rev 3.7 08-11-2015 @attach command added to load an attachment from the inventory to the NPC
+// Rev 3.8 08-17-2015 process queued commands one at a time without calling ProcessNPCLine on link message
+// Rev 3.9 08-23-2011 Queued command fixes including @delete which were not always working
+// Rev 4.0 09-15-2015 Fixes for Sensor functions which continually rezzed a NPC when no one was around.
+// Rev 4.1 09-20-2015 Added a Listener so link messages are not needed
+//*******************************************************************//
+
+// Instructions on how to use this are at http://www.outworldz.com/opensim/posts/NPC/
+// This is an OpenSim-only script.
+// Author: Ferd Frederix aka Fred Beckhusen - fred@mitsi.com
+
+////////////////////////////////////////////////////////////////////////////////////////////
+//    Original code was Copyright (C) 2013 Wizardry and Steamworks - License: GNU GPLv3    //
+///////////////////////////////////////////////////////////////////////////////////////////
+//  Please see: http://www.gnu.org/licenses/gpl.html for legal details,                  //
+//  rights of fair usage, the disclaimer and warranty conditions.                        //
+///////////////////////////////////////////////////////////////////////////////////////////
+// The original NPC controller was from http://was.fm/opensim:npc
+// Extensive additions and bug fixes by Fred Beckhusen, aka Ferd Frederix
+// llSensor had two params swapped
+// @Wander would wander where it had rezzed, not where it was.
+// There was no 'no_sensor' event in sit, so if a @sit failed, the NPC got stuck
+// The animation and walks always stopped old, then started new.  It should be start new, then stop old so the default stand would be suppressed.
+// New code:
+// Merged with new Route recorder and notecard writer
+// If the NPC failed to reach a destination it never moved on.
+// Added WAIT global to tune this
+// Exposed many tunable variables and ported the code 
+// Added floating point to times in notecard.
+
+// Added @sound, @randsound, @whisper, @shout, and @cmd controls.
+//
+// notecards integers are not floats for better control
+// 
+// Link Messages may be used to perform external control by injecting @commands into the stream of actions
+// Example:
+// To chat something, such as with a chat robot
+//  llMessageLinked(LINK_SET,0,"@npc_say=Hello","");
+
+// This script assumes that NPCs and OSSl scripting is enabled in the OpenSim configuration.
+// In order to enable them, the following changes must be made in the OpenSim.ini configuration file:
+//
+// ; Turn on OSSL
+// AllowOSFunctions = true
+// OSFunctionThreatLevel = Severe
+
+//[NPC]
+//    ;# {Enabled} {} {Enable Non Player Character (NPC) facilities} {true false}
+//    Enabled = true
+//
+// and then the server has to be restarted.
+
+
+// Commands: All commands begin with an @ sign.  All other lines are ignored
+// @commands may have optional parameters.  The syntax is always:
+//  @cmd=parm1|parm2
+//  NaN in the table below meand Not a Number.   This means there is no parameter
+
+//Command     First Parameter             Second Parameter        Description
+//@spawn      name                        location (vector)       Rezzes an NPC with name at a location.
+//@appearance NoteCardName                NaN                     switch the NPC appearance to a new notecard
+//@walk       destination (vector)        NaN                     Makes the NPC walk to destination.
+//@fly        destination (vector)        NaN                     Makes the NPC fly to destination.
+//@land       destination (vector)        NaN                     Makes the NPC land at destination.
+//@say        string                      NaN                     Makes the NPC speak a phrase.
+//@whisper    string                      NaN                     Makes the NPC whisper a phrase.
+//@shout      string                      NaN                     Makes the NPC shout a phrase.
+//@pause      seconds (float)             NaN                     Makes the NPC wait for a multiple of seconds.
+//@wander     radius (float)              cycles (integer)        Makes the NPC wander in radius, for cycles seconds.
+//@delete     NaN                         NaN                     Removes the NPC.  Requires a link message to continue
+//@goto       label (string)              NaN                     Jump to the label label in the script.
+//@animate    animation (string)          time (float)            Makes the NPC trigger the animation animation for time seconds.
+//@sound      sound_name                  NaN                     plays a sound from inventory
+//@randsound  NaN                         NaN                     Plays a random sound from inventory
+//@rotate     degrees (float)             NaN                     Rotate the NPC degrees around the Z axis.
+//@sit        primitive name              NaN                     Sit on a primitive with a given name.
+//@touch      primitive name              NaN                     Touch on a primitive with a given name.
+//@stand      NaN                         NaN                     If sitting on a primitive, stand up.
+//@cmd        channel (integer)           string                  Says string on channel, for controlling external gadgets
+//@stop       NaN                         NaN                     Halts the NPC script indefinitely. Can be started with a link message
+//@go         NaN                         NaN                     Continues on next notecard line, for use in link messages
+//@speed      speed (float)               NaN                     from 0 to N, where 1.0 ius a normal speed of an avatar.  0.2 is a turtle.
+//@notecard   notename (string)           NaN                     load a new Path notecard
+//@attach     InventoryName               attachmentPoint         load an attachment from the inventory to the NPC onto point
+
+// Constant            attachmentPoint Comment
+// ATTACH_CHEST            1    chest/sternum
+// ATTACH_HEAD             2    head
+// ATTACH_LSHOULDER        3    left shoulder
+// ATTACH_RSHOULDER        4    right shoulder
+// ATTACH_LHAND            5    left hand
+// ATTACH_RHAND            6    right hand
+// ATTACH_LFOOT            7    left foot
+// ATTACH_RFOOT            8    right foot
+// ATTACH_BACK             9    back
+// ATTACH_PELVIS          10    pelvis
+// ATTACH_MOUTH           11    mouth
+// ATTACH_CHIN            12    chin
+// ATTACH_LEAR            13    left ear
+// ATTACH_REAR            14    right ear
+// ATTACH_LEYE            15    left eye
+// ATTACH_REYE            16    right eye
+// ATTACH_NOSE            17    nose
+// ATTACH_RUARM           18    right upper arm
+// ATTACH_RLARM           19    right lower arm
+// ATTACH_LUARM           20    left upper arm
+// ATTACH_LLARM           21    left lower arm
+// ATTACH_RHIP            22    right hip
+// ATTACH_RULEG           23    right upper leg
+// ATTACH_RLLEG           24    right lower leg
+// ATTACH_LHIP            25    left hip
+// ATTACH_LULEG           26    left upper leg
+// ATTACH_LLLEG           27    left lower leg
+// ATTACH_BELLY           28    belly/stomach/tummy
+// ATTACH_LEFT_PEC        29    left pectoral
+// ATTACH_RIGHT_PEC       30    right pectoral
+// ATTACH_HUD_CENTER_2    31    HUD Center 2
+// ATTACH_HUD_TOP_RIGHT   32    HUD Top Right
+// ATTACH_HUD_TOP_CENTER  33    HUD Top
+// ATTACH_HUD_TOP_LEFT    34    HUD Top Left
+// ATTACH_HUD_CENTER_1    35    HUD Center
+// ATTACH_HUD_BOTTOM_LEFT 36    HUD Bottom Left
+// ATTACH_HUD_BOTTOM      37    HUD Bottom
+// ATTACH_HUD_BOTTOM_RIGHT 38   HUD Bottom Right
+// ATTACH_NECK            39   neck
+// ATTACH_AVATAR_CENTER  40    avatar center/root
+
+
+  
+//////////////////////////////////////////////////////////
+//                  DEBUG                               //
+//////////////////////////////////////////////////////////
+integer debug = TRUE;         // set to TRUE or FALSE for debug chat on various actions
+integer LSLEditor = TRUE;        // set to to TRUE to working in  LSLEditor, FALSE for in-world.
+                              // you must also include the NPC commands found in the other script since LSLEditor does not support OpenSim
+integer iTitleText = FALSE;    // set to TRUE to see debug info in text above the controller
+ 
+//////////////////////////////////////////////////////////
+//                  TUNABLE CONFIGURATION               //
+//////////////////////////////////////////////////////////
+integer   allowListener = TRUE; // set to TRUE to anable a command listener. Usually, this is setto FALSE
+integer   link_Channel =   4223; // some random number you want to talk to this gadget on. Best if large and negative
+float     TIMER = 2;         // faster = less jerky stopping.  How often the system checks the distance traveled.  Fastest you can go is 0.5 seconds
+float     QUICK = 1;        // when we need to move to the next state, we use a QUICK timer
+string    Appearance = "!Appearance";  // The name of the recorded Appearance notecard
+string    Notecard = "!Path"; // The name of the recorded routes
+integer   allowUsers = FALSE;  // If true, any user can get a Start NPC and Stop NPC menu.  Only groups and owners can get all commands if TRUE, or FALSE
+float     MAXDIST = 2.0;       // how close a NPC has to get to a dest pos to continue to next state. Do not lower this too much, as it may miss the target
+integer   WANDERRAND = TRUE;   // set to TRUE and they will pause during wanders a random number of seconds
+float     WANDERTIME = 3.0;    // how long they stand after each @wander,if WANDERRAND is FALSE. If WANDERRAND is  TRUE, this is the max time
+integer   WAIT = 30;           // wait for this number of seconds for the NPC to reach a destination (for safety). If it fails to reach a target, it will move on after this time.
+float     RANGE = 50;        // 1 to N meters  - anyone this close to the controller will start NPCS if Sensor button is clicked
+float     REZTIME = 2.0;      // wait this long for NPC to rez in, then start the process
+string    STAND = "Stand";     // the name of the default Stand animation
+string    WALK = "Walk";       // the name of the default Walk animation
+string    FLY = "Fly";        // the name of the default Fly animation
+string    RUN = "Run";        // the name of the default Run animation
+string    LAND = "Land";      // the name of the default land animation ( for birds only)
+float     OffsetZ = 0.5;      // appear 0.5 meter above ground, this is added to all destinations to keep them from sinking in.  
+float    SPEEDMULT =0.5;     // 1.0 = regular avatar speed. Smaller numbers slow down walks. Large numbers speed them up.
+integer  FLIGHT = 299;        // For controlling wings.  A channel that is shouted at when flight starts and ends. "flying" or "landing" 
+
+// DESCRIPTIONS FIELDS HAVE TO SURVIVE A RESET
+//  These vars are stored  by saving them with KeyValueSet
+// "pr" is a 0 if it is set for Owner Only, 1 for Group control
+// "se" is "on" if Started
+// "co" = "R" or "A" for relative or absolute addressing mode
+// "key" = NPC key
+
+// These Globals used to be stored in description.   Moved to RAM in V1.6
+float RAMPause;          // @pause param
+float RAMwd ;            // @wander distance
+integer RAMwc;           // @wander count
+float RAMrot;            //  @rotate
+string RAMsit;           // @sit primname
+string RAMtouch;         // @touch primname
+string RAManimationName; // @animate animation (string) time (float)
+float RAManimationTime;
+
+// other globals section
+integer iChannel;        // a listen channel, randomly assigned
+integer iHandle;         // the handle to it
+
+// NPC controls
+vector newDest ;                // tmp storage for the walks
+integer iWaitCounter ;          // wait for this number of seconds for the NPC to reach a desrtination
+string sNPCName;                // the name of the NPC that may be in world. So we can remove it.
+integer bNPC_STOP = FALSE;      // boolean to reuse a listener
+integer Stopped = FALSE;        // set to TRUE by link messages so we do not remember them
+float  fTimerVal ;              // how long we wait when wandering (calculated)
+float NPCEnabled;               // true if the NPC is suppodes to be running
+
+// OS_NPC_CREATOR_OWNED will create an 'owned' NPC that will only respond to osNpc* commands issued from scripts that have the same owner as the one that created the NPC.
+// OS_NPC_NOT_OWNED will create an 'unowned' NPC that will respond to any script that has OSSL permissions to call osNpc* commands.
+integer  NPCOptions = OS_NPC_CREATOR_OWNED;    // only yhe owner of this box can control this NPC.
+
+integer walkstate = 0;  // helps us reshare the walk state for run, fly and land - a bit of a hack, but it saves RAM. Has to be done this way because some bits of NPCWalkOption are asserted as 0
+
+integer NPCWalkOption;   // Some notes for what happens to NPCWalkOption:
+// OS_NPC_FLY - Fly the avatar to the given position. The avatar will not land unless the OS_NPC_LAND_AT_TARGET option is also given.
+// OS_NPC_NO_FLY - Do not fly to the target. The NPC will attempt to walk to the location. If it's up in the air then the avatar will keep bouncing hopeless until another move target is given or the move is stopped
+//OS_NPC_LAND_AT_TARGET - If given and the avatar is flying, then it will land when it reaches the target. If OS_NPC_NO_FLY is given then this option has no effect.
+// OS_NPC_RUNNING - if given, NPC avatar moves at running/fast flying speed, otherwise moves at walking/slow flying speed.
+
+// menus
+string mSensor="Sense is Off";    // Sensor or "No Sensor"
+
+list lAtButtons = ["Menu","-",   ">>",         "@run",    "@walk",   "@fly",  "@land", "@wander",    "@sit",   "@stand","@animate","@rotate"];
+list lMenu2 = ["<<", "@comment", ">>>",        "@stop",      "@say",    "@whisper","@shout","@sound","@randsound","@cmd",  "@pause",  "@delete"];
+list lMenu3 = ["<<<","@notecard","@appearance", "@touch", "@speed",       "@attach",     "-","-", "-", "-", "-", "-" ];
+
+string sCommand;  // place to store a command for two-prompted ones
+string sParam2;   // place to store a prompt for two-prompted ones
+string priPub = "Owner Only";    // Private or Group
+key kUserKey;        // the person who is controlling the avatar, not the Owner  
+// the command lists
+list lCommands;  // commands are stored here
+list lNpcCommandList; // Storage for the NPC script.
+string npcAction; // Storage for the next action. @cmd=0|hello, this becomes @cmd
+string npcParams; // Storage for the param, @cmd=0|hello, this becomes 0|hello
+
+// misc vars
+string sNotecard; // commands are stored here temporarily for dumping
+vector  vWanderPos; // a place to wander to
+string lastANIM ;   // last animation run
+// Sensor
+integer avatarPresent;   // Sensor sets this flag when people are within Range.
+
+// Coordinate control
+vector vInitialPos ; // Vector that will be filled by the script with the initial starting position in region coordinates.
+vector vDestPos = ZERO_VECTOR; // Storage for destination position.
+string relAbs = "Relative";    // absolute vs relative positioning
+
+
+// STATES
+integer MENU ;             // processing a dialog box state, may be concurrent with STATE
+integer STATE;             // state storage
+integer MakeNotecard = 1;  // displaying a text box for NPC name
+integer RecordPath = 2;    // displaying a path notecard menu
+integer NobodyHome = 3;    // looking for an avatar
+integer Spawning = 4;      // spawning an avatar
+integer Animate = 5;       // animation timer needed
+integer Walking = 6;       // Hey! I am walking here!
+integer Wander = 7;        // Wandering around neeeds a timer, too
+integer WanderHold = 8;    // We reached a wander point
+integer DoProcess = 9;     // Set this to make it process a new command
+integer Touch = 10;        // Timer is busy sensing something to touch
+integer Sit = 11;          // Timer is busy sensing something to sit on
+integer Paused = 12;       // Timer is busy pausing
+
+key gNpcKey = NULL_KEY;   // global key storage for the one NPC, to save CPU cycles
+list Stack ;              // a command stack from link message input
+
+integer SensorFunc = 0;    // define which function shall be triggered inside the sensor function
+                           // 0 means none, 1 sit, 2 touch
+///////////////////////////////////////////////////////////////////////////
+//                              FUNCTIONS                                //
+///////////////////////////////////////////////////////////////////////////
+
+
+TimerEvent(float timesent)
+{
+    if (LSLEditor)
+        timesent *= 5;   // slow thinggs doen when the LSLEDITOR is in use
+        
+    DEBUG("Setting  timer: " + (string) timesent);
+    llSetTimerEvent(timesent);
+}
+
+// for 4.1 parse a message from a Listen or a Link message
+ParseMsg(string str) {
+    DEBUG("Command In:" + str);
+    if (str=="@go") {
+        SetStop(FALSE); // Let's run the notecard
+        DEBUG("@go running");
+        DoProcessNPCLine();
+    } else {
+        Stack += [str];    // take anything, the controller will filter away non @ stuff
+        if (STATE == 0) {
+            DEBUG("calling DoNPC");
+            DoProcessNPCLine();
+        } else{
+            DEBUG("Queued");
+        }
+    }
+}
+
+SetStop(integer what)
+{
+    DEBUG("Stopped set to " + (string ) what);
+    Stopped = what;
+}
+// Do* functions are much like states from the old V2 scripts.
+    
+// Save a Path notecard
+DoSave()
+{ 
+    STATE = MakeNotecard;
+    makeText("Stand where you want the NPC to appear, and enter the NPC Name");
+}
+
+// This function is used to record the path for the NPC
+// Each command can take 0, 1, or 2 params
+DoMenuForCommands() {
+    makeMenu(lAtButtons);
+}
+
+
+// No one is here when sensors were on, so we kill off the NPC
+DoNobodyHome()
+{
+    DEBUG("Nobody Home");
+    STATE = NobodyHome;
+    if (NPCKey() != NULL_KEY) {
+        osNpcRemove(NPCKey());
+        SaveKey(NULL_KEY);
+    }
+    TimerEvent(5);  // keep ticking to sense avatars   
+}
+
+// Create a NPC
+StateSpawn() {
+    DEBUG("state spawn");
+    STATE = Spawning;
+
+ 
+    NPCEnabled = TRUE; //  in world
+    // see if there is already one out there.
+    if (NPCKey() != NULL_KEY) {
+        DEBUG("Already living");
+        return;
+    }
+    
+        
+    list name = llParseString2List(sNPCName, [" "], []);
+   
+     vector vRezPos = vInitialPos;
+    if (relAbs == "Relative"){
+        vRezPos += llGetPos();
+    }
+
+    DEBUG("Rezzing the  NPC:" + (string) vRezPos);
+    key aKey = osNpcCreate(llList2String(name, 0), llList2String(name, 1), vRezPos, Appearance, NPCOptions);
+
+    SaveKey(aKey); // save in desceription and global, too
+    
+    osSetSpeed(aKey,SPEEDMULT);   // 1.9 speed multiplier
+    TimerEvent(REZTIME);
+    NPCAnimate(STAND);
+}
+ 
+DoRotate() {
+    DEBUG("@rotate=" + (string) RAMrot); 
+    osNpcSetRot(NPCKey(), llEuler2Rot(<0,0,RAMrot> * DEG_TO_RAD));
+}  
+
+StateSit() {
+    DEBUG ("state sit - looking for " + RAMsit);
+    STATE=Sit;
+    SensorFunc = 1; //triggers osNpcSit
+    llSensor(RAMsit, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+
+StateTouch() {
+    DEBUG ("state touch - looking for " + RAMtouch);
+    STATE = Touch;
+    SensorFunc = 2; //triggers osNpcTouch
+    llSensor(RAMtouch, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+ 
+DoStand() {
+    DEBUG("state stand");
+    osNpcStand(NPCKey());
+}
+
+
+StateAnimate() {
+    
+    DEBUG("state animate");
+    STATE = Animate;
+    NPCAnimate(RAManimationName);
+    if (RAManimationTime <=0 )    // V 3.4 tweak
+        RAManimationTime = 1;
+    TimerEvent(RAManimationTime);
+}
+    
+StateWalk() {
+
+    DEBUG("NPCWalkOption = " + (string) NPCWalkOption);
+    STATE = Walking;
+            
+    // walk, fly, run, land
+   if (walkstate == 1) {
+        NPCAnimate(WALK);
+    } else if (walkstate == 2)  {
+        llShout(FLIGHT,"flying");
+        NPCAnimate(FLY);
+    } else if (walkstate == 3) {
+        NPCAnimate(RUN);
+    } else if (walkstate == 4) {
+        NPCAnimate(LAND);
+    } 
+    newDest = vDestPos ;
+    newDest.z += OffsetZ;
+        
+    // notecard is stored as offsets from this box with relative addressing.  Convert to absolute
+    if (relAbs == "Relative"){
+        newDest += llGetPos();
+    }
+
+    DEBUG("Moveto:" + (string) newDest);
+    osNpcMoveToTarget(NPCKey(), newDest, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);
+}
+
+
+StateWander(){
+    DEBUG("state wander");
+    STATE = Wander;
+    
+    vector point = CirclePoint(RAMwd);
+    DEBUG("CirclePoint:" + (string) point);
+    vWanderPos = vDestPos + point;
+    DEBUG("vWanderPos:" + (string) vWanderPos);
+
+    fTimerVal = WANDERTIME;    // default time to pause after each wander
+    if (WANDERRAND)
+        fTimerVal = llFrand(WANDERTIME) + 1;    // override, they want random times
+
+    NPCAnimate(WALK);
+
+    DEBUG("Wander to:" + (string) vWanderPos);
+
+    osNpcMoveToTarget(NPCKey(), vWanderPos, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);      
+}
+
+StateWanderhold() {
+
+    DEBUG("Wander Hold");
+    STATE = WanderHold;
+       
+     // now that we have reached a wander spot, slow the timer down to the desired value
+    TimerEvent(fTimerVal);
+}
+
+// @pause=10 will do nothing for 10 seconds
+DoPause() {
+    STATE =Paused;
+    if (RAMPause < 0.1)
+        RAMPause = 0.1;
+    DEBUG("@pause=" + (string)RAMPause);
+    TimerEvent(RAMPause);
+}
+
+
+// @stop makes the NPC stop moving in whatever state it is in.  You have to linkmessage to get moving again
+DoStop() {    
+    DEBUG("NPC is Stopped");
+    STATE = 0;    // accept commands
+    SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+    
+// @delete removes the NPC forever. Next command starts it up again at the beginning
+DoDelete() {
+    DEBUG("state delete");
+    STATE = 0;    // accept commands
+    osNpcRemove(NPCKey());
+    SaveKey(NULL_KEY);
+    
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+
+// change the appearance of the NPC
+DoAppearance(string notecard) {
+    DEBUG("state appearance");
+    if (llGetInventoryType(notecard) == INVENTORY_NOTECARD){
+        DEBUG("Load appearance " + notecard);
+        osNpcLoadAppearance(NPCKey(),notecard);
+    }
+}
+
+// Change the avatar speed
+DoSpeed(string speed) {
+    float newspeed = (float) speed;
+    if (newspeed > 0.1 && newspeed < 5.0) {// sanity check
+        osSetSpeed(NPCKey(),newspeed);
+    }
+}
+DoNewNote (string card) {
+    DEBUG("Load Notecard " + card);    
+    NPCReadNoteCard(card);
+    SetStop(FALSE);
+}
+DoAttach(string params) {
+    
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    integer attachmentPoint  = (integer) llList2String(Data, 1);
+    if (attachmentPoint > 0
+        && attachmentPoint < 40
+        && llGetInventoryType(itemName) == INVENTORY_OBJECT
+       )
+    {
+        osForceAttachToOtherAvatarFromInventory(NPCKey(),itemName,attachmentPoint);
+    }
+}
+
+// This loops over the notecard, processing each command
+DoProcessNPCLine() {
+    DEBUG("ProcessNPCLine, stopped = " + (string) Stopped);
+    STATE = DoProcess;
+
+        // auto load a notecard
+    if (! llGetListLength(lNpcCommandList)) {
+        DEBUG("Read Notecard");
+        NPCReadNoteCard(Notecard);
+        SetStop(FALSE);
+    }
+
+    // look for link messages on the stack
+    string next = llList2String(Stack,0);    // lets see if there is anithing from a link message
+    if (llStringLength(next))
+    {
+        Stack = llDeleteSubList(Stack,0,0);
+        ProcessCmd(next);        //lets do this command instead.
+        return;
+    }
+
+    // @stop issued?
+    if (Stopped) {
+        TimerEvent(0);
+        DEBUG("Stopped, waiting for input");
+        STATE = 0;
+        return;
+    }
+
+    // No, we have an @go for liftoff
+    next = llList2String(lNpcCommandList, 0);        // get the next command
+    DEBUG("Execute:" + next);
+    lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);      // delete it
+        
+    if (llGetListLength(lNpcCommandList) == 0) {
+        DEBUG("EOF");
+    }
+    ProcessCmd(next); 
+} 
+
+
+
+ProcessCmd(string cmd) {
+
+    DEBUG("ProcessCmd:" + cmd);
+
+    if (llGetSubString(cmd, 0, 0) != "@") {
+        DEBUG("ignoring");
+        TimerEvent(QUICK);  // this is so we do not recurse the stack
+        STATE = 0;
+        return;
+    }
+
+    list data  = llParseString2List(cmd, ["="], []);
+    npcAction = llToLower(llStringTrim(llList2String(data, 0), STRING_TRIM));
+
+    DEBUG("Action:" + npcAction);
+    npcParams = llStringTrim(llList2String(data, 1), STRING_TRIM);
+    DEBUG("Params:" + npcParams);
+    
+    @commands;
+
+    ProcessSensor();
+    
+    if(npcAction == "@spawn" && avatarPresent) {
+        DEBUG("@spawn");
+        list spawnData = llParseString2List(npcParams, ["|"], []);
+        sNPCName =llList2String(spawnData, 0);    // V 1.6 name in RAM
+
+        list spawnDest = llParseString2List(llList2String(spawnData, 1), ["<", ",", ">"], []);
+        vInitialPos.x = llList2Float(spawnDest, 0);
+        vInitialPos.y = llList2Float(spawnDest, 1);
+        vInitialPos.z = llList2Float(spawnDest, 2);
+        
+        DEBUG("Coords for NPC at " + (string) vInitialPos);
+        StateSpawn();
+        return;
+    }
+    
+     if (! avatarPresent){
+        DoNobodyHome();
+        DEBUG("No avatar nearby");
+        STATE = 0;
+        return;
+    } else {
+        if ( NPCKey() == NULL_KEY) {
+            StateSpawn();
+        }
+    }
+
+    
+    
+    
+    if(npcAction == "@stop") {
+        DoStop();
+        STATE = 0;
+        return;
+    }
+    else if(npcAction == "@goto") {
+        DEBUG("goto");
+        integer lastIdx = llGetListLength(lNpcCommandList)-1;
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, lastIdx, lastIdx);
+        // Wind commands till goto label.
+        @wind;
+        string next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        if(next1 != npcParams) jump wind;
+        // Wind the label too.
+        next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        // Get next command.
+        list data1  = llParseString2List(next1, ["="], []);
+        npcAction = llToLower(llStringTrim(llList2String(data1, 0), STRING_TRIM));
+        npcParams = llStringTrim(llList2String(data1, 1), STRING_TRIM);
+        // Reschedule.
+        jump commands;
+    }
+    else if(npcAction == "@sound") {
+        DEBUG("sound");
+        llTriggerSound(npcParams,1.0);
+    }
+    else if(npcAction == "@randsound") {
+        DEBUG("@randsound");
+        integer N = llGetInventoryNumber(INVENTORY_SOUND);
+        integer rand = llCeil(llFrand(N)) -1;    // pick a random sound
+        string toPlay = llGetInventoryName(INVENTORY_SOUND,rand);
+        llTriggerSound(toPlay,1.0);
+    }
+    else if(npcAction == "@walk") {
+        DEBUG("@walk");
+        GetDest(npcParams);
+        walkstate = 1;//  walking
+        NPCWalkOption = OS_NPC_NO_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@fly") {
+        GetDest(npcParams);
+        walkstate = 2;//  flying
+        NPCWalkOption = OS_NPC_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@run") {
+        DEBUG("@run");
+        GetDest(npcParams);
+        walkstate = 3;//  running
+        NPCWalkOption = OS_NPC_NO_FLY | OS_NPC_RUNNING;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@land") {
+        DEBUG("@land");
+        GetDest(npcParams);
+        walkstate = 4;//  landing
+        NPCWalkOption= OS_NPC_FLY | OS_NPC_LAND_AT_TARGET ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@say") {
+        DEBUG("@say " + npcParams);
+        osNpcSay(NPCKey(), 0, npcParams);
+    }
+    else if(npcAction == "@shout") {
+        DEBUG("@shout");
+        osNpcShout(NPCKey(),0, npcParams);
+    }
+    else if(npcAction == "@whisper") {
+        DEBUG("@whisper " + npcParams);
+        osNpcWhisper(NPCKey(),0, npcParams);
+    }
+    // speak a command on a channel, so you can open doors and control stuff.
+    else if(npcAction == "@cmd") {
+        DEBUG("@cmd");
+        list dataToSpeak = llParseString2List(npcParams, ["|"], []);
+        string channel = llList2String(dataToSpeak,0);
+        DEBUG("Channel:"+(string) channel);
+        integer iChannel = (integer) channel;
+        string stringToSpeak = llList2String(dataToSpeak,1);
+        llSay(iChannel, stringToSpeak);
+    }
+    // stop everything
+    else if(npcAction == "@pause") {
+        RAMPause = (float) npcParams;
+        DoPause();
+        return;
+    }
+    else if(npcAction == "@wander") {
+        list wanderData = llParseString2List(npcParams, ["|"], []);
+        RAMwd = (float) llList2String(wanderData, 0);
+        RAMwc = (integer) llList2String(wanderData, 1);
+        vDestPos = osNpcGetPos(NPCKey());        // set the wander start
+        DEBUG("Starting at " + (string) vDestPos);
+        StateWander();
+        return;
+    }
+    else if(npcAction == "@rotate") {
+        RAMrot = (float) npcParams;
+        DoRotate();
+    }
+    else if(npcAction == "@sit") {
+        RAMsit= npcParams;
+        StateSit();
+        return;
+    }
+    else if(npcAction == "@touch") {
+        RAMtouch= npcParams;
+        StateTouch();
+        return;
+    }
+    else  if(npcAction == "@stand") {
+        DoStand();
+    }
+    else if(npcAction == "@delete") {
+        DoDelete();
+        SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+        return;
+    }
+    else if(npcAction == "@animate") {
+        list animateData = llParseString2List(npcParams, ["|"], []);
+        RAManimationName = llList2String(animateData, 0);
+        RAManimationTime = (float) llList2String(animateData, 1);
+        StateAnimate();
+        return;
+    }
+    else if(npcAction == "@appearance" ){
+        DoAppearance(npcParams);
+    }
+    else if (npcAction =="@speed") {
+        DoSpeed(npcParams);
+    }
+    else if (npcAction =="@notecard") {      
+        DoNewNote(npcParams);
+        Notecard = npcParams;
+    }
+    else if (npcAction == "@attach")
+    {
+        DoAttach(npcParams);
+    }
+
+    STATE = 0;
+    TimerEvent(QUICK);  // yeah I know, not possible this fast, we just go as fast as we can go - this is so we do not recurse the stack 
+}
+ 
+
+
+/////////////////// UTILITY Functions, not state-like //////////////////
+
+// DEBUG(string) will chat a string or display it as hovertext if debug == TRUE
+DEBUG(string str) {
+    if (debug && ! LSLEditor)
+        llOwnerSay( str);                    // Send the owner debug info 
+    if (debug &&  LSLEditor)
+        llSay(0, str);                    // Send to the Console in LSLEDitor 
+    if (iTitleText) {
+        llSetText(str,<1.0,1.0,1.0>,1.0);    // show hovertext
+    
+    }
+}
+
+GetDest(string npcParams) {
+    list dest = llParseString2List(npcParams, ["<", ",", ">"], []);
+    vDestPos.x = llList2Float(dest, 0);
+    vDestPos.y = llList2Float(dest, 1);
+    vDestPos.z = llList2Float(dest, 2);
+}
+
+NPCReadNoteCard(string Note) {
+    DEBUG("NPCReadNoteCard");             
+    lNpcCommandList = llParseString2List(osGetNotecard(Note), ["\n"], []);
+}  
+  
+integer SenseAvatar()
+{
+    //Returns a strided list of the UUID, position, and name of each avatar in the region
+    list avatars = llGetAgentList(AGENT_LIST_REGION ,[]);
+    integer numOfAvatars = llGetListLength(avatars);
+    if (numOfAvatars == 0)
+    {
+        DEBUG("No people");
+        return 0;
+    }
+    //DEBUG("Located " + (string)numOfAvatars + " avatars and NPC's"); 
+        
+    integer nAvatars;
+    integer i;
+    for( i = 0;i < numOfAvatars; i++) {
+        key aviKey = llList2Key(avatars,i);
+        if (!osIsNpc(aviKey)) {
+            list detail = llGetObjectDetails(aviKey,[OBJECT_POS]);
+            vector pos = llList2Vector(detail,0);
+            float dist = llVecDist(pos, llGetPos());
+            if (dist  < RANGE)
+            {
+                nAvatars++;
+                DEBUG("In range:" + llKey2Name(aviKey));
+            }
+        }
+    }
+    //DEBUG("Located " + (string) nAvatars + " avatars");
+    return nAvatars;
+} 
+ 
+// return TRUE if the avatar is owner when private is set, or TRUE if the avatar is in the same group and GROUP is set.
+integer checkPerms() {
+
+    integer group = (integer) KeyValueGet("pr");
+    if (! group)
+        priPub = "Owner Only";
+    else
+        priPub = "Group";
+    
+    
+    if (llDetectedKey(0) == llGetOwner()){
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+ 
+    if ( group && llDetectedGroup(0)) {
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+    kUserKey = llDetectedKey(0);
+    return FALSE;
+}
+
+
+
+NPCAnimate(string anim)
+{
+    DEBUG("Start Anim: " + anim);
+    if (llGetInventoryType(anim) == INVENTORY_ANIMATION ) {
+        
+        if (lastANIM != anim) {
+            if(llStringLength(lastANIM)) {
+                osNpcStopAnimation(NPCKey(), lastANIM);  
+            }
+            osNpcPlayAnimation(NPCKey(), anim);
+            lastANIM = anim;
+        }            
+    } else {
+        llSay(DEBUG_CHANNEL, "No animation named " + anim);
+    }
+} 
+
+// Kill a NPC by Name
+Kill(string param)
+{
+    integer count;
+    list avatars = osGetAvatarList(); // Returns a strided list of the UUID, position, and name of each avatar in the region except the owner.\    
+    integer i;
+    integer j = llGetListLength(avatars);
+    for (i=0 ; i <= j; i+=3){
+        
+        string desired = llList2String(avatars,i+2);
+        desired = llStringTrim(desired,STRING_TRIM);    // should not be needed but is needed
+        
+        if (desired == param){
+            vector v = llList2Vector(avatars,i+1);
+            key target = llList2Key(avatars,i);    // get the UUID of the avatar
+            osNpcRemove(target);
+            SaveKey(NULL_KEY );  
+            llOwnerSay("Removed " + param+ " at  location " + (string) v);
+            count++;
+        }
+    }
+    
+    NPCEnabled = FALSE; // not in world
+    
+    if (count)
+        llOwnerSay("Removed " + (string) count + " NPC's");
+    else
+        llOwnerSay("Could not locate " + param);
+}
+
+
+// return a String for the position we are at. Strings used as the caller wants strings
+string Pos()
+{
+    vector where = llGetPos(); // find the box position
+   
+    where.z +=    OffsetZ;  // use the ground position + an offset 
+        
+    if (LSLEditor)
+        where  = <128,128,31 + llFrand(1)>; // force center of sim when editing
+   
+   // if attached the height will be too high by 1/2 the agent size
+    if (llGetAttached()) {
+        vector size = llGetAgentSize(llGetOwner());   
+        float Z = size.z;
+        where.z -= Z/2;  
+    }
+   
+    // DEBUG("Pos= " + (string) where);
+    return (string) where;
+}
+
+// setup a menu with a timer for timeouts, called by all make*()
+menu()
+{
+    llListenRemove(iHandle);
+    iChannel = llCeil(llFrand(100000) + 20000);
+    iHandle = llListen(iChannel,"","","");
+    TimerEvent(30.0);
+    MENU = TRUE;
+}
+
+// make a text box
+makeText(string Param)
+{ 
+    menu();
+    llTextBox(kUserKey, Param, iChannel);
+}
+
+// top level menu
+makeMainMenu()
+{
+    menu();
+    list buttons = ["Appearance","Recording","Save","Help","-","Erase RAM", priPub,relAbs,"-","Stop NPC",mSensor,"Start NPC"];
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Records",buttons,iChannel);
+}
+
+
+// Rev 1.4
+// top level menu for non group/ non owners
+makeUserMenu()
+{
+    if (!allowUsers) return;
+    
+    menu();
+    list buttons = ["Start NPC","Stop NPC"];
+    llDialog(kUserKey,"Choose",buttons,iChannel);
+}
+
+
+
+// programmable menu for @commands
+makeMenu(list buttons)
+{
+    menu();
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Record",buttons,iChannel);
+}
+
+
+// make one or two text boxes with prompts
+Text(string cmd, string p1, string p2)
+{
+    sCommand = cmd;
+     sParam2 = "";
+    if (llStringLength(p2))
+        sParam2 = p2;
+
+    makeText(p1);
+} 
+
+// Set the Avatar Present flag - if sensors are off and we are forece run, there will be one present.
+ProcessSensor()
+{
+    integer SensorOn;
+    if ("on" == KeyValueGet("se"))
+    {
+        SensorOn = TRUE;        // we need to scan for avatars
+    } else {
+        SensorOn = FALSE;        // we need to scan for avatars
+    }
+    DEBUG("Sensor:" + (string) SensorOn);
+    
+    integer n = SenseAvatar();
+    
+    DEBUG("Avatars:" + (string) n);
+    if (SensorOn && n)
+        avatarPresent = TRUE;   // someone is here and we need to tell the system to run
+    else if (SensorOn && !n)
+        avatarPresent = FALSE;  // someone is not here and we need to tell the system to stop
+    else {       // sensor is off, lete see if there is a NPC. If so, we are ON 
+        DEBUG("NPCEnabled:" + (string) NPCEnabled);
+        if (NPCEnabled)
+            avatarPresent = TRUE;  
+        else
+            avatarPresent = FALSE;   
+    }
+    
+    //  start up from when when no one is near
+    if (avatarPresent && STATE == NobodyHome)
+        STATE = 0;
+    
+    DEBUG("Avatar Present: " + (string) avatarPresent);
+}
+
+vector CirclePoint(float radius) {
+    float x = llFrand(radius *2) - radius;        // +/- radius, randomized
+    float y = llFrand(radius *2) - radius;        // +/- radius, randomized
+    return <x, y, 0>;        // so this should always happen
+}
+
+string KeyValueGet(string var) {
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k != var) jump continue;
+        //DEBUG("got " + var + " = " +  llList2String(data, 1));
+        return llList2String(data, 1);
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    return "";
+} 
+
+KeyValueSet(string var, string val) {
+
+    //DEBUG("set " + var + " = " + val);
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    if(llGetListLength(dVars) == 0)
+    {
+        llSetObjectDesc(var + "=" + val);
+        return;
+    }
+    list result = [];
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k == "") jump continue;
+        if(k == var && val == "") jump continue;
+        if(k == var) {
+            result += k + "=" + val;
+            val = "";
+            jump continue;
+        }
+        string v = llList2String(data, 1);
+        if(v == "") jump continue;
+        result += k + "=" + v;
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    if(val != "") result += var + "=" + val;
+    llSetObjectDesc(llDumpList2String(result, "&"));
+}
+
+
+// clear RAM
+Clr() {
+
+    lCommands = [];
+    llOwnerSay("RAM Memory cleared. Notecards, if any, are not modified.");
+    makeMainMenu();
+}
+
+integer checkNoteCards()
+{
+    // Check that they have saved an Appeaance and Path notecard
+    integer num = llGetInventoryNumber(INVENTORY_NOTECARD);    // how many notecards overall
+    
+    integer i;
+    integer count;
+    for (; i < num; i++){
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Notecard)
+            count++;
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Appearance)
+            count++;
+    }
+    DEBUG("Checked " + (string) count + " Notecards");
+    // if we have both, run the NPC
+    return count;
+}
+
+Update(string SName) {
+         
+    // delete all NPC* scripts except myself
+    integer i;
+    integer j = llGetInventoryNumber(INVENTORY_SCRIPT);
+    for (i = 0; i < j; i++) {
+        string targetName = llGetInventoryName(INVENTORY_SCRIPT,i);
+        string match = llGetSubString(targetName,0,2);
+        
+        if (match == SName && llGetScriptName() != targetName){
+                llOwnerSay("Upgrading " + targetName);
+            if (! LSLEditor){        // lets not kill the editor
+                llRemoveInventory(targetName);
+            }
+        }
+    }
+}
+
+// Get all default saved params from the Description
+GetSwitches()
+{
+         string rA = KeyValueGet("co"); // Get the remembered menu setting for Abs Vs Relative
+        if (rA == "A")
+            relAbs = "Absolute";
+        else  if (rA == "R")
+            relAbs = "Relative";
+        else
+            relAbs = "Absolute";
+
+            
+        // reenable NPC if sensor is on.
+        if ("on" == KeyValueGet("se"))
+        {
+            NPCEnabled = TRUE;
+            mSensor  = "Sense is On";
+            ProcessSensor();       // fake 1 avatar to get it rezzed
+        } else {
+            mSensor  = "Sense is Off";
+        }
+    }
+
+
+SaveKey(key akey)
+{
+    DEBUG("Saving Key of " + (string) akey);
+    KeyValueSet("key", akey);
+    if (akey !=  (key) KeyValueGet("key") )
+    {
+        DEBUG("Fatal error, cannot save key");
+    }
+    gNpcKey = akey;
+}
+
+
+key NPCKey()
+{
+    key akey = gNpcKey;   // from cached copy
+    // gNpcKey saves a lot of CPU processing by caching the key, if blank we get it from the description
+    if (gNpcKey == NULL_KEY)
+    {
+        //DEBUG("Get DKey");
+        akey = KeyValueGet("key");    // from Description of the prim
+    }
+   // DEBUG("NPC KEY:" + (string) akey);   
+    return  akey;
+}
+
+
+/////////////////// CODE BEGINS //////////////////
+
+
+default
+{
+    changed(integer change) {
+        if(change & CHANGED_REGION_START) {
+            llResetScript();
+        }
+    }
+    
+    on_rez(integer start_param)
+    {
+        llResetScript();
+    }
+
+    state_entry() {
+        
+        llSetText("",<1,1,1>,1.0);  // clr all hovertext- we may not be using it.
+        DoDelete(); // kill any NPC that is out running
+        Update("NPC"); // If dragged and ropped into a prim with any script named "NPC...", this will replace it.
+        GetSwitches(); // Get all default saved params from the Description
+
+        // 4.1 allow listeners to send us commands
+        if (allowListener)
+            llListen(link_Channel,"","","");
+        TimerEvent(TIMER);
+    } 
+
+
+    touch_start(integer n) 
+    {           // if touched, make a menu
+    
+        if (checkPerms()) {
+            if (RecordPath == STATE) {
+                makeMenu(lAtButtons); 
+            }   else {
+                makeMainMenu();
+            }
+        } else {
+            makeUserMenu();
+        }
+    }
+
+    // menu listener
+    listen(integer iChannel, string name, key id, string message) {
+
+        // process @commands that come in via the listener
+        if (iChannel == link_Channel)
+        {
+            ParseMsg(message);
+            return;
+        }
+        
+        if (MENU) {
+            llListenRemove(iHandle);
+            MENU = 0;       // menu is off
+            iHandle = 0;
+        }
+        
+        if (message == "Stop NPC")
+        {
+            lNpcCommandList = []; // force reload of notecard
+            NPCEnabled = FALSE;
+            if (NPCKey() != NULL_KEY){
+                Kill(sNPCName);
+                sNPCName = "";
+            } else {
+                bNPC_STOP = TRUE;
+                makeText("Enter name of an NPC to stop");
+            }
+        }
+        else if (message == "Menu" ) {
+            makeMainMenu();
+        }
+        else if (message == "Erase RAM"){
+            Clr();
+        }
+        else if (message == "Relative"){
+            relAbs = "Absolute";
+            KeyValueSet("co","A");   // remember coordinates = A
+            Clr();
+        }
+        else if (message == "Absolute"){
+            relAbs = "Relative";
+            KeyValueSet("co","R");   // remember coordinates = R
+            Clr();
+        }
+        else if (message == "Recording"){
+            DoMenuForCommands();        // show them the recording menu
+        }
+        else if (message == "Owner Only") {
+            priPub = "Group";
+            KeyValueSet("pr","1");
+
+            llOwnerSay("Group members have control");
+            makeMainMenu();
+        }
+        else if (message == "Group") {
+            priPub = "Owner Only";
+            KeyValueSet("pr","0");
+            llOwnerSay("Only you have control");
+            makeMainMenu();
+        }
+        else if (message == "Sense is On") {
+            mSensor ="Sense is Off";
+            KeyValueSet("se", "off");
+            llOwnerSay(mSensor);
+            makeMainMenu();
+        }
+        else if (message == "Sense is Off") {
+            mSensor ="Sense is On";
+            llOwnerSay(mSensor);
+            KeyValueSet("se", "on");
+            
+            NPCEnabled = FALSE;
+            
+            integer count = checkNoteCards();
+            if (count >= 2)  {
+                DEBUG("Notecards ok, DoProcessNPCLine");
+                DoProcessNPCLine();
+                return;
+            }
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording and/or appearance, so you cannot start a NPC");
+            makeMainMenu();
+        }
+        else if (message == "Appearance")  {
+            llRemoveInventory(Appearance);            // delete the notecard
+            osAgentSaveAppearance(kUserKey,Appearance);    // make the ntecard 
+            llOwnerSay("Your outfit has been saved");
+            makeMainMenu();
+        }
+        else if (message == "Save") {
+            if (llGetListLength(lCommands) == 0) {
+                llOwnerSay("Nothing recorded, you need to make a recording first");
+                makeMainMenu();
+                return;
+            }
+            DoSave();
+        }
+        else if (message == "Help"){
+            llLoadURL(kUserKey,"Click to view help","http://www.outworldz.com/opensim/posts/NPC/");
+            makeMainMenu();
+        }
+        else if (message == "Start NPC")    {
+            integer count = checkNoteCards();
+
+            NPCEnabled = TRUE;
+
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+            
+            if (count >= 2) {
+                DEBUG("Notecards approved , calling DoProcessNPCLine");
+                SetStop(FALSE); // Let's run the notecard
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording or maybe an appearance, so we cannot start a NPC");
+      
+        }
+        else if (bNPC_STOP){
+            bNPC_STOP = FALSE;
+            Kill(message);
+        }
+        else if (message == ">>"){
+            makeMenu(lMenu2);
+        }
+        else if (message == ">>>"){
+            makeMenu(lMenu3);
+        }
+        else if (message == "<<") {
+            makeMenu(lAtButtons);
+        }
+        else if (message == "<<<") {
+            makeMenu(lMenu2);
+        }
+        else if (message == "@comment"){
+            Text("# ","Enter a comment","");
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@run"){
+            lCommands += "@run=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@fly"){
+            lCommands += "@fly=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@land"){
+            lCommands += "@land=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@walk") {
+            lCommands += "@walk=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@sound"){
+            Text("@sound=","Enter a sound name or UUID to trigger","");
+        }
+        else if (message == "@randsound"){
+            lCommands += "@randsound"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@say") {
+            Text("@say=","Enter what the NPC will say","");
+        }
+        else if (message == "@whisper"){
+            Text("@whisper=","Enter what the NPC will whisper","");
+        }
+        else if (message == "@shout"){
+            Text("@shout=","Enter what the NPC will shout","");
+        }
+        else if (message == "@wander") {
+            Text("@wander=","Enter radius to wander","Enter number of wanders");
+        }
+        else if (message == "@pause") {
+            Text("@pause=","Enter time to pause","");
+        }
+        else if (message == "@rotate") {
+            Text("@rotate=","Enter degrees to rotate","");
+        }
+        else if (message == "@sit"){
+            Text("@sit=","Enter name of object to sit on","");
+        }
+        else if (message == "@touch"){
+            Text("@touch=","Enter name of object to touch","");
+        }
+        else if (message == "@cmd"){
+            Text("@cmd=","Enter cjhannel to speak on","Enter text to speak");
+        }
+        else if (message == "@stand"){
+            lCommands += "@stand\n";
+            llOwnerSay("Stand Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@animate"){
+            Text("@animate=","Enter animation name to play","Enter time to play the animation");
+        }
+        else if (message == "@attach"){
+            Text("@animate=","Enter inventory name to attach","Enter number of the attachment point (1-40)");
+        }
+         else if (message == "@speed"){
+            Text("@speed=","Enter a speed for the NPC, 1=100% normal speed, 0.5=50% speed","");
+        }
+               
+
+        // Save NPC name
+        else if (MakeNotecard == STATE) {
+            sNPCName = message; // in case we need to kill it.
+            
+            vector  vDest = (vector)  Pos();
+
+            if (relAbs == "Relative")
+            {
+                vDest  -= llGetPos();    // just an offset for relative
+            }
+            sNotecard = "@spawn=" + message + "|" +  (string) vDest  + "\n";
+            integer i;
+            integer j = llGetListLength(lCommands);
+            for (; i < j; i++){
+                // get the command to save to the notecard
+                string line = llList2String(lCommands,i);
+                if (relAbs == "Absolute") {
+                    sNotecard += line;    // add the un-modified string to the notecard
+                } else {
+                        // since we have to record absolute coords since we do not know where the box goes until they press Save,
+                        // we process the absolute to relative conversion for walks here
+                        list parts = llParseString2List(line,["="],[]); //get the @command
+
+                    if (llList2String(parts,0) == "@walk") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@walk=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@fly") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@fly=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@run") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@run=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@land") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@land=" + (string) vec + "\n";
+                    }
+                    else {
+                        sNotecard += line;    // add the un-modified string to the notecard
+                    }
+                }
+            }
+            llRemoveInventory(Notecard);        // delete the old notecard
+            osMakeNotecard(Notecard,sNotecard); // Makes the notecard.
+            llSay(0,sNotecard);
+            llOwnerSay("Commands notecard has been written");
+            STATE = 0;
+        } // MakeNotecard
+
+        else  if (! llStringLength(sParam2)) {
+            lCommands +=  sCommand + message + "\n";
+            llOwnerSay("Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (llStringLength(sParam2)){
+            sCommand = sCommand + message + "|";
+            llOwnerSay("Recorded");
+            makeText(sParam2);
+            sParam2 = "";
+        }
+
+    }
+
+
+
+    timer(){
+       // DEBUG("tick");
+        
+        // if llDialog is up, kill the listener for the dialog box.
+        if (iHandle) {
+            llOwnerSay("Menu timed out");
+            llListenRemove(iHandle);
+            iHandle = 0;
+            return;             // ^^^^^^^^^^^^^^^^^^^^^^^
+        }
+        // if NoBodyHome, we are sensing for an avatar
+        else if (NobodyHome == STATE) {
+            ProcessSensor();
+            return;
+        }
+        // if we are spawning, we need time to rez the NPC, then start processing NPC Commands.
+        else if (Spawning == STATE) {
+            STATE = 0;
+            TimerEvent(TIMER);
+        }
+        // We end aniamtions with a timer
+        else if (Animate == STATE){
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+        }
+        
+        else if (Walking == STATE) {
+            if (--iWaitCounter) {
+                if (llVecDist(osNpcGetPos(NPCKey()), newDest) > MAXDIST)  {
+                    return;
+                }
+            }
+
+            DEBUG("At Destination: " + (string) newDest);
+            
+            // walk, fly, run, land
+            if (walkstate == 1) {
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 2)  {
+                    // nothing
+                } else if (walkstate == 3) {
+                     NPCAnimate(STAND);
+                     NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 4) {
+                llShout(FLIGHT,"landing");
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            }
+        }
+        // Wandering timer 
+        else if (Wander == STATE) {
+            if (--iWaitCounter) {          // wait 60 seconds to get to a destination.
+                if (llVecDist(osNpcGetPos(NPCKey()), vWanderPos) > MAXDIST)
+                    return;
+            }
+
+            // see if wander counter == 0, if so, stop walking, go to stand and process next line
+            if(RAMwc == 0) {
+                NPCAnimate(STAND);
+                DEBUG("Wander ended, calling DoProcessNPCLine");
+                STATE = 0;
+                DoProcessNPCLine();
+                return;
+            }
+            // one less time to wander around
+            RAMwc--;
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+            StateWanderhold();
+            return;
+        }
+        // Wandering requires us to re-wander when we reach a destination
+        else if (WanderHold == STATE) {
+            StateWander();
+            TimerEvent(TIMER);
+            return;
+        }
+        else if (DoProcess == STATE) {
+            TimerEvent(QUICK);
+        }
+
+       
+        STATE = 0;
+
+        // We always process a NPC line at end of timer.
+        DEBUG("Tick end, calling DoProcessNPCLine");
+        DoProcessNPCLine();
+    }
+
+    // sensors are used for sitting on prims
+    // Neo Cortex: added different SensorFunc states to trigger sit or touch
+    sensor(integer num) {
+        if (SensorFunc == 1) {
+            osNpcSit(NPCKey(), llDetectedKey(0), OS_NPC_SIT_NOW);
+            DEBUG("Seated, calling DoProcessNPCLine");
+            SensorFunc = 0;
+        } else if (SensorFunc == 2) {
+            osNpcTouch(NPCKey(), llDetectedKey(0), LINK_THIS);
+            DEBUG("Touched, calling DoProcessNPCLine");
+            SensorFunc = 0;
+        }
+        DoProcessNPCLine();
+    }
+    no_sensor(){
+        DEBUG ("no target prim located, calling DoProcessNPCLine");
+        SensorFunc = 0;
+        DoProcessNPCLine();
+    }
+
+    
+    link_message(integer sender, integer num, string str, key id){
+        ParseMsg(str);
+    }
+        
+}
+
+
+
+
+
+
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.2.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.2.lsl
new file mode 100644
index 00000000..170f9589
--- /dev/null
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.2.lsl	
@@ -0,0 +1,1675 @@
+// :SHOW:1
+// :CATEGORY:NPC
+// :NAME:All In One NPC Recorder and Player
+// :AUTHOR:Ferd Frederix
+// :KEYWORDS:NPC, Puppeteer
+// :CREATED:2015-08-28 23:27:03
+// :EDITED:2015-09-24  13:25:15
+// :ID:27
+// :NUM:1828
+// :REV:4.2
+// :WORLD:OpenSim
+// :DESCRIPTION:
+// All in one NPC recorder player.
+// Supports both absolute and relative paths and many new commands
+// Add animations named "Fly, Walk, Stand and Run"
+// Click Prim to use.
+// Should be worn as a HUD to record.
+// Put it on the ground and click Sensor or Start NPC when done.
+// :CODE:
+// This is Rev 4.2  09/24/2015
+
+// Revision History
+// Rev 1.1 10-2-2014 @Sit did not work.  Minor tweaks to casting for lslEditor
+// Rev 1.2 10-14-2014 @ sit had wrong type.
+// Rev 1.3 relative movement fixed for @fly
+// Rev 1.4 4-3-2014 allow anyone to use this, non owners and non group members can only start and stop.
+// Rev 1.5 5-17-2014 set sensor to auto start on reboot of sim
+// Rev 1.6 5-24-2014 move menu so you can get it by touching, removed many of the KeyValues to RAM for efficiency
+// Rev 1.7 CHANGED_REGION_START, not CHANGED_REGION_START (Opensim difference)
+// Rev 1.8 tuned up Kill NPC, added more flexible upgrader
+// Rev 1.9 Better script injection by link message// Rev 2.0 Added osSetSpeed so you can speed up or slow down an NPC.
+// Rev 2.1 No laggy sensor used exept to sit on stuff
+// Rev 2.2 Various sensor fixes
+// Rev 2.3 Sets No Sensor in menu, must be started by hand
+// Rev 2.4 - reserved for patches to 2.3 if needed
+// Rev 3.0 Refactor out into subs, not states to make command injection easier
+//            New command: @appearance=Notecardname so you can switch to a new notecard on the fly
+//            New command: @speed=1.0  which slows up  ( < 1 )  or speeds up ( > 1)
+// Rev 3.1 Commands are not interruptible by Link Message
+// Rev 3.2 Sensor patches for consistency in removing the NPC
+// Rev 3.3 Added Touch command by Neo.Cortex@hbase42/hopto/org:8002
+//         Added Menu 3 for notecard and appearance commands
+// Rev 3.4 animation timer cannot be zero or it shuts off timer tweaked
+//         solves the NPC starting up when no sensor is set.
+// Rev 3.5 fixes saving to !Path  notecard
+// Rev 3.6 08-11-2015 @delete acts like @stop. TYjhe NPC now rezzes after an @go back in where it was deleted 
+// Rev 3.7 08-11-2015 @attach command added to load an attachment from the inventory to the NPC
+// Rev 3.8 08-17-2015 process queued commands one at a time without calling ProcessNPCLine on link message
+// Rev 3.9 08-23-2011 Queued command fixes including @delete which were not always working
+// Rev 4.0 09-15-2015 Fixes for Sensor functions which continually rezzed a NPC when no one was around.
+// Rev 4.1 09-20-2015 Added a Listener so link messages are not needed
+// Rev 4.2 09-23-2015 Added @teleport=<vector>
+//*******************************************************************//
+
+// Instructions on how to use this are at http://www.outworldz.com/opensim/posts/NPC/
+// This is an OpenSim-only script.
+// Author: Ferd Frederix aka Fred Beckhusen - fred@mitsi.com
+
+////////////////////////////////////////////////////////////////////////////////////////////
+//    Original code was Copyright (C) 2013 Wizardry and Steamworks - License: GNU GPLv3    //
+///////////////////////////////////////////////////////////////////////////////////////////
+//  Please see: http://www.gnu.org/licenses/gpl.html for legal details,                  //
+//  rights of fair usage, the disclaimer and warranty conditions.                        //
+///////////////////////////////////////////////////////////////////////////////////////////
+// The original NPC controller was from http://was.fm/opensim:npc
+// Extensive additions and bug fixes by Fred Beckhusen, aka Ferd Frederix
+// llSensor had two params swapped
+// @Wander would wander where it had rezzed, not where it was.
+// There was no 'no_sensor' event in sit, so if a @sit failed, the NPC got stuck
+// The animation and walks always stopped old, then started new.  It should be start new, then stop old so the default stand would be suppressed.
+// New code:
+// Merged with new Route recorder and notecard writer
+// If the NPC failed to reach a destination it never moved on.
+// Added WAIT global to tune this
+// Exposed many tunable variables and ported the code 
+// Added floating point to times in notecard.
+
+// Added @sound, @randsound, @whisper, @shout, and @cmd controls.
+//
+// notecards integers are not floats for better control
+// 
+// Link Messages may be used to perform external control by injecting @commands into the stream of actions
+// Example:
+// To chat something, such as with a chat robot
+//  llMessageLinked(LINK_SET,0,"@npc_say=Hello","");
+
+// This script assumes that NPCs and OSSl scripting is enabled in the OpenSim configuration.
+// In order to enable them, the following changes must be made in the OpenSim.ini configuration file:
+//
+// ; Turn on OSSL
+// AllowOSFunctions = true
+// OSFunctionThreatLevel = Severe
+
+//[NPC]
+//    ;# {Enabled} {} {Enable Non Player Character (NPC) facilities} {true false}
+//    Enabled = true
+//
+// and then the server has to be restarted.
+
+
+// Commands: All commands begin with an @ sign.  All other lines are ignored
+// @commands may have optional parameters.  The syntax is always:
+//  @cmd=parm1|parm2
+//  NaN in the table below meand Not a Number.   This means there is no parameter
+
+//Command     First Parameter             Second Parameter        Description
+//@spawn      name                        location (vector)       Rezzes an NPC with name at a location.
+//@appearance NoteCardName                NaN                     switch the NPC appearance to a new notecard
+//@walk       destination (vector)        NaN                     Makes the NPC walk to destination.
+//@fly        destination (vector)        NaN                     Makes the NPC fly to destination.
+//@land       destination (vector)        NaN                     Makes the NPC land at destination.
+//@say        string                      NaN                     Makes the NPC speak a phrase.
+//@whisper    string                      NaN                     Makes the NPC whisper a phrase.
+//@shout      string                      NaN                     Makes the NPC shout a phrase.
+//@pause      seconds (float)             NaN                     Makes the NPC wait for a multiple of seconds.
+//@wander     radius (float)              cycles (integer)        Makes the NPC wander in radius, for cycles seconds.
+//@delete     NaN                         NaN                     Removes the NPC.  Requires a link message to continue
+//@goto       label (string)              NaN                     Jump to the label label in the script.
+//@animate    animation (string)          time (float)            Makes the NPC trigger the animation animation for time seconds.
+//@sound      sound_name                  NaN                     plays a sound from inventory
+//@randsound  NaN                         NaN                     Plays a random sound from inventory
+//@rotate     degrees (float)             NaN                     Rotate the NPC degrees around the Z axis.
+//@sit        primitive name              NaN                     Sit on a primitive with a given name.
+//@touch      primitive name              NaN                     Touch on a primitive with a given name.
+//@stand      NaN                         NaN                     If sitting on a primitive, stand up.
+//@cmd        channel (integer)           string                  Says string on channel, for controlling external gadgets
+//@stop       NaN                         NaN                     Halts the NPC script indefinitely. Can be started with a link message
+//@go         NaN                         NaN                     Continues on next notecard line, for use in link messages
+//@speed      speed (float)               NaN                     from 0 to N, where 1.0 ius a normal speed of an avatar.  0.2 is a turtle.
+//@notecard   notename (string)           NaN                     load a new Path notecard
+//@attach     InventoryName               attachmentPoint         load an attachment from the inventory to the NPC onto point
+//@teleport   destination (vector)        NaN                     Makes the NPC teleport to destination in the same sim.  They cannot tp to another sim or across the HG
+
+ 
+// Constant            attachmentPoint Comment
+// ATTACH_CHEST            1    chest/sternum
+// ATTACH_HEAD             2    head
+// ATTACH_LSHOULDER        3    left shoulder
+// ATTACH_RSHOULDER        4    right shoulder
+// ATTACH_LHAND            5    left hand
+// ATTACH_RHAND            6    right hand
+// ATTACH_LFOOT            7    left foot
+// ATTACH_RFOOT            8    right foot
+// ATTACH_BACK             9    back
+// ATTACH_PELVIS          10    pelvis
+// ATTACH_MOUTH           11    mouth
+// ATTACH_CHIN            12    chin
+// ATTACH_LEAR            13    left ear
+// ATTACH_REAR            14    right ear
+// ATTACH_LEYE            15    left eye
+// ATTACH_REYE            16    right eye
+// ATTACH_NOSE            17    nose
+// ATTACH_RUARM           18    right upper arm
+// ATTACH_RLARM           19    right lower arm
+// ATTACH_LUARM           20    left upper arm
+// ATTACH_LLARM           21    left lower arm
+// ATTACH_RHIP            22    right hip
+// ATTACH_RULEG           23    right upper leg
+// ATTACH_RLLEG           24    right lower leg
+// ATTACH_LHIP            25    left hip
+// ATTACH_LULEG           26    left upper leg
+// ATTACH_LLLEG           27    left lower leg
+// ATTACH_BELLY           28    belly/stomach/tummy
+// ATTACH_LEFT_PEC        29    left pectoral
+// ATTACH_RIGHT_PEC       30    right pectoral
+// ATTACH_HUD_CENTER_2    31    HUD Center 2
+// ATTACH_HUD_TOP_RIGHT   32    HUD Top Right
+// ATTACH_HUD_TOP_CENTER  33    HUD Top
+// ATTACH_HUD_TOP_LEFT    34    HUD Top Left
+// ATTACH_HUD_CENTER_1    35    HUD Center
+// ATTACH_HUD_BOTTOM_LEFT 36    HUD Bottom Left
+// ATTACH_HUD_BOTTOM      37    HUD Bottom
+// ATTACH_HUD_BOTTOM_RIGHT 38   HUD Bottom Right
+// ATTACH_NECK            39   neck
+// ATTACH_AVATAR_CENTER  40    avatar center/root
+
+
+  
+//////////////////////////////////////////////////////////
+//                  DEBUG                               //
+//////////////////////////////////////////////////////////
+integer debug = TRUE;         // set to TRUE or FALSE for debug chat on various actions
+integer LSLEditor = TRUE;        // set to to TRUE to working in  LSLEditor, FALSE for in-world.
+                              // you must also include the NPC commands found in the other script since LSLEditor does not support OpenSim
+integer iTitleText = FALSE;    // set to TRUE to see debug info in text above the controller
+ 
+//////////////////////////////////////////////////////////
+//                  TUNABLE CONFIGURATION               //
+//////////////////////////////////////////////////////////
+integer   allowListener = TRUE; // set to TRUE to anable a command listener. Usually, this is setto FALSE
+integer   link_Channel =   4223; // some random number you want to talk to this gadget on. Best if large and negative
+float     TIMER = 2;         // faster = less jerky stopping.  How often the system checks the distance traveled.  Fastest you can go is 0.5 seconds
+float     QUICK = 1;        // when we need to move to the next state, we use a QUICK timer
+string    Appearance = "!Appearance";  // The name of the recorded Appearance notecard
+string    Notecard = "!Path"; // The name of the recorded routes
+integer   allowUsers = FALSE;  // If true, any user can get a Start NPC and Stop NPC menu.  Only groups and owners can get all commands if TRUE, or FALSE
+float     MAXDIST = 2.0;       // how close a NPC has to get to a dest pos to continue to next state. Do not lower this too much, as it may miss the target
+integer   WANDERRAND = TRUE;   // set to TRUE and they will pause during wanders a random number of seconds
+float     WANDERTIME = 3.0;    // how long they stand after each @wander,if WANDERRAND is FALSE. If WANDERRAND is  TRUE, this is the max time
+integer   WAIT = 30;           // wait for this number of seconds for the NPC to reach a destination (for safety). If it fails to reach a target, it will move on after this time.
+float     RANGE = 50;        // 1 to N meters  - anyone this close to the controller will start NPCS if Sensor button is clicked
+float     REZTIME = 2.0;      // wait this long for NPC to rez in, then start the process
+string    STAND = "Stand";     // the name of the default Stand animation
+string    WALK = "Walk";       // the name of the default Walk animation
+string    FLY = "Fly";        // the name of the default Fly animation
+string    RUN = "Run";        // the name of the default Run animation
+string    LAND = "Land";      // the name of the default land animation ( for birds only)
+float     OffsetZ = 0.5;      // appear 0.5 meter above ground, this is added to all destinations to keep them from sinking in.  
+float    SPEEDMULT =0.5;     // 1.0 = regular avatar speed. Smaller numbers slow down walks. Large numbers speed them up.
+integer  FLIGHT = 299;        // For controlling wings.  A channel that is shouted at when flight starts and ends. "flying" or "landing" 
+
+// DESCRIPTIONS FIELDS HAVE TO SURVIVE A RESET
+//  These vars are stored  by saving them with KeyValueSet
+// "pr" is a 0 if it is set for Owner Only, 1 for Group control
+// "se" is "on" if Started
+// "co" = "R" or "A" for relative or absolute addressing mode
+// "key" = NPC key
+
+// These Globals used to be stored in description.   Moved to RAM in V1.6
+float RAMPause;          // @pause param
+float RAMwd ;            // @wander distance
+integer RAMwc;           // @wander count
+float RAMrot;            //  @rotate
+string RAMsit;           // @sit primname
+string RAMtouch;         // @touch primname
+string RAManimationName; // @animate animation (string) time (float)
+float RAManimationTime;
+
+// other globals section
+integer iChannel;        // a listen channel, randomly assigned
+integer iHandle;         // the handle to it
+
+// NPC controls
+vector newDest ;                // tmp storage for the walks
+integer iWaitCounter ;          // wait for this number of seconds for the NPC to reach a desrtination
+string sNPCName;                // the name of the NPC that may be in world. So we can remove it.
+integer bNPC_STOP = FALSE;      // boolean to reuse a listener
+integer Stopped = FALSE;        // set to TRUE by link messages so we do not remember them
+float  fTimerVal ;              // how long we wait when wandering (calculated)
+float NPCEnabled;               // true if the NPC is suppodes to be running
+
+// OS_NPC_CREATOR_OWNED will create an 'owned' NPC that will only respond to osNpc* commands issued from scripts that have the same owner as the one that created the NPC.
+// OS_NPC_NOT_OWNED will create an 'unowned' NPC that will respond to any script that has OSSL permissions to call osNpc* commands.
+integer  NPCOptions = OS_NPC_CREATOR_OWNED;    // only yhe owner of this box can control this NPC.
+
+integer walkstate = 0;  // helps us reshare the walk state for run, fly and land - a bit of a hack, but it saves RAM. Has to be done this way because some bits of NPCWalkOption are asserted as 0
+
+integer NPCWalkOption;   // Some notes for what happens to NPCWalkOption:
+// OS_NPC_FLY - Fly the avatar to the given position. The avatar will not land unless the OS_NPC_LAND_AT_TARGET option is also given.
+// OS_NPC_NO_FLY - Do not fly to the target. The NPC will attempt to walk to the location. If it's up in the air then the avatar will keep bouncing hopeless until another move target is given or the move is stopped
+//OS_NPC_LAND_AT_TARGET - If given and the avatar is flying, then it will land when it reaches the target. If OS_NPC_NO_FLY is given then this option has no effect.
+// OS_NPC_RUNNING - if given, NPC avatar moves at running/fast flying speed, otherwise moves at walking/slow flying speed.
+
+// menus
+string mSensor="Sense is Off";    // Sensor or "No Sensor"
+
+list lAtButtons = ["Menu","-",   ">>",         "@run",    "@walk",   "@fly",  "@land", "@wander",    "@sit",   "@stand","@animate","@rotate"];
+list lMenu2 = ["<<", "@comment", ">>>",        "@stop",      "@say",    "@whisper","@shout","@sound","@randsound","@cmd",  "@pause",  "@delete"];
+list lMenu3 = ["<<<","@notecard","@appearance", "@touch", "@speed",       "@attach",     "@teleport","-", "-", "-", "-", "-" ];
+
+string sCommand;  // place to store a command for two-prompted ones
+string sParam2;   // place to store a prompt for two-prompted ones
+string priPub = "Owner Only";    // Private or Group
+key kUserKey;        // the person who is controlling the avatar, not the Owner  
+// the command lists
+list lCommands;  // commands are stored here
+list lNpcCommandList; // Storage for the NPC script.
+string npcAction; // Storage for the next action. @cmd=0|hello, this becomes @cmd
+string npcParams; // Storage for the param, @cmd=0|hello, this becomes 0|hello
+
+// misc vars
+string sNotecard; // commands are stored here temporarily for dumping
+vector  vWanderPos; // a place to wander to
+string lastANIM ;   // last animation run
+// Sensor
+integer avatarPresent;   // Sensor sets this flag when people are within Range.
+
+// Coordinate control
+vector vInitialPos ; // Vector that will be filled by the script with the initial starting position in region coordinates.
+vector vDestPos = ZERO_VECTOR; // Storage for destination position.
+string relAbs = "Relative";    // absolute vs relative positioning
+
+
+// STATES
+integer MENU ;             // processing a dialog box state, may be concurrent with STATE
+integer STATE;             // state storage
+integer MakeNotecard = 1;  // displaying a text box for NPC name
+integer RecordPath = 2;    // displaying a path notecard menu
+integer NobodyHome = 3;    // looking for an avatar
+integer Spawning = 4;      // spawning an avatar
+integer Animate = 5;       // animation timer needed
+integer Walking = 6;       // Hey! I am walking here!
+integer Wander = 7;        // Wandering around neeeds a timer, too
+integer WanderHold = 8;    // We reached a wander point
+integer DoProcess = 9;     // Set this to make it process a new command
+integer Touch = 10;        // Timer is busy sensing something to touch
+integer Sit = 11;          // Timer is busy sensing something to sit on
+integer Paused = 12;       // Timer is busy pausing
+
+key gNpcKey = NULL_KEY;   // global key storage for the one NPC, to save CPU cycles
+list Stack ;              // a command stack from link message input
+
+integer SensorFunc = 0;    // define which function shall be triggered inside the sensor function
+                           // 0 means none, 1 sit, 2 touch
+///////////////////////////////////////////////////////////////////////////
+//                              FUNCTIONS                                //
+///////////////////////////////////////////////////////////////////////////
+
+
+TimerEvent(float timesent)
+{
+    if (LSLEditor)
+        timesent *= 5;   // slow thinggs doen when the LSLEDITOR is in use
+        
+    DEBUG("Setting  timer: " + (string) timesent);
+    llSetTimerEvent(timesent);
+}
+
+// for 4.1 parse a message from a Listen or a Link message
+ParseMsg(string str) {
+    DEBUG("Command In:" + str);
+    if (str=="@go") {
+        SetStop(FALSE); // Let's run the notecard
+        DEBUG("@go running");
+        DoProcessNPCLine();
+    } else {
+        Stack += [str];    // take anything, the controller will filter away non @ stuff
+        if (STATE == 0) {
+            DEBUG("calling DoNPC");
+            DoProcessNPCLine();
+        } else{
+            DEBUG("Queued");
+        }
+    }
+}
+
+SetStop(integer what)
+{
+    DEBUG("Stopped set to " + (string ) what);
+    Stopped = what;
+}
+// Do* functions are much like states from the old V2 scripts.
+    
+// Save a Path notecard
+DoSave()
+{ 
+    STATE = MakeNotecard;
+    makeText("Stand where you want the NPC to appear, and enter the NPC Name");
+}
+
+// This function is used to record the path for the NPC
+// Each command can take 0, 1, or 2 params
+DoMenuForCommands() {
+    makeMenu(lAtButtons);
+}
+
+
+// No one is here when sensors were on, so we kill off the NPC
+DoNobodyHome()
+{
+    DEBUG("Nobody Home");
+    STATE = NobodyHome;
+    if (NPCKey() != NULL_KEY) {
+        osNpcRemove(NPCKey());
+        SaveKey(NULL_KEY);
+    }
+    TimerEvent(5);  // keep ticking to sense avatars   
+}
+
+// Create a NPC
+StateSpawn() {
+    DEBUG("state spawn");
+    STATE = Spawning;
+
+ 
+    NPCEnabled = TRUE; //  in world
+    // see if there is already one out there.
+    if (NPCKey() != NULL_KEY) {
+        DEBUG("Already living");
+        return;
+    }
+    
+        
+    list name = llParseString2List(sNPCName, [" "], []);
+   
+     vector vRezPos = vInitialPos;
+    if (relAbs == "Relative"){
+        vRezPos += llGetPos();
+    }
+
+    DEBUG("Rezzing the  NPC:" + (string) vRezPos);
+    key aKey = osNpcCreate(llList2String(name, 0), llList2String(name, 1), vRezPos, Appearance, NPCOptions);
+
+    SaveKey(aKey); // save in desceription and global, too
+    
+    osSetSpeed(aKey,SPEEDMULT);   // 1.9 speed multiplier
+    TimerEvent(REZTIME);
+    NPCAnimate(STAND);
+}
+ 
+DoRotate() {
+    DEBUG("@rotate=" + (string) RAMrot); 
+    osNpcSetRot(NPCKey(), llEuler2Rot(<0,0,RAMrot> * DEG_TO_RAD));
+}  
+
+StateSit() {
+    DEBUG ("state sit - looking for " + RAMsit);
+    STATE=Sit;
+    SensorFunc = 1; //triggers osNpcSit
+    llSensor(RAMsit, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+
+StateTouch() {
+    DEBUG ("state touch - looking for " + RAMtouch);
+    STATE = Touch;
+    SensorFunc = 2; //triggers osNpcTouch
+    llSensor(RAMtouch, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+ 
+DoStand() {
+    DEBUG("state stand");
+    osNpcStand(NPCKey());
+}
+
+
+StateAnimate() {
+    
+    DEBUG("state animate");
+    STATE = Animate;
+    NPCAnimate(RAManimationName);
+    if (RAManimationTime <=0 )    // V 3.4 tweak
+        RAManimationTime = 1;
+    TimerEvent(RAManimationTime);
+}
+    
+StateWalk() {
+
+    DEBUG("NPCWalkOption = " + (string) NPCWalkOption);
+    STATE = Walking;
+            
+    // walk, fly, run, land
+   if (walkstate == 1) {
+        NPCAnimate(WALK);
+    } else if (walkstate == 2)  {
+        llShout(FLIGHT,"flying");
+        NPCAnimate(FLY);
+    } else if (walkstate == 3) {
+        NPCAnimate(RUN);
+    } else if (walkstate == 4) {
+        NPCAnimate(LAND);
+    } 
+    newDest = vDestPos ;
+    newDest.z += OffsetZ;
+        
+    // notecard is stored as offsets from this box with relative addressing.  Convert to absolute
+    if (relAbs == "Relative"){
+        newDest += llGetPos();
+    }
+
+    DEBUG("Moveto:" + (string) newDest);
+    osNpcMoveToTarget(NPCKey(), newDest, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);
+}
+
+
+StateWander(){
+    DEBUG("state wander");
+    STATE = Wander;
+    
+    vector point = CirclePoint(RAMwd);
+    DEBUG("CirclePoint:" + (string) point);
+    vWanderPos = vDestPos + point;
+    DEBUG("vWanderPos:" + (string) vWanderPos);
+
+    fTimerVal = WANDERTIME;    // default time to pause after each wander
+    if (WANDERRAND)
+        fTimerVal = llFrand(WANDERTIME) + 1;    // override, they want random times
+
+    NPCAnimate(WALK);
+
+    DEBUG("Wander to:" + (string) vWanderPos);
+
+    osNpcMoveToTarget(NPCKey(), vWanderPos, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);      
+}
+
+StateWanderhold() {
+
+    DEBUG("Wander Hold");
+    STATE = WanderHold;
+       
+     // now that we have reached a wander spot, slow the timer down to the desired value
+    TimerEvent(fTimerVal);
+}
+
+// @pause=10 will do nothing for 10 seconds
+DoPause() {
+    STATE =Paused;
+    if (RAMPause < 0.1)
+        RAMPause = 0.1;
+    DEBUG("@pause=" + (string)RAMPause);
+    TimerEvent(RAMPause);
+}
+
+
+// @stop makes the NPC stop moving in whatever state it is in.  You have to linkmessage to get moving again
+DoStop() {    
+    DEBUG("NPC is Stopped");
+    STATE = 0;    // accept commands
+    SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+    
+// @delete removes the NPC forever. Next command starts it up again at the beginning
+DoDelete() {
+    DEBUG("state delete");
+    STATE = 0;    // accept commands
+    osNpcRemove(NPCKey());
+    SaveKey(NULL_KEY);
+    
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+
+// change the appearance of the NPC
+DoAppearance(string notecard) {
+    DEBUG("state appearance");
+    if (llGetInventoryType(notecard) == INVENTORY_NOTECARD){
+        DEBUG("Load appearance " + notecard);
+        osNpcLoadAppearance(NPCKey(),notecard);
+    }
+}
+
+// Change the avatar speed
+DoSpeed(string speed) {
+    float newspeed = (float) speed;
+    if (newspeed > 0.1 && newspeed < 5.0) {// sanity check
+        osSetSpeed(NPCKey(),newspeed);
+    }
+}
+
+DoTeleport(string params) {
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    vector Dest = (vector) itemName;
+    if (Dest !=ZERO_VECTOR) {
+        osTeleportAgent( NPCKey(), llGetRegionName(), Dest, ZERO_VECTOR );
+    }
+    
+}
+
+
+
+DoNewNote (string card) {
+    DEBUG("Load Notecard " + card);    
+    NPCReadNoteCard(card);
+    SetStop(FALSE);
+}
+DoAttach(string params) {
+    
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    integer attachmentPoint  = (integer) llList2String(Data, 1);
+    if (attachmentPoint > 0
+        && attachmentPoint < 40
+        && llGetInventoryType(itemName) == INVENTORY_OBJECT
+       )
+    {
+        osForceAttachToOtherAvatarFromInventory(NPCKey(),itemName,attachmentPoint);
+    }
+}
+
+// This loops over the notecard, processing each command
+DoProcessNPCLine() {
+    DEBUG("ProcessNPCLine, stopped = " + (string) Stopped);
+    STATE = DoProcess;
+
+        // auto load a notecard
+    if (! llGetListLength(lNpcCommandList)) {
+        DEBUG("Read Notecard");
+        NPCReadNoteCard(Notecard);
+        SetStop(FALSE);
+    }
+
+    // look for link messages on the stack
+    string next = llList2String(Stack,0);    // lets see if there is anithing from a link message
+    if (llStringLength(next))
+    {
+        Stack = llDeleteSubList(Stack,0,0);
+        ProcessCmd(next);        //lets do this command instead.
+        return;
+    }
+
+    // @stop issued?
+    if (Stopped) {
+        TimerEvent(0);
+        DEBUG("Stopped, waiting for input");
+        STATE = 0;
+        return;
+    }
+
+    // No, we have an @go for liftoff
+    next = llList2String(lNpcCommandList, 0);        // get the next command
+    DEBUG("Execute:" + next);
+    lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);      // delete it
+        
+    if (llGetListLength(lNpcCommandList) == 0) {
+        DEBUG("EOF");
+    }
+    ProcessCmd(next); 
+} 
+
+
+
+ProcessCmd(string cmd) {
+
+    DEBUG("ProcessCmd:" + cmd);
+
+    if (llGetSubString(cmd, 0, 0) != "@") {
+        DEBUG("ignoring");
+        TimerEvent(QUICK);  // this is so we do not recurse the stack
+        STATE = 0;
+        return;
+    }
+
+    list data  = llParseString2List(cmd, ["="], []);
+    npcAction = llToLower(llStringTrim(llList2String(data, 0), STRING_TRIM));
+
+    DEBUG("Action:" + npcAction);
+    npcParams = llStringTrim(llList2String(data, 1), STRING_TRIM);
+    DEBUG("Params:" + npcParams);
+    
+    @commands;
+
+    ProcessSensor();
+    
+    if(npcAction == "@spawn" && avatarPresent) {
+        DEBUG("@spawn");
+        list spawnData = llParseString2List(npcParams, ["|"], []);
+        sNPCName =llList2String(spawnData, 0);    // V 1.6 name in RAM
+
+        list spawnDest = llParseString2List(llList2String(spawnData, 1), ["<", ",", ">"], []);
+        vInitialPos.x = llList2Float(spawnDest, 0);
+        vInitialPos.y = llList2Float(spawnDest, 1);
+        vInitialPos.z = llList2Float(spawnDest, 2);
+        
+        DEBUG("Coords for NPC at " + (string) vInitialPos);
+        StateSpawn();
+        return;
+    }
+    
+     if (! avatarPresent){
+        DoNobodyHome();
+        DEBUG("No avatar nearby");
+        STATE = 0;
+        return;
+    } else {
+        if ( NPCKey() == NULL_KEY) {
+            StateSpawn();
+        }
+    }
+
+    
+    
+    
+    if(npcAction == "@stop") {
+        DoStop();
+        STATE = 0;
+        return;
+    }
+    else if(npcAction == "@goto") {
+        DEBUG("goto");
+        integer lastIdx = llGetListLength(lNpcCommandList)-1;
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, lastIdx, lastIdx);
+        // Wind commands till goto label.
+        @wind;
+        string next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        if(next1 != npcParams) jump wind;
+        // Wind the label too.
+        next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        // Get next command.
+        list data1  = llParseString2List(next1, ["="], []);
+        npcAction = llToLower(llStringTrim(llList2String(data1, 0), STRING_TRIM));
+        npcParams = llStringTrim(llList2String(data1, 1), STRING_TRIM);
+        // Reschedule.
+        jump commands;
+    }
+    else if(npcAction == "@sound") {
+        DEBUG("sound");
+        llTriggerSound(npcParams,1.0);
+    }
+    else if(npcAction == "@randsound") {
+        DEBUG("@randsound");
+        integer N = llGetInventoryNumber(INVENTORY_SOUND);
+        integer rand = llCeil(llFrand(N)) -1;    // pick a random sound
+        string toPlay = llGetInventoryName(INVENTORY_SOUND,rand);
+        llTriggerSound(toPlay,1.0);
+    }
+    else if(npcAction == "@walk") {
+        DEBUG("@walk");
+        GetDest(npcParams);
+        walkstate = 1;//  walking
+        NPCWalkOption = OS_NPC_NO_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@fly") {
+        GetDest(npcParams);
+        walkstate = 2;//  flying
+        NPCWalkOption = OS_NPC_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@run") {
+        DEBUG("@run");
+        GetDest(npcParams);
+        walkstate = 3;//  running
+        NPCWalkOption = OS_NPC_NO_FLY | OS_NPC_RUNNING;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@land") {
+        DEBUG("@land");
+        GetDest(npcParams);
+        walkstate = 4;//  landing
+        NPCWalkOption= OS_NPC_FLY | OS_NPC_LAND_AT_TARGET ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@say") {
+        DEBUG("@say " + npcParams);
+        osNpcSay(NPCKey(), 0, npcParams);
+    }
+    else if(npcAction == "@shout") {
+        DEBUG("@shout");
+        osNpcShout(NPCKey(),0, npcParams);
+    }
+    else if(npcAction == "@whisper") {
+        DEBUG("@whisper " + npcParams);
+        osNpcWhisper(NPCKey(),0, npcParams);
+    }
+    // speak a command on a channel, so you can open doors and control stuff.
+    else if(npcAction == "@cmd") {
+        DEBUG("@cmd");
+        list dataToSpeak = llParseString2List(npcParams, ["|"], []);
+        string channel = llList2String(dataToSpeak,0);
+        DEBUG("Channel:"+(string) channel);
+        integer iChannel = (integer) channel;
+        string stringToSpeak = llList2String(dataToSpeak,1);
+        llSay(iChannel, stringToSpeak);
+    }
+    // stop everything
+    else if(npcAction == "@pause") {
+        RAMPause = (float) npcParams;
+        DoPause();
+        return;
+    }
+    else if(npcAction == "@wander") {
+        list wanderData = llParseString2List(npcParams, ["|"], []);
+        RAMwd = (float) llList2String(wanderData, 0);
+        RAMwc = (integer) llList2String(wanderData, 1);
+        vDestPos = osNpcGetPos(NPCKey());        // set the wander start
+        DEBUG("Starting at " + (string) vDestPos);
+        StateWander();
+        return;
+    }
+    else if(npcAction == "@rotate") {
+        RAMrot = (float) npcParams;
+        DoRotate();
+    }
+    else if(npcAction == "@sit") {
+        RAMsit= npcParams;
+        StateSit();
+        return;
+    }
+    else if(npcAction == "@touch") {
+        RAMtouch= npcParams;
+        StateTouch();
+        return;
+    }
+    else  if(npcAction == "@stand") {
+        DoStand();
+    }
+    else if(npcAction == "@delete") {
+        DoDelete();
+        SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+        return;
+    }
+    else if(npcAction == "@animate") {
+        list animateData = llParseString2List(npcParams, ["|"], []);
+        RAManimationName = llList2String(animateData, 0);
+        RAManimationTime = (float) llList2String(animateData, 1);
+        StateAnimate();
+        return;
+    }
+    else if(npcAction == "@appearance" ){
+        DoAppearance(npcParams);
+    }
+    else if (npcAction =="@speed") {
+        DoSpeed(npcParams);
+    }
+    else if (npcAction =="@notecard") {      
+        DoNewNote(npcParams);
+        Notecard = npcParams;
+    }
+    else if (npcAction == "@attach")
+    {
+        DoAttach(npcParams);
+    }
+    else if (npcAction == "@teleport")
+    {
+        DoTeleport(npcParams);
+    }
+
+    STATE = 0;
+    TimerEvent(QUICK);  // yeah I know, not possible this fast, we just go as fast as we can go - this is so we do not recurse the stack 
+}
+ 
+
+
+/////////////////// UTILITY Functions, not state-like //////////////////
+
+// DEBUG(string) will chat a string or display it as hovertext if debug == TRUE
+DEBUG(string str) {
+    if (debug && ! LSLEditor)
+        llOwnerSay( str);                    // Send the owner debug info 
+    if (debug &&  LSLEditor)
+        llSay(0, str);                    // Send to the Console in LSLEDitor 
+    if (iTitleText) {
+        llSetText(str,<1.0,1.0,1.0>,1.0);    // show hovertext
+    
+    }
+}
+
+GetDest(string npcParams) {
+    list dest = llParseString2List(npcParams, ["<", ",", ">"], []);
+    vDestPos.x = llList2Float(dest, 0);
+    vDestPos.y = llList2Float(dest, 1);
+    vDestPos.z = llList2Float(dest, 2);
+}
+
+NPCReadNoteCard(string Note) {
+    DEBUG("NPCReadNoteCard");             
+    lNpcCommandList = llParseString2List(osGetNotecard(Note), ["\n"], []);
+}  
+  
+integer SenseAvatar()
+{
+    //Returns a strided list of the UUID, position, and name of each avatar in the region
+    list avatars = llGetAgentList(AGENT_LIST_REGION ,[]);
+    integer numOfAvatars = llGetListLength(avatars);
+    if (numOfAvatars == 0)
+    {
+        DEBUG("No people");
+        return 0;
+    }
+    //DEBUG("Located " + (string)numOfAvatars + " avatars and NPC's"); 
+        
+    integer nAvatars;
+    integer i;
+    for( i = 0;i < numOfAvatars; i++) {
+        key aviKey = llList2Key(avatars,i);
+        if (!osIsNpc(aviKey)) {
+            list detail = llGetObjectDetails(aviKey,[OBJECT_POS]);
+            vector pos = llList2Vector(detail,0);
+            float dist = llVecDist(pos, llGetPos());
+            if (dist  < RANGE)
+            {
+                nAvatars++;
+                DEBUG("In range:" + llKey2Name(aviKey));
+            }
+        }
+    }
+    //DEBUG("Located " + (string) nAvatars + " avatars");
+    return nAvatars;
+} 
+ 
+// return TRUE if the avatar is owner when private is set, or TRUE if the avatar is in the same group and GROUP is set.
+integer checkPerms() {
+
+    integer group = (integer) KeyValueGet("pr");
+    if (! group)
+        priPub = "Owner Only";
+    else
+        priPub = "Group";
+    
+    
+    if (llDetectedKey(0) == llGetOwner()){
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+ 
+    if ( group && llDetectedGroup(0)) {
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+    kUserKey = llDetectedKey(0);
+    return FALSE;
+}
+
+
+
+NPCAnimate(string anim)
+{
+    DEBUG("Start Anim: " + anim);
+    if (llGetInventoryType(anim) == INVENTORY_ANIMATION ) {
+        
+        if (lastANIM != anim) {
+            if(llStringLength(lastANIM)) {
+                osNpcStopAnimation(NPCKey(), lastANIM);  
+            }
+            osNpcPlayAnimation(NPCKey(), anim);
+            lastANIM = anim;
+        }            
+    } else {
+        llSay(DEBUG_CHANNEL, "No animation named " + anim);
+    }
+} 
+
+// Kill a NPC by Name
+Kill(string param)
+{
+    integer count;
+    list avatars = osGetAvatarList(); // Returns a strided list of the UUID, position, and name of each avatar in the region except the owner.\    
+    integer i;
+    integer j = llGetListLength(avatars);
+    for (i=0 ; i <= j; i+=3){
+        
+        string desired = llList2String(avatars,i+2);
+        desired = llStringTrim(desired,STRING_TRIM);    // should not be needed but is needed
+        
+        if (desired == param){
+            vector v = llList2Vector(avatars,i+1);
+            key target = llList2Key(avatars,i);    // get the UUID of the avatar
+            osNpcRemove(target);
+            SaveKey(NULL_KEY );  
+            llOwnerSay("Removed " + param+ " at  location " + (string) v);
+            count++;
+        }
+    }
+    
+    NPCEnabled = FALSE; // not in world
+    
+    if (count)
+        llOwnerSay("Removed " + (string) count + " NPC's");
+    else
+        llOwnerSay("Could not locate " + param);
+}
+
+
+// return a String for the position we are at. Strings used as the caller wants strings
+string Pos()
+{
+    vector where = llGetPos(); // find the box position
+   
+    where.z +=    OffsetZ;  // use the ground position + an offset 
+        
+    if (LSLEditor)
+        where  = <128,128,31 + llFrand(1)>; // force center of sim when editing
+   
+   // if attached the height will be too high by 1/2 the agent size
+    if (llGetAttached()) {
+        vector size = llGetAgentSize(llGetOwner());   
+        float Z = size.z;
+        where.z -= Z/2;  
+    }
+   
+    // DEBUG("Pos= " + (string) where);
+    return (string) where;
+}
+
+// setup a menu with a timer for timeouts, called by all make*()
+menu()
+{
+    llListenRemove(iHandle);
+    iChannel = llCeil(llFrand(100000) + 20000);
+    iHandle = llListen(iChannel,"","","");
+    TimerEvent(30.0);
+    MENU = TRUE;
+}
+
+// make a text box
+makeText(string Param)
+{ 
+    menu();
+    llTextBox(kUserKey, Param, iChannel);
+}
+
+// top level menu
+makeMainMenu()
+{
+    menu();
+    list buttons = ["Appearance","Recording","Save","Help","-","Erase RAM", priPub,relAbs,"-","Stop NPC",mSensor,"Start NPC"];
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Records",buttons,iChannel);
+}
+
+
+// Rev 1.4
+// top level menu for non group/ non owners
+makeUserMenu()
+{
+    if (!allowUsers) return;
+    
+    menu();
+    list buttons = ["Start NPC","Stop NPC"];
+    llDialog(kUserKey,"Choose",buttons,iChannel);
+}
+
+
+
+// programmable menu for @commands
+makeMenu(list buttons)
+{
+    menu();
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Record",buttons,iChannel);
+}
+
+
+// make one or two text boxes with prompts
+Text(string cmd, string p1, string p2)
+{
+    sCommand = cmd;
+     sParam2 = "";
+    if (llStringLength(p2))
+        sParam2 = p2;
+
+    makeText(p1);
+} 
+
+// Set the Avatar Present flag - if sensors are off and we are forece run, there will be one present.
+ProcessSensor()
+{
+    integer SensorOn;
+    if ("on" == KeyValueGet("se"))
+    {
+        SensorOn = TRUE;        // we need to scan for avatars
+    } else {
+        SensorOn = FALSE;        // we need to scan for avatars
+    }
+    DEBUG("Sensor:" + (string) SensorOn);
+    
+    integer n = SenseAvatar();
+    
+    DEBUG("Avatars:" + (string) n);
+    if (SensorOn && n)
+        avatarPresent = TRUE;   // someone is here and we need to tell the system to run
+    else if (SensorOn && !n)
+        avatarPresent = FALSE;  // someone is not here and we need to tell the system to stop
+    else {       // sensor is off, lete see if there is a NPC. If so, we are ON 
+        DEBUG("NPCEnabled:" + (string) NPCEnabled);
+        if (NPCEnabled)
+            avatarPresent = TRUE;  
+        else
+            avatarPresent = FALSE;   
+    }
+    
+    //  start up from when when no one is near
+    if (avatarPresent && STATE == NobodyHome)
+        STATE = 0;
+    
+    DEBUG("Avatar Present: " + (string) avatarPresent);
+}
+
+vector CirclePoint(float radius) {
+    float x = llFrand(radius *2) - radius;        // +/- radius, randomized
+    float y = llFrand(radius *2) - radius;        // +/- radius, randomized
+    return <x, y, 0>;        // so this should always happen
+}
+
+string KeyValueGet(string var) {
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k != var) jump continue;
+        //DEBUG("got " + var + " = " +  llList2String(data, 1));
+        return llList2String(data, 1);
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    return "";
+} 
+
+KeyValueSet(string var, string val) {
+
+    //DEBUG("set " + var + " = " + val);
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    if(llGetListLength(dVars) == 0)
+    {
+        llSetObjectDesc(var + "=" + val);
+        return;
+    }
+    list result = [];
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k == "") jump continue;
+        if(k == var && val == "") jump continue;
+        if(k == var) {
+            result += k + "=" + val;
+            val = "";
+            jump continue;
+        }
+        string v = llList2String(data, 1);
+        if(v == "") jump continue;
+        result += k + "=" + v;
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    if(val != "") result += var + "=" + val;
+    llSetObjectDesc(llDumpList2String(result, "&"));
+}
+
+
+// clear RAM
+Clr() {
+
+    lCommands = [];
+    llOwnerSay("RAM Memory cleared. Notecards, if any, are not modified.");
+    makeMainMenu();
+}
+
+integer checkNoteCards()
+{
+    // Check that they have saved an Appeaance and Path notecard
+    integer num = llGetInventoryNumber(INVENTORY_NOTECARD);    // how many notecards overall
+    
+    integer i;
+    integer count;
+    for (; i < num; i++){
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Notecard)
+            count++;
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Appearance)
+            count++;
+    }
+    DEBUG("Checked " + (string) count + " Notecards");
+    // if we have both, run the NPC
+    return count;
+}
+
+Update(string SName) {
+         
+    // delete all NPC* scripts except myself
+    integer i;
+    integer j = llGetInventoryNumber(INVENTORY_SCRIPT);
+    for (i = 0; i < j; i++) {
+        string targetName = llGetInventoryName(INVENTORY_SCRIPT,i);
+        string match = llGetSubString(targetName,0,2);
+        
+        if (match == SName && llGetScriptName() != targetName){
+                llOwnerSay("Upgrading " + targetName);
+            if (! LSLEditor){        // lets not kill the editor
+                llRemoveInventory(targetName);
+            }
+        }
+    }
+}
+
+// Get all default saved params from the Description
+GetSwitches()
+{
+         string rA = KeyValueGet("co"); // Get the remembered menu setting for Abs Vs Relative
+        if (rA == "A")
+            relAbs = "Absolute";
+        else  if (rA == "R")
+            relAbs = "Relative";
+        else
+            relAbs = "Absolute";
+
+            
+        // reenable NPC if sensor is on.
+        if ("on" == KeyValueGet("se"))
+        {
+            NPCEnabled = TRUE;
+            mSensor  = "Sense is On";
+            ProcessSensor();       // fake 1 avatar to get it rezzed
+        } else {
+            mSensor  = "Sense is Off";
+        }
+    }
+
+
+SaveKey(key akey)
+{
+    DEBUG("Saving Key of " + (string) akey);
+    KeyValueSet("key", akey);
+    if (akey !=  (key) KeyValueGet("key") )
+    {
+        DEBUG("Fatal error, cannot save key");
+    }
+    gNpcKey = akey;
+}
+
+
+key NPCKey()
+{
+    key akey = gNpcKey;   // from cached copy
+    // gNpcKey saves a lot of CPU processing by caching the key, if blank we get it from the description
+    if (gNpcKey == NULL_KEY)
+    {
+        //DEBUG("Get DKey");
+        akey = KeyValueGet("key");    // from Description of the prim
+    }
+   // DEBUG("NPC KEY:" + (string) akey);   
+    return  akey;
+}
+
+
+/////////////////// CODE BEGINS //////////////////
+
+
+default
+{
+    changed(integer change) {
+        if(change & CHANGED_REGION_START) {
+            llResetScript();
+        }
+    }
+    
+    on_rez(integer start_param)
+    {
+        llResetScript();
+    }
+
+    state_entry() {
+        
+        llSetText("",<1,1,1>,1.0);  // clr all hovertext- we may not be using it.
+        DoDelete(); // kill any NPC that is out running
+        Update("NPC"); // If dragged and ropped into a prim with any script named "NPC...", this will replace it.
+        GetSwitches(); // Get all default saved params from the Description
+
+        // 4.1 allow listeners to send us commands
+        if (allowListener)
+            llListen(link_Channel,"","","");
+        TimerEvent(TIMER);
+    } 
+
+
+    touch_start(integer n) 
+    {           // if touched, make a menu
+    
+        if (checkPerms()) {
+            if (RecordPath == STATE) {
+                makeMenu(lAtButtons); 
+            }   else {
+                makeMainMenu();
+            }
+        } else {
+            makeUserMenu();
+        }
+    }
+
+    // menu listener
+    listen(integer iChannel, string name, key id, string message) {
+
+        // process @commands that come in via the listener
+        if (iChannel == link_Channel)
+        {
+            ParseMsg(message);
+            return;
+        }
+        
+        if (MENU) {
+            llListenRemove(iHandle);
+            MENU = 0;       // menu is off
+            iHandle = 0;
+        }
+        
+        if (message == "Stop NPC")
+        {
+            lNpcCommandList = []; // force reload of notecard
+            NPCEnabled = FALSE;
+            if (NPCKey() != NULL_KEY){
+                Kill(sNPCName);
+                sNPCName = "";
+            } else {
+                bNPC_STOP = TRUE;
+                makeText("Enter name of an NPC to stop");
+            }
+        }
+        else if (message == "Menu" ) {
+            makeMainMenu();
+        }
+        else if (message == "Erase RAM"){
+            Clr();
+        }
+        else if (message == "Relative"){
+            relAbs = "Absolute";
+            KeyValueSet("co","A");   // remember coordinates = A
+            Clr();
+        }
+        else if (message == "Absolute"){
+            relAbs = "Relative";
+            KeyValueSet("co","R");   // remember coordinates = R
+            Clr();
+        }
+        else if (message == "Recording"){
+            DoMenuForCommands();        // show them the recording menu
+        }
+        else if (message == "Owner Only") {
+            priPub = "Group";
+            KeyValueSet("pr","1");
+
+            llOwnerSay("Group members have control");
+            makeMainMenu();
+        }
+        else if (message == "Group") {
+            priPub = "Owner Only";
+            KeyValueSet("pr","0");
+            llOwnerSay("Only you have control");
+            makeMainMenu();
+        }
+        else if (message == "Sense is On") {
+            mSensor ="Sense is Off";
+            KeyValueSet("se", "off");
+            llOwnerSay(mSensor);
+            makeMainMenu();
+        }
+        else if (message == "Sense is Off") {
+            mSensor ="Sense is On";
+            llOwnerSay(mSensor);
+            KeyValueSet("se", "on");
+            
+            NPCEnabled = FALSE;
+            
+            integer count = checkNoteCards();
+            if (count >= 2)  {
+                DEBUG("Notecards ok, DoProcessNPCLine");
+                DoProcessNPCLine();
+                return;
+            }
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording and/or appearance, so you cannot start a NPC");
+            makeMainMenu();
+        }
+        else if (message == "Appearance")  {
+            llRemoveInventory(Appearance);            // delete the notecard
+            osAgentSaveAppearance(kUserKey,Appearance);    // make the ntecard 
+            llOwnerSay("Your outfit has been saved");
+            makeMainMenu();
+        }
+        else if (message == "Save") {
+            if (llGetListLength(lCommands) == 0) {
+                llOwnerSay("Nothing recorded, you need to make a recording first");
+                makeMainMenu();
+                return;
+            }
+            DoSave();
+        }
+        else if (message == "Help"){
+            llLoadURL(kUserKey,"Click to view help","http://www.outworldz.com/opensim/posts/NPC/");
+            makeMainMenu();
+        }
+        else if (message == "Start NPC")    {
+            integer count = checkNoteCards();
+
+            NPCEnabled = TRUE;
+
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+            
+            if (count >= 2) {
+                DEBUG("Notecards approved , calling DoProcessNPCLine");
+                SetStop(FALSE); // Let's run the notecard
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording or maybe an appearance, so we cannot start a NPC");
+      
+        }
+        else if (bNPC_STOP){
+            bNPC_STOP = FALSE;
+            Kill(message);
+        }
+        else if (message == ">>"){
+            makeMenu(lMenu2);
+        }
+        else if (message == ">>>"){
+            makeMenu(lMenu3);
+        }
+        else if (message == "<<") {
+            makeMenu(lAtButtons);
+        }
+        else if (message == "<<<") {
+            makeMenu(lMenu2);
+        }
+        else if (message == "@comment"){
+            Text("# ","Enter a comment","");
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@run"){
+            lCommands += "@run=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@fly"){
+            lCommands += "@fly=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@land"){
+            lCommands += "@land=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@walk") {
+            lCommands += "@walk=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@sound"){
+            Text("@sound=","Enter a sound name or UUID to trigger","");
+        }
+        else if (message == "@randsound"){
+            lCommands += "@randsound"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@say") {
+            Text("@say=","Enter what the NPC will say","");
+        }
+        else if (message == "@whisper"){
+            Text("@whisper=","Enter what the NPC will whisper","");
+        }
+        else if (message == "@shout"){
+            Text("@shout=","Enter what the NPC will shout","");
+        }
+        else if (message == "@wander") {
+            Text("@wander=","Enter radius to wander","Enter number of wanders");
+        }
+        else if (message == "@pause") {
+            Text("@pause=","Enter time to pause","");
+        }
+        else if (message == "@rotate") {
+            Text("@rotate=","Enter degrees to rotate","");
+        }
+        else if (message == "@sit"){
+            Text("@sit=","Enter name of object to sit on","");
+        }
+        else if (message == "@teleport"){
+            lCommands += "@teleport=" + Pos() + "\n";
+            llOwnerSay("teleport to position: " + Pos());
+            makeMenu(lMenu3);
+        }
+        else if (message == "@touch"){
+            Text("@touch=","Enter name of object to touch","");
+        }
+        else if (message == "@cmd"){
+            Text("@cmd=","Enter cjhannel to speak on","Enter text to speak");
+        }
+        else if (message == "@stand"){
+            lCommands += "@stand\n";
+            llOwnerSay("Stand Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@animate"){
+            Text("@animate=","Enter animation name to play","Enter time to play the animation");
+        }
+        else if (message == "@attach"){
+            Text("@animate=","Enter inventory name to attach","Enter number of the attachment point (1-40)");
+        }
+         else if (message == "@speed"){
+            Text("@speed=","Enter a speed for the NPC, 1=100% normal speed, 0.5=50% speed","");
+        }
+               
+
+        // Save NPC name
+        else if (MakeNotecard == STATE) {
+            sNPCName = message; // in case we need to kill it.
+            
+            vector  vDest = (vector)  Pos();
+
+            if (relAbs == "Relative")
+            {
+                vDest  -= llGetPos();    // just an offset for relative
+            }
+            sNotecard = "@spawn=" + message + "|" +  (string) vDest  + "\n";
+            integer i;
+            integer j = llGetListLength(lCommands);
+            for (; i < j; i++){
+                // get the command to save to the notecard
+                string line = llList2String(lCommands,i);
+                if (relAbs == "Absolute") {
+                    sNotecard += line;    // add the un-modified string to the notecard
+                } else {
+                        // since we have to record absolute coords since we do not know where the box goes until they press Save,
+                        // we process the absolute to relative conversion for walks here
+                        list parts = llParseString2List(line,["="],[]); //get the @command
+
+                    if (llList2String(parts,0) == "@walk") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@walk=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@fly") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@fly=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@run") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@run=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@land") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@land=" + (string) vec + "\n";
+                    }
+                    else {
+                        sNotecard += line;    // add the un-modified string to the notecard
+                    }
+                }
+            }
+            llRemoveInventory(Notecard);        // delete the old notecard
+            osMakeNotecard(Notecard,sNotecard); // Makes the notecard.
+            llSay(0,sNotecard);
+            llOwnerSay("Commands notecard has been written");
+            STATE = 0;
+        } // MakeNotecard
+
+        else  if (! llStringLength(sParam2)) {
+            lCommands +=  sCommand + message + "\n";
+            llOwnerSay("Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (llStringLength(sParam2)){
+            sCommand = sCommand + message + "|";
+            llOwnerSay("Recorded");
+            makeText(sParam2);
+            sParam2 = "";
+        }
+
+    }
+
+
+
+    timer(){
+       // DEBUG("tick");
+        
+        // if llDialog is up, kill the listener for the dialog box.
+        if (iHandle) {
+            llOwnerSay("Menu timed out");
+            llListenRemove(iHandle);
+            iHandle = 0;
+            return;             // ^^^^^^^^^^^^^^^^^^^^^^^
+        }
+        // if NoBodyHome, we are sensing for an avatar
+        else if (NobodyHome == STATE) {
+            ProcessSensor();
+            return;
+        }
+        // if we are spawning, we need time to rez the NPC, then start processing NPC Commands.
+        else if (Spawning == STATE) {
+            STATE = 0;
+            TimerEvent(TIMER);
+        }
+        // We end aniamtions with a timer
+        else if (Animate == STATE){
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+        }
+        
+        else if (Walking == STATE) {
+            if (--iWaitCounter) {
+                if (llVecDist(osNpcGetPos(NPCKey()), newDest) > MAXDIST)  {
+                    return;
+                }
+            }
+
+            DEBUG("At Destination: " + (string) newDest);
+            
+            // walk, fly, run, land
+            if (walkstate == 1) {
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 2)  {
+                    // nothing
+                } else if (walkstate == 3) {
+                     NPCAnimate(STAND);
+                     NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 4) {
+                llShout(FLIGHT,"landing");
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            }
+        }
+        // Wandering timer 
+        else if (Wander == STATE) {
+            if (--iWaitCounter) {          // wait 60 seconds to get to a destination.
+                if (llVecDist(osNpcGetPos(NPCKey()), vWanderPos) > MAXDIST)
+                    return;
+            }
+
+            // see if wander counter == 0, if so, stop walking, go to stand and process next line
+            if(RAMwc == 0) {
+                NPCAnimate(STAND);
+                DEBUG("Wander ended, calling DoProcessNPCLine");
+                STATE = 0;
+                DoProcessNPCLine();
+                return;
+            }
+            // one less time to wander around
+            RAMwc--;
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+            StateWanderhold();
+            return;
+        }
+        // Wandering requires us to re-wander when we reach a destination
+        else if (WanderHold == STATE) {
+            StateWander();
+            TimerEvent(TIMER);
+            return;
+        }
+        else if (DoProcess == STATE) {
+            TimerEvent(QUICK);
+        }
+
+       
+        STATE = 0;
+
+        // We always process a NPC line at end of timer.
+        DEBUG("Tick end, calling DoProcessNPCLine");
+        DoProcessNPCLine();
+    }
+
+    // sensors are used for sitting on prims
+    // Neo Cortex: added different SensorFunc states to trigger sit or touch
+    sensor(integer num) {
+        if (SensorFunc == 1) {
+            osNpcSit(NPCKey(), llDetectedKey(0), OS_NPC_SIT_NOW);
+            DEBUG("Seated, calling DoProcessNPCLine");
+            SensorFunc = 0;
+        } else if (SensorFunc == 2) {
+            osNpcTouch(NPCKey(), llDetectedKey(0), LINK_THIS);
+            DEBUG("Touched, calling DoProcessNPCLine");
+            SensorFunc = 0;
+        }
+        DoProcessNPCLine();
+    }
+    no_sensor(){
+        DEBUG ("no target prim located, calling DoProcessNPCLine");
+        SensorFunc = 0;
+        DoProcessNPCLine();
+    }
+
+    
+    link_message(integer sender, integer num, string str, key id){
+        ParseMsg(str);
+    }
+        
+}
+
+
+
+
+
+
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.3.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.3.lsl
new file mode 100644
index 00000000..3a68f8ff
--- /dev/null
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.3.lsl	
@@ -0,0 +1,1686 @@
+// :SHOW:1
+// :CATEGORY:NPC
+// :NAME:All In One NPC Recorder and Player
+// :AUTHOR:Ferd Frederix
+// :KEYWORDS:NPC, Puppeteer
+// :CREATED:2015-09-24 14:25:15
+// :EDITED:2015-09-24  13:25:15
+// :ID:27
+// :NUM:1829
+// :REV:4.3
+// :WORLD:OpenSim
+// :DESCRIPTION:
+// All in one NPC recorder player.
+// Supports both absolute and relative paths and many new commands
+// Add animations named "Fly, Walk, Stand and Run"
+// Click Prim to use.
+// Should be worn as a HUD to record.
+// Put it on the ground and click Sensor or Start NPC when done.
+// :CODE:
+// This is Rev 4.3  09/24/2015
+
+// Revision History
+// Rev 1.1 10-2-2014 @Sit did not work.  Minor tweaks to casting for lslEditor
+// Rev 1.2 10-14-2014 @ sit had wrong type.
+// Rev 1.3 relative movement fixed for @fly
+// Rev 1.4 4-3-2014 allow anyone to use this, non owners and non group members can only start and stop.
+// Rev 1.5 5-17-2014 set sensor to auto start on reboot of sim
+// Rev 1.6 5-24-2014 move menu so you can get it by touching, removed many of the KeyValues to RAM for efficiency
+// Rev 1.7 CHANGED_REGION_START, not CHANGED_REGION_START (Opensim difference)
+// Rev 1.8 tuned up Kill NPC, added more flexible upgrader
+// Rev 1.9 Better script injection by link message// Rev 2.0 Added osSetSpeed so you can speed up or slow down an NPC.
+// Rev 2.1 No laggy sensor used exept to sit on stuff
+// Rev 2.2 Various sensor fixes
+// Rev 2.3 Sets No Sensor in menu, must be started by hand
+// Rev 2.4 - reserved for patches to 2.3 if needed
+// Rev 3.0 Refactor out into subs, not states to make command injection easier
+//            New command: @appearance=Notecardname so you can switch to a new notecard on the fly
+//            New command: @speed=1.0  which slows up  ( < 1 )  or speeds up ( > 1)
+// Rev 3.1 Commands are not interruptible by Link Message
+// Rev 3.2 Sensor patches for consistency in removing the NPC
+// Rev 3.3 Added Touch command by Neo.Cortex@hbase42/hopto/org:8002
+//         Added Menu 3 for notecard and appearance commands
+// Rev 3.4 animation timer cannot be zero or it shuts off timer tweaked
+//         solves the NPC starting up when no sensor is set.
+// Rev 3.5 fixes saving to !Path  notecard
+// Rev 3.6 08-11-2015 @delete acts like @stop. TYjhe NPC now rezzes after an @go back in where it was deleted 
+// Rev 3.7 08-11-2015 @attach command added to load an attachment from the inventory to the NPC
+// Rev 3.8 08-17-2015 process queued commands one at a time without calling ProcessNPCLine on link message
+// Rev 3.9 08-23-2011 Queued command fixes including @delete which were not always working
+// Rev 4.0 09-15-2015 Fixes for Sensor functions which continually rezzed a NPC when no one was around.
+// Rev 4.1 09-20-2015 Added a Listener so link messages are not needed
+// Rev 4.2 09-23-2015 Added @teleport=<vector>
+// Rev 4.3 09-24-2015 Added @reset to restart the NPC at the very start of the !Path notecard
+//                    @teleport works for relative and absolute modes
+
+//*******************************************************************//
+
+// Instructions on how to use this are at http://www.outworldz.com/opensim/posts/NPC/
+// This is an OpenSim-only script.
+// Author: Ferd Frederix aka Fred Beckhusen - fred@mitsi.com
+
+////////////////////////////////////////////////////////////////////////////////////////////
+//    Original code was Copyright (C) 2013 Wizardry and Steamworks - License: GNU GPLv3    //
+///////////////////////////////////////////////////////////////////////////////////////////
+//  Please see: http://www.gnu.org/licenses/gpl.html for legal details,                  //
+//  rights of fair usage, the disclaimer and warranty conditions.                        //
+///////////////////////////////////////////////////////////////////////////////////////////
+// The original NPC controller was from http://was.fm/opensim:npc
+// Extensive additions and bug fixes by Fred Beckhusen, aka Ferd Frederix
+// llSensor had two params swapped
+// @Wander would wander where it had rezzed, not where it was.
+// There was no 'no_sensor' event in sit, so if a @sit failed, the NPC got stuck
+// The animation and walks always stopped old, then started new.  It should be start new, then stop old so the default stand would be suppressed.
+// New code:
+// Merged with new Route recorder and notecard writer
+// If the NPC failed to reach a destination it never moved on.
+// Added WAIT global to tune this
+// Exposed many tunable variables and ported the code 
+// Added floating point to times in notecard.
+// Added @sound, @randsound, @whisper, @shout, and @cmd controls.
+// notecards integers are not floats for better control
+// 
+// Link Messages may be used to perform external control by injecting @commands into the stream of actions
+// Example:
+// To chat something, such as with a chat robot
+//  llMessageLinked(LINK_SET,0,"@npc_say=Hello","");
+
+// This script assumes that NPCs and OSSl scripting is enabled in the OpenSim configuration.
+// In order to enable them, the following changes must be made in the OpenSim.ini configuration file:
+//
+// ; Turn on OSSL
+// AllowOSFunctions = true
+// OSFunctionThreatLevel = Severe
+
+//[NPC]
+//    ;# {Enabled} {} {Enable Non Player Character (NPC) facilities} {true false}
+//    Enabled = true
+//
+// and then the server has to be restarted.
+// please note that there are better ways to enable NPC in the latest Opensim.  
+
+// Commands: All commands begin with an @ sign.  All other lines are ignored
+// @commands may have optional parameters.  The syntax is always:
+//  @cmd=parm1|parm2
+//  NaN in the table below meand Not a Number.   This means there is no parameter
+
+//Command     First Parameter             Second Parameter        Description
+//@spawn      name                        location (vector)       Rezzes an NPC with name at a location.
+//@appearance NoteCardName                NaN                     switch the NPC appearance to a new notecard
+//@walk       destination (vector)        NaN                     Makes the NPC walk to destination.
+//@fly        destination (vector)        NaN                     Makes the NPC fly to destination.
+//@land       destination (vector)        NaN                     Makes the NPC land at destination.
+//@say        string                      NaN                     Makes the NPC speak a phrase.
+//@whisper    string                      NaN                     Makes the NPC whisper a phrase.
+//@shout      string                      NaN                     Makes the NPC shout a phrase.
+//@pause      seconds (float)             NaN                     Makes the NPC wait for a multiple of seconds.
+//@wander     radius (float)              cycles (integer)        Makes the NPC wander in radius, for cycles seconds.
+//@delete     NaN                         NaN                     Removes the NPC.  Requires a link message to continue
+//@goto       label (string)              NaN                     Jump to the label label in the script.
+//@animate    animation (string)          time (float)            Makes the NPC trigger the animation animation for time seconds.
+//@sound      sound_name                  NaN                     plays a sound from inventory
+//@randsound  NaN                         NaN                     Plays a random sound from inventory
+//@rotate     degrees (float)             NaN                     Rotate the NPC degrees around the Z axis.
+//@sit        primitive name              NaN                     Sit on a primitive with a given name.
+//@touch      primitive name              NaN                     Touch on a primitive with a given name.
+//@stand      NaN                         NaN                     If sitting on a primitive, stand up.
+//@cmd        channel (integer)           string                  Says string on channel, for controlling external gadgets
+//@stop       NaN                         NaN                     Halts the NPC script indefinitely. Can be started with a link message
+//@go         NaN                         NaN                     Continues on next notecard line, for use in link messages
+//@speed      speed (float)               NaN                     from 0 to N, where 1.0 ius a normal speed of an avatar.  0.2 is a turtle.
+//@notecard   notename (string)           NaN                     load a new Path notecard
+//@attach     InventoryName               attachmentPoint         load an attachment from the inventory to the NPC onto point
+//@teleport   destination (vector)        NaN                     Makes the NPC teleport to destination in the same sim.  They cannot tp to another sim or across the HG
+//@reset      NaN                         NaN                     Deletes the NPC, starts the !Path notecard over.
+ 
+// Constant            attachmentPoint Comment
+// ATTACH_CHEST            1    chest/sternum
+// ATTACH_HEAD             2    head
+// ATTACH_LSHOULDER        3    left shoulder
+// ATTACH_RSHOULDER        4    right shoulder
+// ATTACH_LHAND            5    left hand
+// ATTACH_RHAND            6    right hand
+// ATTACH_LFOOT            7    left foot
+// ATTACH_RFOOT            8    right foot
+// ATTACH_BACK             9    back
+// ATTACH_PELVIS          10    pelvis
+// ATTACH_MOUTH           11    mouth
+// ATTACH_CHIN            12    chin
+// ATTACH_LEAR            13    left ear
+// ATTACH_REAR            14    right ear
+// ATTACH_LEYE            15    left eye
+// ATTACH_REYE            16    right eye
+// ATTACH_NOSE            17    nose
+// ATTACH_RUARM           18    right upper arm
+// ATTACH_RLARM           19    right lower arm
+// ATTACH_LUARM           20    left upper arm
+// ATTACH_LLARM           21    left lower arm
+// ATTACH_RHIP            22    right hip
+// ATTACH_RULEG           23    right upper leg
+// ATTACH_RLLEG           24    right lower leg
+// ATTACH_LHIP            25    left hip
+// ATTACH_LULEG           26    left upper leg
+// ATTACH_LLLEG           27    left lower leg
+// ATTACH_BELLY           28    belly/stomach/tummy
+// ATTACH_LEFT_PEC        29    left pectoral
+// ATTACH_RIGHT_PEC       30    right pectoral
+// ATTACH_HUD_CENTER_2    31    HUD Center 2
+// ATTACH_HUD_TOP_RIGHT   32    HUD Top Right
+// ATTACH_HUD_TOP_CENTER  33    HUD Top
+// ATTACH_HUD_TOP_LEFT    34    HUD Top Left
+// ATTACH_HUD_CENTER_1    35    HUD Center
+// ATTACH_HUD_BOTTOM_LEFT 36    HUD Bottom Left
+// ATTACH_HUD_BOTTOM      37    HUD Bottom
+// ATTACH_HUD_BOTTOM_RIGHT 38   HUD Bottom Right
+// ATTACH_NECK            39   neck
+// ATTACH_AVATAR_CENTER  40    avatar center/root
+
+
+  
+//////////////////////////////////////////////////////////
+//                  DEBUG                               //
+//////////////////////////////////////////////////////////
+integer debug = TRUE;         // set to TRUE or FALSE for debug chat on various actions
+integer LSLEditor = TRUE;        // set to to TRUE to working in  LSLEditor, FALSE for in-world.
+                              // you must also include the NPC commands found in the other script since LSLEditor does not support OpenSim
+integer iTitleText = FALSE;    // set to TRUE to see debug info in text above the controller
+ 
+//////////////////////////////////////////////////////////
+//                  TUNABLE CONFIGURATION               //
+//////////////////////////////////////////////////////////
+integer   allowListener = TRUE; // set to TRUE to anable a command listener. Usually, this is setto FALSE
+integer   link_Channel =   4223; // some random number you want to talk to this gadget on. Best if large and negative
+float     TIMER = 2;         // faster = less jerky stopping.  How often the system checks the distance traveled.  Fastest you can go is 0.5 seconds
+float     QUICK = 1;        // when we need to move to the next state, we use a QUICK timer
+string    Appearance = "!Appearance";  // The name of the recorded Appearance notecard
+string    Notecard = "!Path"; // The name of the recorded routes
+integer   allowUsers = FALSE;  // If true, any user can get a Start NPC and Stop NPC menu.  Only groups and owners can get all commands if TRUE, or FALSE
+float     MAXDIST = 2.0;       // how close a NPC has to get to a dest pos to continue to next state. Do not lower this too much, as it may miss the target
+integer   WANDERRAND = TRUE;   // set to TRUE and they will pause during wanders a random number of seconds
+float     WANDERTIME = 3.0;    // how long they stand after each @wander,if WANDERRAND is FALSE. If WANDERRAND is  TRUE, this is the max time
+integer   WAIT = 30;           // wait for this number of seconds for the NPC to reach a destination (for safety). If it fails to reach a target, it will move on after this time.
+float     RANGE = 50;        // 1 to N meters  - anyone this close to the controller will start NPCS if Sensor button is clicked
+float     REZTIME = 2.0;      // wait this long for NPC to rez in, then start the process
+string    STAND = "Stand";     // the name of the default Stand animation
+string    WALK = "Walk";       // the name of the default Walk animation
+string    FLY = "Fly";        // the name of the default Fly animation
+string    RUN = "Run";        // the name of the default Run animation
+string    LAND = "Land";      // the name of the default land animation ( for birds only)
+float     OffsetZ = 0.5;      // appear 0.5 meter above ground, this is added to all destinations to keep them from sinking in.  
+float    SPEEDMULT =0.5;     // 1.0 = regular avatar speed. Smaller numbers slow down walks. Large numbers speed them up.
+integer  FLIGHT = 299;        // For controlling wings.  A channel that is shouted at when flight starts and ends. "flying" or "landing" 
+
+// DESCRIPTIONS FIELDS HAVE TO SURVIVE A RESET
+//  These vars are stored  by saving them with KeyValueSet
+// "pr" is a 0 if it is set for Owner Only, 1 for Group control
+// "se" is "on" if Started
+// "co" = "R" or "A" for relative or absolute addressing mode
+// "key" = NPC key
+
+// These Globals used to be stored in description.   Moved to RAM in V1.6
+float RAMPause;          // @pause param
+float RAMwd ;            // @wander distance
+integer RAMwc;           // @wander count
+float RAMrot;            //  @rotate
+string RAMsit;           // @sit primname
+string RAMtouch;         // @touch primname
+string RAManimationName; // @animate animation (string) time (float)
+float RAManimationTime;
+
+// other globals section
+integer iChannel;        // a listen channel, randomly assigned
+integer iHandle;         // the handle to it
+
+// NPC controls
+vector newDest ;                // tmp storage for the walks
+integer iWaitCounter ;          // wait for this number of seconds for the NPC to reach a desrtination
+string sNPCName;                // the name of the NPC that may be in world. So we can remove it.
+integer bNPC_STOP = FALSE;      // boolean to reuse a listener
+integer Stopped = FALSE;        // set to TRUE by link messages so we do not remember them
+float  fTimerVal ;              // how long we wait when wandering (calculated)
+float NPCEnabled;               // true if the NPC is suppodes to be running
+
+// OS_NPC_CREATOR_OWNED will create an 'owned' NPC that will only respond to osNpc* commands issued from scripts that have the same owner as the one that created the NPC.
+// OS_NPC_NOT_OWNED will create an 'unowned' NPC that will respond to any script that has OSSL permissions to call osNpc* commands.
+integer  NPCOptions = OS_NPC_CREATOR_OWNED;    // only yhe owner of this box can control this NPC.
+
+integer walkstate = 0;  // helps us reshare the walk state for run, fly and land - a bit of a hack, but it saves RAM. Has to be done this way because some bits of NPCWalkOption are asserted as 0
+
+integer NPCWalkOption;   // Some notes for what happens to NPCWalkOption:
+// OS_NPC_FLY - Fly the avatar to the given position. The avatar will not land unless the OS_NPC_LAND_AT_TARGET option is also given.
+// OS_NPC_NO_FLY - Do not fly to the target. The NPC will attempt to walk to the location. If it's up in the air then the avatar will keep bouncing hopeless until another move target is given or the move is stopped
+//OS_NPC_LAND_AT_TARGET - If given and the avatar is flying, then it will land when it reaches the target. If OS_NPC_NO_FLY is given then this option has no effect.
+// OS_NPC_RUNNING - if given, NPC avatar moves at running/fast flying speed, otherwise moves at walking/slow flying speed.
+
+// menus
+string mSensor="Sense is Off";    // Sensor or "No Sensor"
+
+list lAtButtons = ["Menu","-",   ">>",         "@run",    "@walk",   "@fly",  "@land", "@wander",    "@sit",   "@stand","@animate","@rotate"];
+list lMenu2 = ["<<", "@comment", ">>>",        "@stop",      "@say",    "@whisper","@shout","@sound","@randsound","@cmd",  "@pause",  "@delete"];
+list lMenu3 = ["<<<","@notecard","@appearance", "@touch", "@speed",       "@attach",     "@teleport","-", "-", "-", "-", "-" ];
+
+string sCommand;  // place to store a command for two-prompted ones
+string sParam2;   // place to store a prompt for two-prompted ones
+string priPub = "Owner Only";    // Private or Group
+key kUserKey;        // the person who is controlling the avatar, not the Owner  
+// the command lists
+list lCommands;  // commands are stored here
+list lNpcCommandList; // Storage for the NPC script.
+string npcAction; // Storage for the next action. @cmd=0|hello, this becomes @cmd
+string npcParams; // Storage for the param, @cmd=0|hello, this becomes 0|hello
+
+// misc vars
+string sNotecard; // commands are stored here temporarily for dumping
+vector  vWanderPos; // a place to wander to
+string lastANIM ;   // last animation run
+// Sensor
+integer avatarPresent;   // Sensor sets this flag when people are within Range.
+
+// Coordinate control
+vector vInitialPos ; // Vector that will be filled by the script with the initial starting position in region coordinates.
+vector vDestPos = ZERO_VECTOR; // Storage for destination position.
+string relAbs = "Relative";    // absolute vs relative positioning
+
+
+// STATES
+integer MENU ;             // processing a dialog box state, may be concurrent with STATE
+integer STATE;             // state storage
+integer MakeNotecard = 1;  // displaying a text box for NPC name
+integer RecordPath = 2;    // displaying a path notecard menu
+integer NobodyHome = 3;    // looking for an avatar
+integer Spawning = 4;      // spawning an avatar
+integer Animate = 5;       // animation timer needed
+integer Walking = 6;       // Hey! I am walking here!
+integer Wander = 7;        // Wandering around neeeds a timer, too
+integer WanderHold = 8;    // We reached a wander point
+integer DoProcess = 9;     // Set this to make it process a new command
+integer Touch = 10;        // Timer is busy sensing something to touch
+integer Sit = 11;          // Timer is busy sensing something to sit on
+integer Paused = 12;       // Timer is busy pausing
+
+key gNpcKey = NULL_KEY;   // global key storage for the one NPC, to save CPU cycles
+list Stack ;              // a command stack from link message input
+
+integer SensorFunc = 0;    // define which function shall be triggered inside the sensor function
+                           // 0 means none, 1 sit, 2 touch
+///////////////////////////////////////////////////////////////////////////
+//                              FUNCTIONS                                //
+///////////////////////////////////////////////////////////////////////////
+
+
+TimerEvent(float timesent)
+{
+    if (LSLEditor)
+        timesent *= 5;   // slow thinggs doen when the LSLEDITOR is in use
+        
+    DEBUG("Setting  timer: " + (string) timesent);
+    llSetTimerEvent(timesent);
+}
+
+// for 4.1 parse a message from a Listen or a Link message
+ParseMsg(string str) {
+    DEBUG("Command In:" + str);
+    if (str=="@go") {
+        SetStop(FALSE); // Let's run the notecard
+        DEBUG("@go running");
+        DoProcessNPCLine();
+    } else {
+        Stack += [str];    // take anything, the controller will filter away non @ stuff
+        if (STATE == 0) {
+            DEBUG("calling DoNPC");
+            DoProcessNPCLine();
+        } else{
+            DEBUG("Queued");
+        }
+    }
+}
+
+SetStop(integer what)
+{
+    DEBUG("Stopped set to " + (string ) what);
+    Stopped = what;
+}
+// Do* functions are much like states from the old V2 scripts.
+    
+// Save a Path notecard
+DoSave()
+{ 
+    STATE = MakeNotecard;
+    makeText("Stand where you want the NPC to appear, and enter the NPC Name");
+}
+
+// This function is used to record the path for the NPC
+// Each command can take 0, 1, or 2 params
+DoMenuForCommands() {
+    makeMenu(lAtButtons);
+}
+
+
+// No one is here when sensors were on, so we kill off the NPC
+DoNobodyHome()
+{
+    DEBUG("Nobody Home");
+    STATE = NobodyHome;
+    if (NPCKey() != NULL_KEY) {
+        osNpcRemove(NPCKey());
+        SaveKey(NULL_KEY);
+    }
+    TimerEvent(5);  // keep ticking to sense avatars   
+}
+
+// Create a NPC
+StateSpawn() {
+    DEBUG("state spawn");
+    STATE = Spawning;
+
+ 
+    NPCEnabled = TRUE; //  in world
+    // see if there is already one out there.
+    if (NPCKey() != NULL_KEY) {
+        DEBUG("Already living");
+        return;
+    }
+    
+        
+    list name = llParseString2List(sNPCName, [" "], []);
+   
+     vector vRezPos = vInitialPos;
+    if (relAbs == "Relative"){
+        vRezPos += llGetPos();
+    }
+
+    DEBUG("Rezzing the  NPC:" + (string) vRezPos);
+    key aKey = osNpcCreate(llList2String(name, 0), llList2String(name, 1), vRezPos, Appearance, NPCOptions);
+
+    SaveKey(aKey); // save in desceription and global, too
+    
+    osSetSpeed(aKey,SPEEDMULT);   // 1.9 speed multiplier
+    TimerEvent(REZTIME);
+    NPCAnimate(STAND);
+}
+ 
+DoRotate() {
+    DEBUG("@rotate=" + (string) RAMrot); 
+    osNpcSetRot(NPCKey(), llEuler2Rot(<0,0,RAMrot> * DEG_TO_RAD));
+}  
+
+StateSit() {
+    DEBUG ("state sit - looking for " + RAMsit);
+    STATE=Sit;
+    SensorFunc = 1; //triggers osNpcSit
+    llSensor(RAMsit, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+
+StateTouch() {
+    DEBUG ("state touch - looking for " + RAMtouch);
+    STATE = Touch;
+    SensorFunc = 2; //triggers osNpcTouch
+    llSensor(RAMtouch, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+ 
+DoStand() {
+    DEBUG("state stand");
+    osNpcStand(NPCKey());
+}
+
+
+StateAnimate() {
+    
+    DEBUG("state animate");
+    STATE = Animate;
+    NPCAnimate(RAManimationName);
+    if (RAManimationTime <=0 )    // V 3.4 tweak
+        RAManimationTime = 1;
+    TimerEvent(RAManimationTime);
+}
+    
+StateWalk() {
+
+    DEBUG("NPCWalkOption = " + (string) NPCWalkOption);
+    STATE = Walking;
+            
+    // walk, fly, run, land
+   if (walkstate == 1) {
+        NPCAnimate(WALK);
+    } else if (walkstate == 2)  {
+        llShout(FLIGHT,"flying");
+        NPCAnimate(FLY);
+    } else if (walkstate == 3) {
+        NPCAnimate(RUN);
+    } else if (walkstate == 4) {
+        NPCAnimate(LAND);
+    } 
+    newDest = vDestPos ;
+    newDest.z += OffsetZ;
+        
+    // notecard is stored as offsets from this box with relative addressing.  Convert to absolute
+    if (relAbs == "Relative"){
+        newDest += llGetPos();
+    }
+
+    DEBUG("Moveto:" + (string) newDest);
+    osNpcMoveToTarget(NPCKey(), newDest, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);
+}
+
+
+StateWander(){
+    DEBUG("state wander");
+    STATE = Wander;
+    
+    vector point = CirclePoint(RAMwd);
+    DEBUG("CirclePoint:" + (string) point);
+    vWanderPos = vDestPos + point;
+    DEBUG("vWanderPos:" + (string) vWanderPos);
+
+    fTimerVal = WANDERTIME;    // default time to pause after each wander
+    if (WANDERRAND)
+        fTimerVal = llFrand(WANDERTIME) + 1;    // override, they want random times
+
+    NPCAnimate(WALK);
+
+    DEBUG("Wander to:" + (string) vWanderPos);
+
+    osNpcMoveToTarget(NPCKey(), vWanderPos, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);      
+}
+
+StateWanderhold() {
+
+    DEBUG("Wander Hold");
+    STATE = WanderHold;
+       
+     // now that we have reached a wander spot, slow the timer down to the desired value
+    TimerEvent(fTimerVal);
+}
+
+// @pause=10 will do nothing for 10 seconds
+DoPause() {
+    STATE =Paused;
+    if (RAMPause < 0.1)
+        RAMPause = 0.1;
+    DEBUG("@pause=" + (string)RAMPause);
+    TimerEvent(RAMPause);
+}
+
+
+// @stop makes the NPC stop moving in whatever state it is in.  You have to linkmessage to get moving again
+DoStop() {    
+    DEBUG("NPC is Stopped");
+    STATE = 0;    // accept commands
+    SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+    
+// @delete removes the NPC forever. Next command starts it up again at the beginning
+DoDelete() {
+    DEBUG("state delete");
+    STATE = 0;    // accept commands
+    osNpcRemove(NPCKey());
+    SaveKey(NULL_KEY);
+    
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+
+// change the appearance of the NPC
+DoAppearance(string notecard) {
+    DEBUG("state appearance");
+    if (llGetInventoryType(notecard) == INVENTORY_NOTECARD){
+        DEBUG("Load appearance " + notecard);
+        osNpcLoadAppearance(NPCKey(),notecard);
+    }
+}
+
+// Change the avatar speed
+DoSpeed(string speed) {
+    float newspeed = (float) speed;
+    if (newspeed > 0.1 && newspeed < 5.0) {// sanity check
+        osSetSpeed(NPCKey(),newspeed);
+    }
+}
+
+DoTeleport(string params) {
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    vector Dest = (vector) itemName;
+    if (Dest != ZERO_VECTOR) {
+        if (relAbs == "Relative"){
+            Dest += llGetPos();
+        }
+        osTeleportAgent( NPCKey(), llGetRegionName(), Dest, ZERO_VECTOR );
+        
+    } else {
+        llSay(DEBUG_CHANNEL,"Attempt to teleport to <0,0,0> probably not what you intended: @teleport=<vector>");
+    }
+}
+
+
+
+DoNewNote (string card) {
+    DEBUG("Load Notecard " + card);    
+    NPCReadNoteCard(card);
+    SetStop(FALSE);
+}
+DoAttach(string params) {
+    
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    integer attachmentPoint  = (integer) llList2String(Data, 1);
+    if (attachmentPoint > 0
+        && attachmentPoint < 40
+        && llGetInventoryType(itemName) == INVENTORY_OBJECT
+       )
+    {
+        osForceAttachToOtherAvatarFromInventory(NPCKey(),itemName,attachmentPoint);
+    }
+}
+
+// This loops over the notecard, processing each command
+DoProcessNPCLine() {
+    DEBUG("ProcessNPCLine, stopped = " + (string) Stopped);
+    STATE = DoProcess;
+
+        // auto load a notecard
+    if (! llGetListLength(lNpcCommandList)) {
+        DEBUG("Read Notecard");
+        NPCReadNoteCard(Notecard);
+        SetStop(FALSE);
+    }
+
+    // look for link messages on the stack
+    string next = llList2String(Stack,0);    // lets see if there is anithing from a link message
+    if (llStringLength(next))
+    {
+        Stack = llDeleteSubList(Stack,0,0);
+        ProcessCmd(next);        //lets do this command instead.
+        return;
+    }
+
+    // @stop issued?
+    if (Stopped) {
+        TimerEvent(0);
+        DEBUG("Stopped, waiting for input");
+        STATE = 0;
+        return;
+    }
+
+    // No, we have an @go for liftoff
+    next = llList2String(lNpcCommandList, 0);        // get the next command
+    DEBUG("Execute:" + next);
+    lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);      // delete it
+        
+    if (llGetListLength(lNpcCommandList) == 0) {
+        DEBUG("EOF");
+    }
+    ProcessCmd(next); 
+} 
+
+
+
+ProcessCmd(string cmd) {
+
+    DEBUG("ProcessCmd:" + cmd);
+
+    if (llGetSubString(cmd, 0, 0) != "@") {
+        DEBUG("ignoring");
+        TimerEvent(QUICK);  // this is so we do not recurse the stack
+        STATE = 0;
+        return;
+    }
+
+    list data  = llParseString2List(cmd, ["="], []);
+    npcAction = llToLower(llStringTrim(llList2String(data, 0), STRING_TRIM));
+
+    DEBUG("Action:" + npcAction);
+    npcParams = llStringTrim(llList2String(data, 1), STRING_TRIM);
+    DEBUG("Params:" + npcParams);
+    
+    @commands;
+
+    ProcessSensor();
+    
+    if(npcAction == "@spawn" && avatarPresent) {
+        DEBUG("@spawn");
+        list spawnData = llParseString2List(npcParams, ["|"], []);
+        sNPCName =llList2String(spawnData, 0);    // V 1.6 name in RAM
+
+        list spawnDest = llParseString2List(llList2String(spawnData, 1), ["<", ",", ">"], []);
+        vInitialPos.x = llList2Float(spawnDest, 0);
+        vInitialPos.y = llList2Float(spawnDest, 1);
+        vInitialPos.z = llList2Float(spawnDest, 2);
+        
+        DEBUG("Coords for NPC at " + (string) vInitialPos);
+        StateSpawn();
+        return;
+    }
+    
+     if (! avatarPresent){
+        DoNobodyHome();
+        DEBUG("No avatar nearby");
+        STATE = 0;
+        return;
+    } else {
+        if ( NPCKey() == NULL_KEY) {
+            StateSpawn();
+        }
+    }
+
+    
+    
+    
+    if(npcAction == "@stop") {
+        DoStop();
+        STATE = 0;
+        return;
+    }
+    else if(npcAction == "@goto") {
+        DEBUG("goto");
+        integer lastIdx = llGetListLength(lNpcCommandList)-1;
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, lastIdx, lastIdx);
+        // Wind commands till goto label.
+        @wind;
+        string next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        if(next1 != npcParams) jump wind;
+        // Wind the label too.
+        next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        // Get next command.
+        list data1  = llParseString2List(next1, ["="], []);
+        npcAction = llToLower(llStringTrim(llList2String(data1, 0), STRING_TRIM));
+        npcParams = llStringTrim(llList2String(data1, 1), STRING_TRIM);
+        // Reschedule.
+        jump commands;
+    }
+    else if(npcAction == "@sound") {
+        DEBUG("sound");
+        llTriggerSound(npcParams,1.0);
+    }
+    else if(npcAction == "@randsound") {
+        DEBUG("@randsound");
+        integer N = llGetInventoryNumber(INVENTORY_SOUND);
+        integer rand = llCeil(llFrand(N)) -1;    // pick a random sound
+        string toPlay = llGetInventoryName(INVENTORY_SOUND,rand);
+        llTriggerSound(toPlay,1.0);
+    }
+    else if(npcAction == "@walk") {
+        DEBUG("@walk");
+        GetDest(npcParams);
+        walkstate = 1;//  walking
+        NPCWalkOption = OS_NPC_NO_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@fly") {
+        GetDest(npcParams);
+        walkstate = 2;//  flying
+        NPCWalkOption = OS_NPC_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@run") {
+        DEBUG("@run");
+        GetDest(npcParams);
+        walkstate = 3;//  running
+        NPCWalkOption = OS_NPC_NO_FLY | OS_NPC_RUNNING;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@land") {
+        DEBUG("@land");
+        GetDest(npcParams);
+        walkstate = 4;//  landing
+        NPCWalkOption= OS_NPC_FLY | OS_NPC_LAND_AT_TARGET ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@say") {
+        DEBUG("@say " + npcParams);
+        osNpcSay(NPCKey(), 0, npcParams);
+    }
+    else if(npcAction == "@shout") {
+        DEBUG("@shout");
+        osNpcShout(NPCKey(),0, npcParams);
+    }
+    else if(npcAction == "@whisper") {
+        DEBUG("@whisper " + npcParams);
+        osNpcWhisper(NPCKey(),0, npcParams);
+    }
+    // speak a command on a channel, so you can open doors and control stuff.
+    else if(npcAction == "@cmd") {
+        DEBUG("@cmd");
+        list dataToSpeak = llParseString2List(npcParams, ["|"], []);
+        string channel = llList2String(dataToSpeak,0);
+        DEBUG("Channel:"+(string) channel);
+        integer iChannel = (integer) channel;
+        string stringToSpeak = llList2String(dataToSpeak,1);
+        llSay(iChannel, stringToSpeak);
+    }
+    // stop everything
+    else if(npcAction == "@pause") {
+        RAMPause = (float) npcParams;
+        DoPause();
+        return;
+    }
+    else if(npcAction == "@wander") {
+        list wanderData = llParseString2List(npcParams, ["|"], []);
+        RAMwd = (float) llList2String(wanderData, 0);
+        RAMwc = (integer) llList2String(wanderData, 1);
+        vDestPos = osNpcGetPos(NPCKey());        // set the wander start
+        DEBUG("Starting at " + (string) vDestPos);
+        StateWander();
+        return;
+    }
+    else if(npcAction == "@rotate") {
+        RAMrot = (float) npcParams;
+        DoRotate();
+    }
+    else if(npcAction == "@sit") {
+        RAMsit= npcParams;
+        StateSit();
+        return;
+    }
+    else if(npcAction == "@touch") {
+        RAMtouch= npcParams;
+        StateTouch();
+        return;
+    }
+    else  if(npcAction == "@stand") {
+        DoStand();
+    }
+    else if(npcAction == "@delete") {
+        DoDelete();
+        SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+        return;
+    }
+    else if(npcAction == "@animate") {
+        list animateData = llParseString2List(npcParams, ["|"], []);
+        RAManimationName = llList2String(animateData, 0);
+        RAManimationTime = (float) llList2String(animateData, 1);
+        StateAnimate();
+        return;
+    }
+    else if(npcAction == "@appearance" ){
+        DoAppearance(npcParams);
+    }
+    else if (npcAction =="@speed") {
+        DoSpeed(npcParams);
+    }
+    else if (npcAction =="@notecard") {      
+        DoNewNote(npcParams);
+        Notecard = npcParams;
+    }
+    else if (npcAction == "@attach")
+    {
+        DoAttach(npcParams);
+    }
+    else if (npcAction == "@teleport")
+    {
+        DoTeleport(npcParams);
+    }
+    else if (npcAction == "@reset")
+    {
+        DoDelete();
+        SetStop(FALSE); // a @resst will restart the original !Path after deleting the notecard.
+    }
+
+    STATE = 0;
+    TimerEvent(QUICK);  // yeah I know, not possible this fast, we just go as fast as we can go - this is so we do not recurse the stack 
+}
+ 
+
+
+/////////////////// UTILITY Functions, not state-like //////////////////
+
+// DEBUG(string) will chat a string or display it as hovertext if debug == TRUE
+DEBUG(string str) {
+    if (debug && ! LSLEditor)
+        llOwnerSay( str);                    // Send the owner debug info 
+    if (debug &&  LSLEditor)
+        llSay(0, str);                    // Send to the Console in LSLEDitor 
+    if (iTitleText) {
+        llSetText(str,<1.0,1.0,1.0>,1.0);    // show hovertext
+    
+    }
+}
+
+GetDest(string npcParams) {
+    list dest = llParseString2List(npcParams, ["<", ",", ">"], []);
+    vDestPos.x = llList2Float(dest, 0);
+    vDestPos.y = llList2Float(dest, 1);
+    vDestPos.z = llList2Float(dest, 2);
+}
+
+NPCReadNoteCard(string Note) {
+    DEBUG("NPCReadNoteCard");             
+    lNpcCommandList = llParseString2List(osGetNotecard(Note), ["\n"], []);
+}  
+  
+integer SenseAvatar()
+{
+    //Returns a strided list of the UUID, position, and name of each avatar in the region
+    list avatars = llGetAgentList(AGENT_LIST_REGION ,[]);
+    integer numOfAvatars = llGetListLength(avatars);
+    if (numOfAvatars == 0)
+    {
+        DEBUG("No people");
+        return 0;
+    }
+    //DEBUG("Located " + (string)numOfAvatars + " avatars and NPC's"); 
+        
+    integer nAvatars;
+    integer i;
+    for( i = 0;i < numOfAvatars; i++) {
+        key aviKey = llList2Key(avatars,i);
+        if (!osIsNpc(aviKey)) {
+            list detail = llGetObjectDetails(aviKey,[OBJECT_POS]);
+            vector pos = llList2Vector(detail,0);
+            float dist = llVecDist(pos, llGetPos());
+            if (dist  < RANGE)
+            {
+                nAvatars++;
+                DEBUG("In range:" + llKey2Name(aviKey));
+            }
+        }
+    }
+    //DEBUG("Located " + (string) nAvatars + " avatars");
+    return nAvatars;
+} 
+ 
+// return TRUE if the avatar is owner when private is set, or TRUE if the avatar is in the same group and GROUP is set.
+integer checkPerms() {
+
+    integer group = (integer) KeyValueGet("pr");
+    if (! group)
+        priPub = "Owner Only";
+    else
+        priPub = "Group";
+    
+    
+    if (llDetectedKey(0) == llGetOwner()){
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+ 
+    if ( group && llDetectedGroup(0)) {
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+    kUserKey = llDetectedKey(0);
+    return FALSE;
+}
+
+
+
+NPCAnimate(string anim)
+{
+    DEBUG("Start Anim: " + anim);
+    if (llGetInventoryType(anim) == INVENTORY_ANIMATION ) {
+        
+        if (lastANIM != anim) {
+            if(llStringLength(lastANIM)) {
+                osNpcStopAnimation(NPCKey(), lastANIM);  
+            }
+            osNpcPlayAnimation(NPCKey(), anim);
+            lastANIM = anim;
+        }            
+    } else {
+        llSay(DEBUG_CHANNEL, "No animation named " + anim);
+    }
+} 
+
+// Kill a NPC by Name
+Kill(string param)
+{
+    integer count;
+    list avatars = osGetAvatarList(); // Returns a strided list of the UUID, position, and name of each avatar in the region except the owner.\    
+    integer i;
+    integer j = llGetListLength(avatars);
+    for (i=0 ; i <= j; i+=3){
+        
+        string desired = llList2String(avatars,i+2);
+        desired = llStringTrim(desired,STRING_TRIM);    // should not be needed but is needed
+        
+        if (desired == param){
+            vector v = llList2Vector(avatars,i+1);
+            key target = llList2Key(avatars,i);    // get the UUID of the avatar
+            osNpcRemove(target);
+            SaveKey(NULL_KEY );  
+            llOwnerSay("Removed " + param+ " at  location " + (string) v);
+            count++;
+        }
+    }
+    
+    NPCEnabled = FALSE; // not in world
+    
+    if (count)
+        llOwnerSay("Removed " + (string) count + " NPC's");
+    else
+        llOwnerSay("Could not locate " + param);
+}
+
+
+// return a String for the position we are at. Strings used as the caller wants strings
+string Pos()
+{
+    vector where = llGetPos(); // find the box position
+   
+    where.z +=    OffsetZ;  // use the ground position + an offset 
+        
+    if (LSLEditor)
+        where  = <128,128,31 + llFrand(1)>; // force center of sim when editing
+   
+   // if attached the height will be too high by 1/2 the agent size
+    if (llGetAttached()) {
+        vector size = llGetAgentSize(llGetOwner());   
+        float Z = size.z;
+        where.z -= Z/2;  
+    }
+   
+    // DEBUG("Pos= " + (string) where);
+    return (string) where;
+}
+
+// setup a menu with a timer for timeouts, called by all make*()
+menu()
+{
+    llListenRemove(iHandle);
+    iChannel = llCeil(llFrand(100000) + 20000);
+    iHandle = llListen(iChannel,"","","");
+    TimerEvent(30.0);
+    MENU = TRUE;
+}
+
+// make a text box
+makeText(string Param)
+{ 
+    menu();
+    llTextBox(kUserKey, Param, iChannel);
+}
+
+// top level menu
+makeMainMenu()
+{
+    menu();
+    list buttons = ["Appearance","Recording","Save","Help","-","Erase RAM", priPub,relAbs,"-","Stop NPC",mSensor,"Start NPC"];
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Records",buttons,iChannel);
+}
+
+
+// Rev 1.4
+// top level menu for non group/ non owners
+makeUserMenu()
+{
+    if (!allowUsers) return;
+    
+    menu();
+    list buttons = ["Start NPC","Stop NPC"];
+    llDialog(kUserKey,"Choose",buttons,iChannel);
+}
+
+
+
+// programmable menu for @commands
+makeMenu(list buttons)
+{
+    menu();
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Record",buttons,iChannel);
+}
+
+
+// make one or two text boxes with prompts
+Text(string cmd, string p1, string p2)
+{
+    sCommand = cmd;
+     sParam2 = "";
+    if (llStringLength(p2))
+        sParam2 = p2;
+
+    makeText(p1);
+} 
+
+// Set the Avatar Present flag - if sensors are off and we are forece run, there will be one present.
+ProcessSensor()
+{
+    integer SensorOn;
+    if ("on" == KeyValueGet("se"))
+    {
+        SensorOn = TRUE;        // we need to scan for avatars
+    } else {
+        SensorOn = FALSE;        // we need to scan for avatars
+    }
+    DEBUG("Sensor:" + (string) SensorOn);
+    
+    integer n = SenseAvatar();
+    
+    DEBUG("Avatars:" + (string) n);
+    if (SensorOn && n)
+        avatarPresent = TRUE;   // someone is here and we need to tell the system to run
+    else if (SensorOn && !n)
+        avatarPresent = FALSE;  // someone is not here and we need to tell the system to stop
+    else {       // sensor is off, lete see if there is a NPC. If so, we are ON 
+        DEBUG("NPCEnabled:" + (string) NPCEnabled);
+        if (NPCEnabled)
+            avatarPresent = TRUE;  
+        else
+            avatarPresent = FALSE;   
+    }
+    
+    //  start up from when when no one is near
+    if (avatarPresent && STATE == NobodyHome)
+        STATE = 0;
+    
+    DEBUG("Avatar Present: " + (string) avatarPresent);
+}
+
+vector CirclePoint(float radius) {
+    float x = llFrand(radius *2) - radius;        // +/- radius, randomized
+    float y = llFrand(radius *2) - radius;        // +/- radius, randomized
+    return <x, y, 0>;        // so this should always happen
+}
+
+string KeyValueGet(string var) {
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k != var) jump continue;
+        //DEBUG("got " + var + " = " +  llList2String(data, 1));
+        return llList2String(data, 1);
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    return "";
+} 
+
+KeyValueSet(string var, string val) {
+
+    //DEBUG("set " + var + " = " + val);
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    if(llGetListLength(dVars) == 0)
+    {
+        llSetObjectDesc(var + "=" + val);
+        return;
+    }
+    list result = [];
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k == "") jump continue;
+        if(k == var && val == "") jump continue;
+        if(k == var) {
+            result += k + "=" + val;
+            val = "";
+            jump continue;
+        }
+        string v = llList2String(data, 1);
+        if(v == "") jump continue;
+        result += k + "=" + v;
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    if(val != "") result += var + "=" + val;
+    llSetObjectDesc(llDumpList2String(result, "&"));
+}
+
+
+// clear RAM
+Clr() {
+
+    lCommands = [];
+    llOwnerSay("RAM Memory cleared. Notecards, if any, are not modified.");
+    makeMainMenu();
+}
+
+integer checkNoteCards()
+{
+    // Check that they have saved an Appeaance and Path notecard
+    integer num = llGetInventoryNumber(INVENTORY_NOTECARD);    // how many notecards overall
+    
+    integer i;
+    integer count;
+    for (; i < num; i++){
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Notecard)
+            count++;
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Appearance)
+            count++;
+    }
+    DEBUG("Checked " + (string) count + " Notecards");
+    // if we have both, run the NPC
+    return count;
+}
+
+Update(string SName) {
+         
+    // delete all NPC* scripts except myself
+    integer i;
+    integer j = llGetInventoryNumber(INVENTORY_SCRIPT);
+    for (i = 0; i < j; i++) {
+        string targetName = llGetInventoryName(INVENTORY_SCRIPT,i);
+        string match = llGetSubString(targetName,0,2);
+        
+        if (match == SName && llGetScriptName() != targetName){
+                llOwnerSay("Upgrading " + targetName);
+            if (! LSLEditor){        // lets not kill the editor
+                llRemoveInventory(targetName);
+            }
+        }
+    }
+}
+
+// Get all default saved params from the Description
+GetSwitches()
+{
+         string rA = KeyValueGet("co"); // Get the remembered menu setting for Abs Vs Relative
+        if (rA == "A")
+            relAbs = "Absolute";
+        else  if (rA == "R")
+            relAbs = "Relative";
+        else
+            relAbs = "Absolute";
+
+            
+        // reenable NPC if sensor is on.
+        if ("on" == KeyValueGet("se"))
+        {
+            NPCEnabled = TRUE;
+            mSensor  = "Sense is On";
+            ProcessSensor();       // fake 1 avatar to get it rezzed
+        } else {
+            mSensor  = "Sense is Off";
+        }
+    }
+
+
+SaveKey(key akey)
+{
+    DEBUG("Saving Key of " + (string) akey);
+    KeyValueSet("key", akey);
+    if (akey !=  (key) KeyValueGet("key") )
+    {
+        DEBUG("Fatal error, cannot save key");
+    }
+    gNpcKey = akey;
+}
+
+
+key NPCKey()
+{
+    key akey = gNpcKey;   // from cached copy
+    // gNpcKey saves a lot of CPU processing by caching the key, if blank we get it from the description
+    if (gNpcKey == NULL_KEY)
+    {
+        //DEBUG("Get DKey");
+        akey = KeyValueGet("key");    // from Description of the prim
+    }
+   // DEBUG("NPC KEY:" + (string) akey);   
+    return  akey;
+}
+
+
+/////////////////// CODE BEGINS //////////////////
+
+
+default
+{
+    changed(integer change) {
+        if(change & CHANGED_REGION_START) {
+            llResetScript();
+        }
+    }
+    
+    on_rez(integer start_param)
+    {
+        llResetScript();
+    }
+
+    state_entry() {
+        
+        llSetText("",<1,1,1>,1.0);  // clr all hovertext- we may not be using it.
+        DoDelete(); // kill any NPC that is out running
+        Update("NPC"); // If dragged and ropped into a prim with any script named "NPC...", this will replace it.
+        GetSwitches(); // Get all default saved params from the Description
+
+        // 4.1 allow listeners to send us commands
+        if (allowListener)
+            llListen(link_Channel,"","","");
+        TimerEvent(TIMER);
+    } 
+
+
+    touch_start(integer n) 
+    {           // if touched, make a menu
+    
+        if (checkPerms()) {
+            if (RecordPath == STATE) {
+                makeMenu(lAtButtons); 
+            }   else {
+                makeMainMenu();
+            }
+        } else {
+            makeUserMenu();
+        }
+    }
+
+    // menu listener
+    listen(integer iChannel, string name, key id, string message) {
+
+        // process @commands that come in via the listener
+        if (iChannel == link_Channel)
+        {
+            ParseMsg(message);
+            return;
+        }
+        
+        if (MENU) {
+            llListenRemove(iHandle);
+            MENU = 0;       // menu is off
+            iHandle = 0;
+        }
+        
+        if (message == "Stop NPC")
+        {
+            lNpcCommandList = []; // force reload of notecard
+            NPCEnabled = FALSE;
+            if (NPCKey() != NULL_KEY){
+                Kill(sNPCName);
+                sNPCName = "";
+            } else {
+                bNPC_STOP = TRUE;
+                makeText("Enter name of an NPC to stop");
+            }
+        }
+        else if (message == "Menu" ) {
+            makeMainMenu();
+        }
+        else if (message == "Erase RAM"){
+            Clr();
+        }
+        else if (message == "Relative"){
+            relAbs = "Absolute";
+            KeyValueSet("co","A");   // remember coordinates = A
+            Clr();
+        }
+        else if (message == "Absolute"){
+            relAbs = "Relative";
+            KeyValueSet("co","R");   // remember coordinates = R
+            Clr();
+        }
+        else if (message == "Recording"){
+            DoMenuForCommands();        // show them the recording menu
+        }
+        else if (message == "Owner Only") {
+            priPub = "Group";
+            KeyValueSet("pr","1");
+
+            llOwnerSay("Group members have control");
+            makeMainMenu();
+        }
+        else if (message == "Group") {
+            priPub = "Owner Only";
+            KeyValueSet("pr","0");
+            llOwnerSay("Only you have control");
+            makeMainMenu();
+        }
+        else if (message == "Sense is On") {
+            mSensor ="Sense is Off";
+            KeyValueSet("se", "off");
+            llOwnerSay(mSensor);
+            makeMainMenu();
+        }
+        else if (message == "Sense is Off") {
+            mSensor ="Sense is On";
+            llOwnerSay(mSensor);
+            KeyValueSet("se", "on");
+            
+            NPCEnabled = FALSE;
+            
+            integer count = checkNoteCards();
+            if (count >= 2)  {
+                DEBUG("Notecards ok, DoProcessNPCLine");
+                DoProcessNPCLine();
+                return;
+            }
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording and/or appearance, so you cannot start a NPC");
+            makeMainMenu();
+        }
+        else if (message == "Appearance")  {
+            llRemoveInventory(Appearance);            // delete the notecard
+            osAgentSaveAppearance(kUserKey,Appearance);    // make the ntecard 
+            llOwnerSay("Your outfit has been saved");
+            makeMainMenu();
+        }
+        else if (message == "Save") {
+            if (llGetListLength(lCommands) == 0) {
+                llOwnerSay("Nothing recorded, you need to make a recording first");
+                makeMainMenu();
+                return;
+            }
+            DoSave();
+        }
+        else if (message == "Help"){
+            llLoadURL(kUserKey,"Click to view help","http://www.outworldz.com/opensim/posts/NPC/");
+            makeMainMenu();
+        }
+        else if (message == "Start NPC")    {
+            integer count = checkNoteCards();
+
+            NPCEnabled = TRUE;
+
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+            
+            if (count >= 2) {
+                DEBUG("Notecards approved , calling DoProcessNPCLine");
+                SetStop(FALSE); // Let's run the notecard
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording or maybe an appearance, so we cannot start a NPC");
+      
+        }
+        else if (bNPC_STOP){
+            bNPC_STOP = FALSE;
+            Kill(message);
+        }
+        else if (message == ">>"){
+            makeMenu(lMenu2);
+        }
+        else if (message == ">>>"){
+            makeMenu(lMenu3);
+        }
+        else if (message == "<<") {
+            makeMenu(lAtButtons);
+        }
+        else if (message == "<<<") {
+            makeMenu(lMenu2);
+        }
+        else if (message == "@comment"){
+            Text("# ","Enter a comment","");
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@run"){
+            lCommands += "@run=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@fly"){
+            lCommands += "@fly=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@land"){
+            lCommands += "@land=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@walk") {
+            lCommands += "@walk=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@sound"){
+            Text("@sound=","Enter a sound name or UUID to trigger","");
+        }
+        else if (message == "@randsound"){
+            lCommands += "@randsound"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@say") {
+            Text("@say=","Enter what the NPC will say","");
+        }
+        else if (message == "@whisper"){
+            Text("@whisper=","Enter what the NPC will whisper","");
+        }
+        else if (message == "@shout"){
+            Text("@shout=","Enter what the NPC will shout","");
+        }
+        else if (message == "@wander") {
+            Text("@wander=","Enter radius to wander","Enter number of wanders");
+        }
+        else if (message == "@pause") {
+            Text("@pause=","Enter time to pause","");
+        }
+        else if (message == "@rotate") {
+            Text("@rotate=","Enter degrees to rotate","");
+        }
+        else if (message == "@sit"){
+            Text("@sit=","Enter name of object to sit on","");
+        }
+        else if (message == "@teleport"){
+            lCommands += "@teleport=" + Pos() + "\n";
+            llOwnerSay("teleport to position: " + Pos());
+            makeMenu(lMenu3);
+        }
+        else if (message == "@touch"){
+            Text("@touch=","Enter name of object to touch","");
+        }
+        else if (message == "@cmd"){
+            Text("@cmd=","Enter cjhannel to speak on","Enter text to speak");
+        }
+        else if (message == "@stand"){
+            lCommands += "@stand\n";
+            llOwnerSay("Stand Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@animate"){
+            Text("@animate=","Enter animation name to play","Enter time to play the animation");
+        }
+        else if (message == "@attach"){
+            Text("@animate=","Enter inventory name to attach","Enter number of the attachment point (1-40)");
+        }
+         else if (message == "@speed"){
+            Text("@speed=","Enter a speed for the NPC, 1=100% normal speed, 0.5=50% speed","");
+        }
+               
+
+        // Save NPC name
+        else if (MakeNotecard == STATE) {
+            sNPCName = message; // in case we need to kill it.
+            
+            vector  vDest = (vector)  Pos();
+
+            if (relAbs == "Relative")
+            {
+                vDest  -= llGetPos();    // just an offset for relative
+            }
+            sNotecard = "@spawn=" + message + "|" +  (string) vDest  + "\n";
+            integer i;
+            integer j = llGetListLength(lCommands);
+            for (; i < j; i++){
+                // get the command to save to the notecard
+                string line = llList2String(lCommands,i);
+                if (relAbs == "Absolute") {
+                    sNotecard += line;    // add the un-modified string to the notecard
+                } else {
+                        // since we have to record absolute coords since we do not know where the box goes until they press Save,
+                        // we process the absolute to relative conversion for walks here
+                        list parts = llParseString2List(line,["="],[]); //get the @command
+
+                    if (llList2String(parts,0) == "@walk") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@walk=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@fly") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@fly=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@run") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@run=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@land") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@land=" + (string) vec + "\n";
+                    }
+                    else {
+                        sNotecard += line;    // add the un-modified string to the notecard
+                    }
+                }
+            }
+            llRemoveInventory(Notecard);        // delete the old notecard
+            osMakeNotecard(Notecard,sNotecard); // Makes the notecard.
+            llSay(0,sNotecard);
+            llOwnerSay("Commands notecard has been written");
+            STATE = 0;
+        } // MakeNotecard
+
+        else  if (! llStringLength(sParam2)) {
+            lCommands +=  sCommand + message + "\n";
+            llOwnerSay("Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (llStringLength(sParam2)){
+            sCommand = sCommand + message + "|";
+            llOwnerSay("Recorded");
+            makeText(sParam2);
+            sParam2 = "";
+        }
+
+    }
+
+
+
+    timer(){
+       // DEBUG("tick");
+        
+        // if llDialog is up, kill the listener for the dialog box.
+        if (iHandle) {
+            llOwnerSay("Menu timed out");
+            llListenRemove(iHandle);
+            iHandle = 0;
+            return;             // ^^^^^^^^^^^^^^^^^^^^^^^
+        }
+        // if NoBodyHome, we are sensing for an avatar
+        else if (NobodyHome == STATE) {
+            ProcessSensor();
+            return;
+        }
+        // if we are spawning, we need time to rez the NPC, then start processing NPC Commands.
+        else if (Spawning == STATE) {
+            STATE = 0;
+            TimerEvent(TIMER);
+        }
+        // We end aniamtions with a timer
+        else if (Animate == STATE){
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+        }
+        
+        else if (Walking == STATE) {
+            if (--iWaitCounter) {
+                if (llVecDist(osNpcGetPos(NPCKey()), newDest) > MAXDIST)  {
+                    return;
+                }
+            }
+
+            DEBUG("At Destination: " + (string) newDest);
+            
+            // walk, fly, run, land
+            if (walkstate == 1) {
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 2)  {
+                    // nothing
+                } else if (walkstate == 3) {
+                     NPCAnimate(STAND);
+                     NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 4) {
+                llShout(FLIGHT,"landing");
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            }
+        }
+        // Wandering timer 
+        else if (Wander == STATE) {
+            if (--iWaitCounter) {          // wait 60 seconds to get to a destination.
+                if (llVecDist(osNpcGetPos(NPCKey()), vWanderPos) > MAXDIST)
+                    return;
+            }
+
+            // see if wander counter == 0, if so, stop walking, go to stand and process next line
+            if(RAMwc == 0) {
+                NPCAnimate(STAND);
+                DEBUG("Wander ended, calling DoProcessNPCLine");
+                STATE = 0;
+                DoProcessNPCLine();
+                return;
+            }
+            // one less time to wander around
+            RAMwc--;
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+            StateWanderhold();
+            return;
+        }
+        // Wandering requires us to re-wander when we reach a destination
+        else if (WanderHold == STATE) {
+            StateWander();
+            TimerEvent(TIMER);
+            return;
+        }
+        else if (DoProcess == STATE) {
+            TimerEvent(QUICK);
+        }
+
+       
+        STATE = 0;
+
+        // We always process a NPC line at end of timer.
+        DEBUG("Tick end, calling DoProcessNPCLine");
+        DoProcessNPCLine();
+    }
+
+    // sensors are used for sitting on prims
+    // Neo Cortex: added different SensorFunc states to trigger sit or touch
+    sensor(integer num) {
+        if (SensorFunc == 1) {
+            osNpcSit(NPCKey(), llDetectedKey(0), OS_NPC_SIT_NOW);
+            DEBUG("Seated, calling DoProcessNPCLine");
+            SensorFunc = 0;
+        } else if (SensorFunc == 2) {
+            osNpcTouch(NPCKey(), llDetectedKey(0), LINK_THIS);
+            DEBUG("Touched, calling DoProcessNPCLine");
+            SensorFunc = 0;
+        }
+        DoProcessNPCLine();
+    }
+    no_sensor(){
+        DEBUG ("no target prim located, calling DoProcessNPCLine");
+        SensorFunc = 0;
+        DoProcessNPCLine();
+    }
+
+    
+    link_message(integer sender, integer num, string str, key id){
+        ParseMsg(str);
+    }
+        
+}
+
+
+
+
+
+
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.4.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.4.lsl
new file mode 100644
index 00000000..7c84c12b
--- /dev/null
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.4.lsl	
@@ -0,0 +1,1688 @@
+// :SHOW:1
+// :CATEGORY:NPC
+// :NAME:All In One NPC Recorder and Player
+// :AUTHOR:Ferd Frederix
+// :KEYWORDS:NPC, Puppeteer
+// :CREATED:2015-09-29 18:04:52
+// :EDITED:2015-09-29  17:04:52
+// :ID:27
+// :NUM:1830
+// :REV:4.4
+// :WORLD:OpenSim
+// :DESCRIPTION:
+// All in one NPC recorder player.
+// Supports both absolute and relative paths and many new commands
+// Add animations named "Fly, Walk, Stand and Run"
+// Click Prim to use.
+// Should be worn as a HUD to record.
+// Put it on the ground and click Sensor or Start NPC when done.
+// :CODE:
+// This is Rev 4.4  09/26/2015
+
+// Revision History
+// Rev 1.1 10-2-2014 @Sit did not work.  Minor tweaks to casting for lslEditor
+// Rev 1.2 10-14-2014 @ sit had wrong type.
+// Rev 1.3 relative movement fixed for @fly
+// Rev 1.4 4-3-2014 allow anyone to use this, non owners and non group members can only start and stop.
+// Rev 1.5 5-17-2014 set sensor to auto start on reboot of sim
+// Rev 1.6 5-24-2014 move menu so you can get it by touching, removed many of the KeyValues to RAM for efficiency
+// Rev 1.7 CHANGED_REGION_START, not CHANGED_REGION_START (Opensim difference)
+// Rev 1.8 tuned up Kill NPC, added more flexible upgrader
+// Rev 1.9 Better script injection by link message// Rev 2.0 Added osSetSpeed so you can speed up or slow down an NPC.
+// Rev 2.1 No laggy sensor used exept to sit on stuff
+// Rev 2.2 Various sensor fixes
+// Rev 2.3 Sets No Sensor in menu, must be started by hand
+// Rev 2.4 - reserved for patches to 2.3 if needed
+// Rev 3.0 Refactor out into subs, not states to make command injection easier
+//            New command: @appearance=Notecardname so you can switch to a new notecard on the fly
+//            New command: @speed=1.0  which slows up  ( < 1 )  or speeds up ( > 1)
+// Rev 3.1 Commands are not interruptible by Link Message
+// Rev 3.2 Sensor patches for consistency in removing the NPC
+// Rev 3.3 Added Touch command by Neo.Cortex@hbase42/hopto/org:8002
+//         Added Menu 3 for notecard and appearance commands
+// Rev 3.4 animation timer cannot be zero or it shuts off timer tweaked
+//         solves the NPC starting up when no sensor is set.
+// Rev 3.5 fixes saving to !Path  notecard
+// Rev 3.6 08-11-2015 @delete acts like @stop. TYjhe NPC now rezzes after an @go back in where it was deleted 
+// Rev 3.7 08-11-2015 @attach command added to load an attachment from the inventory to the NPC
+// Rev 3.8 08-17-2015 process queued commands one at a time without calling ProcessNPCLine on link message
+// Rev 3.9 08-23-2011 Queued command fixes including @delete which were not always working
+// Rev 4.0 09-15-2015 Fixes for Sensor functions which continually rezzed a NPC when no one was around.
+// Rev 4.1 09-20-2015 Added a Listener so link messages are not needed
+// Rev 4.2 09-23-2015 Added @teleport=<vector>
+// Rev 4.3 09-24-2015 Added @reset to restart the NPC at the very start of the !Path notecard
+//                    @teleport works for relative and absolute modes
+// Rev 4.4 09-26-2015 if it could not find the (deleted) NPC, it could not restart
+
+//*******************************************************************//
+
+// Instructions on how to use this are at http://www.outworldz.com/opensim/posts/NPC/
+// This is an OpenSim-only script.
+// Author: Ferd Frederix aka Fred Beckhusen - fred@mitsi.com
+
+////////////////////////////////////////////////////////////////////////////////////////////
+//    Original code was Copyright (C) 2013 Wizardry and Steamworks - License: GNU GPLv3    //
+///////////////////////////////////////////////////////////////////////////////////////////
+//  Please see: http://www.gnu.org/licenses/gpl.html for legal details,                  //
+//  rights of fair usage, the disclaimer and warranty conditions.                        //
+///////////////////////////////////////////////////////////////////////////////////////////
+// The original NPC controller was from http://was.fm/opensim:npc
+// Extensive additions and bug fixes by Fred Beckhusen, aka Ferd Frederix
+// llSensor had two params swapped
+// @Wander would wander where it had rezzed, not where it was.
+// There was no 'no_sensor' event in sit, so if a @sit failed, the NPC got stuck
+// The animation and walks always stopped old, then started new.  It should be start new, then stop old so the default stand would be suppressed.
+// New code:
+// Merged with new Route recorder and notecard writer
+// If the NPC failed to reach a destination it never moved on.
+// Added WAIT global to tune this
+// Exposed many tunable variables and ported the code 
+// Added floating point to times in notecard.
+// Added @sound, @randsound, @whisper, @shout, and @cmd controls.
+// notecards integers are not floats for better control
+// 
+// Link Messages may be used to perform external control by injecting @commands into the stream of actions
+// Example:
+// To chat something, such as with a chat robot
+//  llMessageLinked(LINK_SET,0,"@npc_say=Hello","");
+
+// This script assumes that NPCs and OSSl scripting is enabled in the OpenSim configuration.
+// In order to enable them, the following changes must be made in the OpenSim.ini configuration file:
+//
+// ; Turn on OSSL
+// AllowOSFunctions = true
+// OSFunctionThreatLevel = Severe
+
+//[NPC]
+//    ;# {Enabled} {} {Enable Non Player Character (NPC) facilities} {true false}
+//    Enabled = true
+//
+// and then the server has to be restarted.
+// please note that there are better ways to enable NPC in the latest Opensim.  
+
+// Commands: All commands begin with an @ sign.  All other lines are ignored
+// @commands may have optional parameters.  The syntax is always:
+//  @cmd=parm1|parm2
+//  NaN in the table below meand Not a Number.   This means there is no parameter
+
+//Command     First Parameter             Second Parameter        Description
+//@spawn      name                        location (vector)       Rezzes an NPC with name at a location.
+//@appearance NoteCardName                NaN                     switch the NPC appearance to a new notecard
+//@walk       destination (vector)        NaN                     Makes the NPC walk to destination.
+//@fly        destination (vector)        NaN                     Makes the NPC fly to destination.
+//@land       destination (vector)        NaN                     Makes the NPC land at destination.
+//@say        string                      NaN                     Makes the NPC speak a phrase.
+//@whisper    string                      NaN                     Makes the NPC whisper a phrase.
+//@shout      string                      NaN                     Makes the NPC shout a phrase.
+//@pause      seconds (float)             NaN                     Makes the NPC wait for a multiple of seconds.
+//@wander     radius (float)              cycles (integer)        Makes the NPC wander in radius, for cycles seconds.
+//@delete     NaN                         NaN                     Removes the NPC.  Requires a link message to continue
+//@goto       label (string)              NaN                     Jump to the label label in the script.
+//@animate    animation (string)          time (float)            Makes the NPC trigger the animation animation for time seconds.
+//@sound      sound_name                  NaN                     plays a sound from inventory
+//@randsound  NaN                         NaN                     Plays a random sound from inventory
+//@rotate     degrees (float)             NaN                     Rotate the NPC degrees around the Z axis.
+//@sit        primitive name              NaN                     Sit on a primitive with a given name.
+//@touch      primitive name              NaN                     Touch on a primitive with a given name.
+//@stand      NaN                         NaN                     If sitting on a primitive, stand up.
+//@cmd        channel (integer)           string                  Says string on channel, for controlling external gadgets
+//@stop       NaN                         NaN                     Halts the NPC script indefinitely. Can be started with a link message
+//@go         NaN                         NaN                     Continues on next notecard line, for use in link messages
+//@speed      speed (float)               NaN                     from 0 to N, where 1.0 ius a normal speed of an avatar.  0.2 is a turtle.
+//@notecard   notename (string)           NaN                     load a new Path notecard
+//@attach     InventoryName               attachmentPoint         load an attachment from the inventory to the NPC onto point
+//@teleport   destination (vector)        NaN                     Makes the NPC teleport to destination in the same sim.  They cannot tp to another sim or across the HG
+//@reset      NaN                         NaN                     Deletes the NPC, starts the !Path notecard over.
+ 
+// Constant            attachmentPoint Comment
+// ATTACH_CHEST            1    chest/sternum
+// ATTACH_HEAD             2    head
+// ATTACH_LSHOULDER        3    left shoulder
+// ATTACH_RSHOULDER        4    right shoulder
+// ATTACH_LHAND            5    left hand
+// ATTACH_RHAND            6    right hand
+// ATTACH_LFOOT            7    left foot
+// ATTACH_RFOOT            8    right foot
+// ATTACH_BACK             9    back
+// ATTACH_PELVIS          10    pelvis
+// ATTACH_MOUTH           11    mouth
+// ATTACH_CHIN            12    chin
+// ATTACH_LEAR            13    left ear
+// ATTACH_REAR            14    right ear
+// ATTACH_LEYE            15    left eye
+// ATTACH_REYE            16    right eye
+// ATTACH_NOSE            17    nose
+// ATTACH_RUARM           18    right upper arm
+// ATTACH_RLARM           19    right lower arm
+// ATTACH_LUARM           20    left upper arm
+// ATTACH_LLARM           21    left lower arm
+// ATTACH_RHIP            22    right hip
+// ATTACH_RULEG           23    right upper leg
+// ATTACH_RLLEG           24    right lower leg
+// ATTACH_LHIP            25    left hip
+// ATTACH_LULEG           26    left upper leg
+// ATTACH_LLLEG           27    left lower leg
+// ATTACH_BELLY           28    belly/stomach/tummy
+// ATTACH_LEFT_PEC        29    left pectoral
+// ATTACH_RIGHT_PEC       30    right pectoral
+// ATTACH_HUD_CENTER_2    31    HUD Center 2
+// ATTACH_HUD_TOP_RIGHT   32    HUD Top Right
+// ATTACH_HUD_TOP_CENTER  33    HUD Top
+// ATTACH_HUD_TOP_LEFT    34    HUD Top Left
+// ATTACH_HUD_CENTER_1    35    HUD Center
+// ATTACH_HUD_BOTTOM_LEFT 36    HUD Bottom Left
+// ATTACH_HUD_BOTTOM      37    HUD Bottom
+// ATTACH_HUD_BOTTOM_RIGHT 38   HUD Bottom Right
+// ATTACH_NECK            39   neck
+// ATTACH_AVATAR_CENTER  40    avatar center/root
+
+
+  
+//////////////////////////////////////////////////////////
+//                  DEBUG                               //
+//////////////////////////////////////////////////////////
+integer debug = TRUE;         // set to TRUE or FALSE for debug chat on various actions
+integer LSLEditor = TRUE;        // set to to TRUE to working in  LSLEditor, FALSE for in-world.
+                              // you must also include the NPC commands found in the other script since LSLEditor does not support OpenSim
+integer iTitleText = FALSE;    // set to TRUE to see debug info in text above the controller
+ 
+//////////////////////////////////////////////////////////
+//                  TUNABLE CONFIGURATION               //
+//////////////////////////////////////////////////////////
+integer   allowListener = TRUE; // set to TRUE to anable a command listener. Usually, this is setto FALSE
+integer   link_Channel =   4223; // some random number you want to talk to this gadget on. Best if large and negative
+float     TIMER = 2;         // faster = less jerky stopping.  How often the system checks the distance traveled.  Fastest you can go is 0.5 seconds
+float     QUICK = 1;        // when we need to move to the next state, we use a QUICK timer
+string    Appearance = "!Appearance";  // The name of the recorded Appearance notecard
+string    Notecard = "!Path"; // The name of the recorded routes
+integer   allowUsers = FALSE;  // If true, any user can get a Start NPC and Stop NPC menu.  Only groups and owners can get all commands if TRUE, or FALSE
+float     MAXDIST = 2.0;       // how close a NPC has to get to a dest pos to continue to next state. Do not lower this too much, as it may miss the target
+integer   WANDERRAND = TRUE;   // set to TRUE and they will pause during wanders a random number of seconds
+float     WANDERTIME = 3.0;    // how long they stand after each @wander,if WANDERRAND is FALSE. If WANDERRAND is  TRUE, this is the max time
+integer   WAIT = 30;           // wait for this number of seconds for the NPC to reach a destination (for safety). If it fails to reach a target, it will move on after this time.
+float     RANGE = 50;        // 1 to N meters  - anyone this close to the controller will start NPCS if Sensor button is clicked
+float     REZTIME = 2.0;      // wait this long for NPC to rez in, then start the process
+string    STAND = "Stand";     // the name of the default Stand animation
+string    WALK = "Walk";       // the name of the default Walk animation
+string    FLY = "Fly";        // the name of the default Fly animation
+string    RUN = "Run";        // the name of the default Run animation
+string    LAND = "Land";      // the name of the default land animation ( for birds only)
+float     OffsetZ = 0.5;      // appear 0.5 meter above ground, this is added to all destinations to keep them from sinking in.  
+float    SPEEDMULT =0.5;     // 1.0 = regular avatar speed. Smaller numbers slow down walks. Large numbers speed them up.
+integer  FLIGHT = 299;        // For controlling wings.  A channel that is shouted at when flight starts and ends. "flying" or "landing" 
+
+// DESCRIPTIONS FIELDS HAVE TO SURVIVE A RESET
+//  These vars are stored  by saving them with KeyValueSet
+// "pr" is a 0 if it is set for Owner Only, 1 for Group control
+// "se" is "on" if Started
+// "co" = "R" or "A" for relative or absolute addressing mode
+// "key" = NPC key
+
+// These Globals used to be stored in description.   Moved to RAM in V1.6
+float RAMPause;          // @pause param
+float RAMwd ;            // @wander distance
+integer RAMwc;           // @wander count
+float RAMrot;            //  @rotate
+string RAMsit;           // @sit primname
+string RAMtouch;         // @touch primname
+string RAManimationName; // @animate animation (string) time (float)
+float RAManimationTime;
+
+// other globals section
+integer iChannel;        // a listen channel, randomly assigned
+integer iHandle;         // the handle to it
+
+// NPC controls
+vector newDest ;                // tmp storage for the walks
+integer iWaitCounter ;          // wait for this number of seconds for the NPC to reach a desrtination
+string sNPCName;                // the name of the NPC that may be in world. So we can remove it.
+integer bNPC_STOP = FALSE;      // boolean to reuse a listener
+integer Stopped = FALSE;        // set to TRUE by link messages so we do not remember them
+float  fTimerVal ;              // how long we wait when wandering (calculated)
+float NPCEnabled;               // true if the NPC is suppodes to be running
+
+// OS_NPC_CREATOR_OWNED will create an 'owned' NPC that will only respond to osNpc* commands issued from scripts that have the same owner as the one that created the NPC.
+// OS_NPC_NOT_OWNED will create an 'unowned' NPC that will respond to any script that has OSSL permissions to call osNpc* commands.
+integer  NPCOptions = OS_NPC_CREATOR_OWNED;    // only yhe owner of this box can control this NPC.
+
+integer walkstate = 0;  // helps us reshare the walk state for run, fly and land - a bit of a hack, but it saves RAM. Has to be done this way because some bits of NPCWalkOption are asserted as 0
+
+integer NPCWalkOption;   // Some notes for what happens to NPCWalkOption:
+// OS_NPC_FLY - Fly the avatar to the given position. The avatar will not land unless the OS_NPC_LAND_AT_TARGET option is also given.
+// OS_NPC_NO_FLY - Do not fly to the target. The NPC will attempt to walk to the location. If it's up in the air then the avatar will keep bouncing hopeless until another move target is given or the move is stopped
+//OS_NPC_LAND_AT_TARGET - If given and the avatar is flying, then it will land when it reaches the target. If OS_NPC_NO_FLY is given then this option has no effect.
+// OS_NPC_RUNNING - if given, NPC avatar moves at running/fast flying speed, otherwise moves at walking/slow flying speed.
+
+// menus
+string mSensor="Sense is Off";    // Sensor or "No Sensor"
+
+list lAtButtons = ["Menu","-",   ">>",         "@run",    "@walk",   "@fly",  "@land", "@wander",    "@sit",   "@stand","@animate","@rotate"];
+list lMenu2 = ["<<", "@comment", ">>>",        "@stop",      "@say",    "@whisper","@shout","@sound","@randsound","@cmd",  "@pause",  "@delete"];
+list lMenu3 = ["<<<","@notecard","@appearance", "@touch", "@speed",       "@attach",     "@teleport","-", "-", "-", "-", "-" ];
+
+string sCommand;  // place to store a command for two-prompted ones
+string sParam2;   // place to store a prompt for two-prompted ones
+string priPub = "Owner Only";    // Private or Group
+key kUserKey;        // the person who is controlling the avatar, not the Owner  
+// the command lists
+list lCommands;  // commands are stored here
+list lNpcCommandList; // Storage for the NPC script.
+string npcAction; // Storage for the next action. @cmd=0|hello, this becomes @cmd
+string npcParams; // Storage for the param, @cmd=0|hello, this becomes 0|hello
+
+// misc vars
+string sNotecard; // commands are stored here temporarily for dumping
+vector  vWanderPos; // a place to wander to
+string lastANIM ;   // last animation run
+// Sensor
+integer avatarPresent;   // Sensor sets this flag when people are within Range.
+
+// Coordinate control
+vector vInitialPos ; // Vector that will be filled by the script with the initial starting position in region coordinates.
+vector vDestPos = ZERO_VECTOR; // Storage for destination position.
+string relAbs = "Relative";    // absolute vs relative positioning
+
+
+// STATES
+integer MENU ;             // processing a dialog box state, may be concurrent with STATE
+integer STATE;             // state storage
+integer MakeNotecard = 1;  // displaying a text box for NPC name
+integer RecordPath = 2;    // displaying a path notecard menu
+integer NobodyHome = 3;    // looking for an avatar
+integer Spawning = 4;      // spawning an avatar
+integer Animate = 5;       // animation timer needed
+integer Walking = 6;       // Hey! I am walking here!
+integer Wander = 7;        // Wandering around neeeds a timer, too
+integer WanderHold = 8;    // We reached a wander point
+integer DoProcess = 9;     // Set this to make it process a new command
+integer Touch = 10;        // Timer is busy sensing something to touch
+integer Sit = 11;          // Timer is busy sensing something to sit on
+integer Paused = 12;       // Timer is busy pausing
+
+key gNpcKey = NULL_KEY;   // global key storage for the one NPC, to save CPU cycles
+list Stack ;              // a command stack from link message input
+
+integer SensorFunc = 0;    // define which function shall be triggered inside the sensor function
+                           // 0 means none, 1 sit, 2 touch
+///////////////////////////////////////////////////////////////////////////
+//                              FUNCTIONS                                //
+///////////////////////////////////////////////////////////////////////////
+
+
+TimerEvent(float timesent)
+{
+    if (LSLEditor)
+        timesent *= 5;   // slow thinggs doen when the LSLEDITOR is in use
+        
+    DEBUG("Setting  timer: " + (string) timesent);
+    llSetTimerEvent(timesent);
+}
+
+// for 4.1 parse a message from a Listen or a Link message
+ParseMsg(string str) {
+    DEBUG("Command In:" + str);
+    if (str=="@go") {
+        SetStop(FALSE); // Let's run the notecard
+        DEBUG("@go running");
+        DoProcessNPCLine();
+    } else {
+        Stack += [str];    // take anything, the controller will filter away non @ stuff
+        if (STATE == 0) {
+            DEBUG("calling DoNPC");
+            DoProcessNPCLine();
+        } else{
+            DEBUG("Queued");
+        }
+    }
+}
+
+SetStop(integer what)
+{
+    DEBUG("Stopped set to " + (string ) what);
+    Stopped = what;
+}
+// Do* functions are much like states from the old V2 scripts.
+    
+// Save a Path notecard
+DoSave()
+{ 
+    STATE = MakeNotecard;
+    makeText("Stand where you want the NPC to appear, and enter the NPC Name");
+}
+
+// This function is used to record the path for the NPC
+// Each command can take 0, 1, or 2 params
+DoMenuForCommands() {
+    makeMenu(lAtButtons);
+}
+
+
+// No one is here when sensors were on, so we kill off the NPC
+DoNobodyHome()
+{
+    DEBUG("Nobody Home");
+    STATE = NobodyHome;
+    if (NPCKey() != NULL_KEY) {
+        osNpcRemove(NPCKey());
+        SaveKey(NULL_KEY);
+    }
+    TimerEvent(5);  // keep ticking to sense avatars   
+}
+
+// Create a NPC
+StateSpawn() {
+    DEBUG("state spawn");
+    STATE = Spawning;
+
+ 
+    NPCEnabled = TRUE; //  in world
+    // see if there is already one out there.
+    if (NPCKey() != NULL_KEY) {
+        DEBUG("Already living");
+        return;
+    }
+    
+        
+    list name = llParseString2List(sNPCName, [" "], []);
+   
+     vector vRezPos = vInitialPos;
+    if (relAbs == "Relative"){
+        vRezPos += llGetPos();
+    }
+
+    DEBUG("Rezzing the  NPC:" + (string) vRezPos);
+    key aKey = osNpcCreate(llList2String(name, 0), llList2String(name, 1), vRezPos, Appearance, NPCOptions);
+
+    SaveKey(aKey); // save in desceription and global, too
+    
+    osSetSpeed(aKey,SPEEDMULT);   // 1.9 speed multiplier
+    TimerEvent(REZTIME);
+    NPCAnimate(STAND);
+}
+ 
+DoRotate() {
+    DEBUG("@rotate=" + (string) RAMrot); 
+    osNpcSetRot(NPCKey(), llEuler2Rot(<0,0,RAMrot> * DEG_TO_RAD));
+}  
+
+StateSit() {
+    DEBUG ("state sit - looking for " + RAMsit);
+    STATE=Sit;
+    SensorFunc = 1; //triggers osNpcSit
+    llSensor(RAMsit, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+
+StateTouch() {
+    DEBUG ("state touch - looking for " + RAMtouch);
+    STATE = Touch;
+    SensorFunc = 2; //triggers osNpcTouch
+    llSensor(RAMtouch, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+ 
+DoStand() {
+    DEBUG("state stand");
+    osNpcStand(NPCKey());
+}
+
+
+StateAnimate() {
+    
+    DEBUG("state animate");
+    STATE = Animate;
+    NPCAnimate(RAManimationName);
+    if (RAManimationTime <=0 )    // V 3.4 tweak
+        RAManimationTime = 1;
+    TimerEvent(RAManimationTime);
+}
+    
+StateWalk() {
+
+    DEBUG("NPCWalkOption = " + (string) NPCWalkOption);
+    STATE = Walking;
+            
+    // walk, fly, run, land
+   if (walkstate == 1) {
+        NPCAnimate(WALK);
+    } else if (walkstate == 2)  {
+        llShout(FLIGHT,"flying");
+        NPCAnimate(FLY);
+    } else if (walkstate == 3) {
+        NPCAnimate(RUN);
+    } else if (walkstate == 4) {
+        NPCAnimate(LAND);
+    } 
+    newDest = vDestPos ;
+    newDest.z += OffsetZ;
+        
+    // notecard is stored as offsets from this box with relative addressing.  Convert to absolute
+    if (relAbs == "Relative"){
+        newDest += llGetPos();
+    }
+
+    DEBUG("Moveto:" + (string) newDest);
+    osNpcMoveToTarget(NPCKey(), newDest, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);
+}
+
+
+StateWander(){
+    DEBUG("state wander");
+    STATE = Wander;
+    
+    vector point = CirclePoint(RAMwd);
+    DEBUG("CirclePoint:" + (string) point);
+    vWanderPos = vDestPos + point;
+    DEBUG("vWanderPos:" + (string) vWanderPos);
+
+    fTimerVal = WANDERTIME;    // default time to pause after each wander
+    if (WANDERRAND)
+        fTimerVal = llFrand(WANDERTIME) + 1;    // override, they want random times
+
+    NPCAnimate(WALK);
+
+    DEBUG("Wander to:" + (string) vWanderPos);
+
+    osNpcMoveToTarget(NPCKey(), vWanderPos, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);      
+}
+
+StateWanderhold() {
+
+    DEBUG("Wander Hold");
+    STATE = WanderHold;
+       
+     // now that we have reached a wander spot, slow the timer down to the desired value
+    TimerEvent(fTimerVal);
+}
+
+// @pause=10 will do nothing for 10 seconds
+DoPause() {
+    STATE =Paused;
+    if (RAMPause < 0.1)
+        RAMPause = 0.1;
+    DEBUG("@pause=" + (string)RAMPause);
+    TimerEvent(RAMPause);
+}
+
+
+// @stop makes the NPC stop moving in whatever state it is in.  You have to linkmessage to get moving again
+DoStop() {    
+    DEBUG("NPC is Stopped");
+    STATE = 0;    // accept commands
+    SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+    
+// @delete removes the NPC forever. Next command starts it up again at the beginning
+DoDelete() {
+    DEBUG("state delete");
+    STATE = 0;    // accept commands
+    osNpcRemove(NPCKey());
+    SaveKey(NULL_KEY);
+    
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+
+// change the appearance of the NPC
+DoAppearance(string notecard) {
+    DEBUG("state appearance");
+    if (llGetInventoryType(notecard) == INVENTORY_NOTECARD){
+        DEBUG("Load appearance " + notecard);
+        osNpcLoadAppearance(NPCKey(),notecard);
+    }
+}
+
+// Change the avatar speed
+DoSpeed(string speed) {
+    float newspeed = (float) speed;
+    if (newspeed > 0.1 && newspeed < 5.0) {// sanity check
+        osSetSpeed(NPCKey(),newspeed);
+    }
+}
+
+DoTeleport(string params) {
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    vector Dest = (vector) itemName;
+    if (Dest != ZERO_VECTOR) {
+        if (relAbs == "Relative"){
+            Dest += llGetPos();
+        }
+        osTeleportAgent( NPCKey(), llGetRegionName(), Dest, ZERO_VECTOR );
+        
+    } else {
+        llSay(DEBUG_CHANNEL,"Attempt to teleport to <0,0,0> probably not what you intended: @teleport=<vector>");
+    }
+}
+
+
+
+DoNewNote (string card) {
+    DEBUG("Load Notecard " + card);    
+    NPCReadNoteCard(card);
+    SetStop(FALSE);
+}
+DoAttach(string params) {
+    
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    integer attachmentPoint  = (integer) llList2String(Data, 1);
+    if (attachmentPoint > 0
+        && attachmentPoint < 40
+        && llGetInventoryType(itemName) == INVENTORY_OBJECT
+       )
+    {
+        osForceAttachToOtherAvatarFromInventory(NPCKey(),itemName,attachmentPoint);
+    }
+}
+
+// This loops over the notecard, processing each command
+DoProcessNPCLine() {
+    DEBUG("ProcessNPCLine, stopped = " + (string) Stopped);
+    STATE = DoProcess;
+
+        // auto load a notecard
+    if (! llGetListLength(lNpcCommandList)) {
+        DEBUG("Read Notecard");
+        NPCReadNoteCard(Notecard);
+        SetStop(FALSE);
+    }
+
+    // look for link messages on the stack
+    string next = llList2String(Stack,0);    // lets see if there is anithing from a link message
+    if (llStringLength(next))
+    {
+        Stack = llDeleteSubList(Stack,0,0);
+        ProcessCmd(next);        //lets do this command instead.
+        return;
+    }
+
+    // @stop issued?
+    if (Stopped) {
+        TimerEvent(0);
+        DEBUG("Stopped, waiting for input");
+        STATE = 0;
+        return;
+    }
+
+    // No, we have an @go for liftoff
+    next = llList2String(lNpcCommandList, 0);        // get the next command
+    DEBUG("Execute:" + next);
+    lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);      // delete it
+        
+    if (llGetListLength(lNpcCommandList) == 0) {
+        DEBUG("EOF");
+    }
+    ProcessCmd(next); 
+} 
+
+
+
+ProcessCmd(string cmd) {
+
+    DEBUG("ProcessCmd:" + cmd);
+
+    if (llGetSubString(cmd, 0, 0) != "@") {
+        DEBUG("ignoring");
+        TimerEvent(QUICK);  // this is so we do not recurse the stack
+        STATE = 0;
+        return;
+    }
+
+    list data  = llParseString2List(cmd, ["="], []);
+    npcAction = llToLower(llStringTrim(llList2String(data, 0), STRING_TRIM));
+
+    DEBUG("Action:" + npcAction);
+    npcParams = llStringTrim(llList2String(data, 1), STRING_TRIM);
+    DEBUG("Params:" + npcParams);
+    
+    @commands;
+
+    ProcessSensor();
+    
+    if(npcAction == "@spawn" && avatarPresent) {
+        DEBUG("@spawn");
+        list spawnData = llParseString2List(npcParams, ["|"], []);
+        sNPCName =llList2String(spawnData, 0);    // V 1.6 name in RAM
+
+        list spawnDest = llParseString2List(llList2String(spawnData, 1), ["<", ",", ">"], []);
+        vInitialPos.x = llList2Float(spawnDest, 0);
+        vInitialPos.y = llList2Float(spawnDest, 1);
+        vInitialPos.z = llList2Float(spawnDest, 2);
+        
+        DEBUG("Coords for NPC at " + (string) vInitialPos);
+        StateSpawn();
+        return;
+    }
+    
+     if (! avatarPresent){
+        DoNobodyHome();
+        DEBUG("No avatar nearby");
+        STATE = 0;
+        return;
+    } else {
+        if ( NPCKey() == NULL_KEY) {
+            StateSpawn();
+        }
+    }
+
+    
+    
+    
+    if(npcAction == "@stop") {
+        DoStop();
+        STATE = 0;
+        return;
+    }
+    else if(npcAction == "@goto") {
+        DEBUG("goto");
+        integer lastIdx = llGetListLength(lNpcCommandList)-1;
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, lastIdx, lastIdx);
+        // Wind commands till goto label.
+        @wind;
+        string next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        if(next1 != npcParams) jump wind;
+        // Wind the label too.
+        next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        // Get next command.
+        list data1  = llParseString2List(next1, ["="], []);
+        npcAction = llToLower(llStringTrim(llList2String(data1, 0), STRING_TRIM));
+        npcParams = llStringTrim(llList2String(data1, 1), STRING_TRIM);
+        // Reschedule.
+        jump commands;
+    }
+    else if(npcAction == "@sound") {
+        DEBUG("sound");
+        llTriggerSound(npcParams,1.0);
+    }
+    else if(npcAction == "@randsound") {
+        DEBUG("@randsound");
+        integer N = llGetInventoryNumber(INVENTORY_SOUND);
+        integer rand = llCeil(llFrand(N)) -1;    // pick a random sound
+        string toPlay = llGetInventoryName(INVENTORY_SOUND,rand);
+        llTriggerSound(toPlay,1.0);
+    }
+    else if(npcAction == "@walk") {
+        DEBUG("@walk");
+        GetDest(npcParams);
+        walkstate = 1;//  walking
+        NPCWalkOption = OS_NPC_NO_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@fly") {
+        GetDest(npcParams);
+        walkstate = 2;//  flying
+        NPCWalkOption = OS_NPC_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@run") {
+        DEBUG("@run");
+        GetDest(npcParams);
+        walkstate = 3;//  running
+        NPCWalkOption = OS_NPC_NO_FLY | OS_NPC_RUNNING;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@land") {
+        DEBUG("@land");
+        GetDest(npcParams);
+        walkstate = 4;//  landing
+        NPCWalkOption= OS_NPC_FLY | OS_NPC_LAND_AT_TARGET ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@say") {
+        DEBUG("@say " + npcParams);
+        osNpcSay(NPCKey(), 0, npcParams);
+    }
+    else if(npcAction == "@shout") {
+        DEBUG("@shout");
+        osNpcShout(NPCKey(),0, npcParams);
+    }
+    else if(npcAction == "@whisper") {
+        DEBUG("@whisper " + npcParams);
+        osNpcWhisper(NPCKey(),0, npcParams);
+    }
+    // speak a command on a channel, so you can open doors and control stuff.
+    else if(npcAction == "@cmd") {
+        DEBUG("@cmd");
+        list dataToSpeak = llParseString2List(npcParams, ["|"], []);
+        string channel = llList2String(dataToSpeak,0);
+        DEBUG("Channel:"+(string) channel);
+        integer iChannel = (integer) channel;
+        string stringToSpeak = llList2String(dataToSpeak,1);
+        llSay(iChannel, stringToSpeak);
+    }
+    // stop everything
+    else if(npcAction == "@pause") {
+        RAMPause = (float) npcParams;
+        DoPause();
+        return;
+    }
+    else if(npcAction == "@wander") {
+        list wanderData = llParseString2List(npcParams, ["|"], []);
+        RAMwd = (float) llList2String(wanderData, 0);
+        RAMwc = (integer) llList2String(wanderData, 1);
+        vDestPos = osNpcGetPos(NPCKey());        // set the wander start
+        DEBUG("Starting at " + (string) vDestPos);
+        StateWander();
+        return;
+    }
+    else if(npcAction == "@rotate") {
+        RAMrot = (float) npcParams;
+        DoRotate();
+    }
+    else if(npcAction == "@sit") {
+        RAMsit= npcParams;
+        StateSit();
+        return;
+    }
+    else if(npcAction == "@touch") {
+        RAMtouch= npcParams;
+        StateTouch();
+        return;
+    }
+    else  if(npcAction == "@stand") {
+        DoStand();
+    }
+    else if(npcAction == "@delete") {
+        DoDelete();
+        SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+        return;
+    }
+    else if(npcAction == "@animate") {
+        list animateData = llParseString2List(npcParams, ["|"], []);
+        RAManimationName = llList2String(animateData, 0);
+        RAManimationTime = (float) llList2String(animateData, 1);
+        StateAnimate();
+        return;
+    }
+    else if(npcAction == "@appearance" ){
+        DoAppearance(npcParams);
+    }
+    else if (npcAction =="@speed") {
+        DoSpeed(npcParams);
+    }
+    else if (npcAction =="@notecard") {      
+        DoNewNote(npcParams);
+        Notecard = npcParams;
+    }
+    else if (npcAction == "@attach")
+    {
+        DoAttach(npcParams);
+    }
+    else if (npcAction == "@teleport")
+    {
+        DoTeleport(npcParams);
+    }
+    else if (npcAction == "@reset")
+    {
+        DoDelete();
+        SetStop(FALSE); // a @resst will restart the original !Path after deleting the notecard.
+    }
+
+    STATE = 0;
+    TimerEvent(QUICK);  // yeah I know, not possible this fast, we just go as fast as we can go - this is so we do not recurse the stack 
+}
+ 
+
+
+/////////////////// UTILITY Functions, not state-like //////////////////
+
+// DEBUG(string) will chat a string or display it as hovertext if debug == TRUE
+DEBUG(string str) {
+    if (debug && ! LSLEditor)
+        llOwnerSay( str);                    // Send the owner debug info 
+    if (debug &&  LSLEditor)
+        llSay(0, str);                    // Send to the Console in LSLEDitor 
+    if (iTitleText) {
+        llSetText(str,<1.0,1.0,1.0>,1.0);    // show hovertext
+    
+    }
+}
+
+GetDest(string npcParams) {
+    list dest = llParseString2List(npcParams, ["<", ",", ">"], []);
+    vDestPos.x = llList2Float(dest, 0);
+    vDestPos.y = llList2Float(dest, 1);
+    vDestPos.z = llList2Float(dest, 2);
+}
+
+NPCReadNoteCard(string Note) {
+    DEBUG("NPCReadNoteCard");             
+    lNpcCommandList = llParseString2List(osGetNotecard(Note), ["\n"], []);
+}  
+  
+integer SenseAvatar()
+{
+    //Returns a strided list of the UUID, position, and name of each avatar in the region
+    list avatars = llGetAgentList(AGENT_LIST_REGION ,[]);
+    integer numOfAvatars = llGetListLength(avatars);
+    if (numOfAvatars == 0)
+    {
+        DEBUG("No people");
+        return 0;
+    }
+    //DEBUG("Located " + (string)numOfAvatars + " avatars and NPC's"); 
+        
+    integer nAvatars;
+    integer i;
+    for( i = 0;i < numOfAvatars; i++) {
+        key aviKey = llList2Key(avatars,i);
+        if (!osIsNpc(aviKey)) {
+            list detail = llGetObjectDetails(aviKey,[OBJECT_POS]);
+            vector pos = llList2Vector(detail,0);
+            float dist = llVecDist(pos, llGetPos());
+            if (dist  < RANGE)
+            {
+                nAvatars++;
+                DEBUG("In range:" + llKey2Name(aviKey));
+            }
+        }
+    }
+    //DEBUG("Located " + (string) nAvatars + " avatars");
+    return nAvatars;
+} 
+ 
+// return TRUE if the avatar is owner when private is set, or TRUE if the avatar is in the same group and GROUP is set.
+integer checkPerms() {
+
+    integer group = (integer) KeyValueGet("pr");
+    if (! group)
+        priPub = "Owner Only";
+    else
+        priPub = "Group";
+    
+    
+    if (llDetectedKey(0) == llGetOwner()){
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+ 
+    if ( group && llDetectedGroup(0)) {
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+    kUserKey = llDetectedKey(0);
+    return FALSE;
+}
+
+
+
+NPCAnimate(string anim)
+{
+    DEBUG("Start Anim: " + anim);
+    if (llGetInventoryType(anim) == INVENTORY_ANIMATION ) {
+        
+        if (lastANIM != anim) {
+            if(llStringLength(lastANIM)) {
+                osNpcStopAnimation(NPCKey(), lastANIM);  
+            }
+            osNpcPlayAnimation(NPCKey(), anim);
+            lastANIM = anim;
+        }            
+    } else {
+        llSay(DEBUG_CHANNEL, "No animation named " + anim);
+    }
+} 
+
+// Kill a NPC by Name
+Kill(string param)
+{
+    integer count;
+    list avatars = osGetAvatarList(); // Returns a strided list of the UUID, position, and name of each avatar in the region except the owner.\    
+    integer i;
+    integer j = llGetListLength(avatars);
+    for (i=0 ; i <= j; i+=3){
+        
+        string desired = llList2String(avatars,i+2);
+        desired = llStringTrim(desired,STRING_TRIM);    // should not be needed but is needed
+        
+        if (desired == param){
+            vector v = llList2Vector(avatars,i+1);
+            key target = llList2Key(avatars,i);    // get the UUID of the avatar
+            osNpcRemove(target);
+            
+            llOwnerSay("Removed " + param+ " at  location " + (string) v);
+            count++;
+        }
+    }
+    
+    NPCEnabled = FALSE; // not in world
+    SaveKey(NULL_KEY );    // Rev 4.4
+    
+    if (count)
+        llOwnerSay("Removed " + (string) count + " NPC's");
+    else
+        llOwnerSay("Could not locate " + param);
+}
+
+
+// return a String for the position we are at. Strings used as the caller wants strings
+string Pos()
+{
+    vector where = llGetPos(); // find the box position
+   
+    where.z +=    OffsetZ;  // use the ground position + an offset 
+        
+    if (LSLEditor)
+        where  = <128,128,31 + llFrand(1)>; // force center of sim when editing
+   
+   // if attached the height will be too high by 1/2 the agent size
+    if (llGetAttached()) {
+        vector size = llGetAgentSize(llGetOwner());   
+        float Z = size.z;
+        where.z -= Z/2;  
+    }
+   
+    // DEBUG("Pos= " + (string) where);
+    return (string) where;
+}
+
+// setup a menu with a timer for timeouts, called by all make*()
+menu()
+{
+    llListenRemove(iHandle);
+    iChannel = llCeil(llFrand(100000) + 20000);
+    iHandle = llListen(iChannel,"","","");
+    TimerEvent(30.0);
+    MENU = TRUE;
+}
+
+// make a text box
+makeText(string Param)
+{ 
+    menu();
+    llTextBox(kUserKey, Param, iChannel);
+}
+
+// top level menu
+makeMainMenu()
+{
+    menu();
+    list buttons = ["Appearance","Recording","Save","Help","-","Erase RAM", priPub,relAbs,"-","Stop NPC",mSensor,"Start NPC"];
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Records",buttons,iChannel);
+}
+
+
+// Rev 1.4
+// top level menu for non group/ non owners
+makeUserMenu()
+{
+    if (!allowUsers) return;
+    
+    menu();
+    list buttons = ["Start NPC","Stop NPC"];
+    llDialog(kUserKey,"Choose",buttons,iChannel);
+}
+
+
+
+// programmable menu for @commands
+makeMenu(list buttons)
+{
+    menu();
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Record",buttons,iChannel);
+}
+
+
+// make one or two text boxes with prompts
+Text(string cmd, string p1, string p2)
+{
+    sCommand = cmd;
+     sParam2 = "";
+    if (llStringLength(p2))
+        sParam2 = p2;
+
+    makeText(p1);
+} 
+
+// Set the Avatar Present flag - if sensors are off and we are forece run, there will be one present.
+ProcessSensor()
+{
+    integer SensorOn;
+    if ("on" == KeyValueGet("se"))
+    {
+        SensorOn = TRUE;        // we need to scan for avatars
+    } else {
+        SensorOn = FALSE;        // we need to scan for avatars
+    }
+    DEBUG("Sensor:" + (string) SensorOn);
+    
+    integer n = SenseAvatar();
+    
+    DEBUG("Avatars:" + (string) n);
+    if (SensorOn && n)
+        avatarPresent = TRUE;   // someone is here and we need to tell the system to run
+    else if (SensorOn && !n)
+        avatarPresent = FALSE;  // someone is not here and we need to tell the system to stop
+    else {       // sensor is off, lete see if there is a NPC. If so, we are ON 
+        DEBUG("NPCEnabled:" + (string) NPCEnabled);
+        if (NPCEnabled)
+            avatarPresent = TRUE;  
+        else
+            avatarPresent = FALSE;   
+    }
+    
+    //  start up from when when no one is near
+    if (avatarPresent && STATE == NobodyHome)
+        STATE = 0;
+    
+    DEBUG("Avatar Present: " + (string) avatarPresent);
+}
+
+vector CirclePoint(float radius) {
+    float x = llFrand(radius *2) - radius;        // +/- radius, randomized
+    float y = llFrand(radius *2) - radius;        // +/- radius, randomized
+    return <x, y, 0>;        // so this should always happen
+}
+
+string KeyValueGet(string var) {
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k != var) jump continue;
+        //DEBUG("got " + var + " = " +  llList2String(data, 1));
+        return llList2String(data, 1);
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    return "";
+} 
+
+KeyValueSet(string var, string val) {
+
+    //DEBUG("set " + var + " = " + val);
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    if(llGetListLength(dVars) == 0)
+    {
+        llSetObjectDesc(var + "=" + val);
+        return;
+    }
+    list result = [];
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k == "") jump continue;
+        if(k == var && val == "") jump continue;
+        if(k == var) {
+            result += k + "=" + val;
+            val = "";
+            jump continue;
+        }
+        string v = llList2String(data, 1);
+        if(v == "") jump continue;
+        result += k + "=" + v;
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    if(val != "") result += var + "=" + val;
+    llSetObjectDesc(llDumpList2String(result, "&"));
+}
+
+
+// clear RAM
+Clr() {
+
+    lCommands = [];
+    llOwnerSay("RAM Memory cleared. Notecards, if any, are not modified.");
+    makeMainMenu();
+}
+
+integer checkNoteCards()
+{
+    // Check that they have saved an Appeaance and Path notecard
+    integer num = llGetInventoryNumber(INVENTORY_NOTECARD);    // how many notecards overall
+    
+    integer i;
+    integer count;
+    for (; i < num; i++){
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Notecard)
+            count++;
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Appearance)
+            count++;
+    }
+    DEBUG("Checked " + (string) count + " Notecards");
+    // if we have both, run the NPC
+    return count;
+}
+
+Update(string SName) {
+         
+    // delete all NPC* scripts except myself
+    integer i;
+    integer j = llGetInventoryNumber(INVENTORY_SCRIPT);
+    for (i = 0; i < j; i++) {
+        string targetName = llGetInventoryName(INVENTORY_SCRIPT,i);
+        string match = llGetSubString(targetName,0,2);
+        
+        if (match == SName && llGetScriptName() != targetName){
+                llOwnerSay("Upgrading " + targetName);
+            if (! LSLEditor){        // lets not kill the editor
+                llRemoveInventory(targetName);
+            }
+        }
+    }
+}
+
+// Get all default saved params from the Description
+GetSwitches()
+{
+         string rA = KeyValueGet("co"); // Get the remembered menu setting for Abs Vs Relative
+        if (rA == "A")
+            relAbs = "Absolute";
+        else  if (rA == "R")
+            relAbs = "Relative";
+        else
+            relAbs = "Absolute";
+
+            
+        // reenable NPC if sensor is on.
+        if ("on" == KeyValueGet("se"))
+        {
+            NPCEnabled = TRUE;
+            mSensor  = "Sense is On";
+            ProcessSensor();       // fake 1 avatar to get it rezzed
+        } else {
+            mSensor  = "Sense is Off";
+        }
+    }
+
+
+SaveKey(key akey)
+{
+    DEBUG("Saving Key of " + (string) akey);
+    KeyValueSet("key", akey);
+    if (akey !=  (key) KeyValueGet("key") )
+    {
+        DEBUG("Fatal error, cannot save key");
+    }
+    gNpcKey = akey;
+}
+
+
+key NPCKey()
+{
+    key akey = gNpcKey;   // from cached copy
+    // gNpcKey saves a lot of CPU processing by caching the key, if blank we get it from the description
+    if (gNpcKey == NULL_KEY)
+    {
+        //DEBUG("Get DKey");
+        akey = KeyValueGet("key");    // from Description of the prim
+    }
+   // DEBUG("NPC KEY:" + (string) akey);   
+    return  akey;
+}
+
+
+/////////////////// CODE BEGINS //////////////////
+
+
+default
+{
+    changed(integer change) {
+        if(change & CHANGED_REGION_START) {
+            llResetScript();
+        }
+    }
+    
+    on_rez(integer start_param)
+    {
+        llResetScript();
+    }
+
+    state_entry() {
+        
+        llSetText("",<1,1,1>,1.0);  // clr all hovertext- we may not be using it.
+        DoDelete(); // kill any NPC that is out running
+        Update("NPC"); // If dragged and ropped into a prim with any script named "NPC...", this will replace it.
+        GetSwitches(); // Get all default saved params from the Description
+
+        // 4.1 allow listeners to send us commands
+        if (allowListener)
+            llListen(link_Channel,"","","");
+        TimerEvent(TIMER);
+    } 
+
+
+    touch_start(integer n) 
+    {           // if touched, make a menu
+    
+        if (checkPerms()) {
+            if (RecordPath == STATE) {
+                makeMenu(lAtButtons); 
+            }   else {
+                makeMainMenu();
+            }
+        } else {
+            makeUserMenu();
+        }
+    }
+
+    // menu listener
+    listen(integer iChannel, string name, key id, string message) {
+
+        // process @commands that come in via the listener
+        if (iChannel == link_Channel)
+        {
+            ParseMsg(message);
+            return;
+        }
+        
+        if (MENU) {
+            llListenRemove(iHandle);
+            MENU = 0;       // menu is off
+            iHandle = 0;
+        }
+        
+        if (message == "Stop NPC")
+        {
+            lNpcCommandList = []; // force reload of notecard
+            NPCEnabled = FALSE;
+            if (NPCKey() != NULL_KEY){
+                Kill(sNPCName);
+                sNPCName = "";
+            } else {
+                bNPC_STOP = TRUE;
+                makeText("Enter name of an NPC to stop");
+            }
+        }
+        else if (message == "Menu" ) {
+            makeMainMenu();
+        }
+        else if (message == "Erase RAM"){
+            Clr();
+        }
+        else if (message == "Relative"){
+            relAbs = "Absolute";
+            KeyValueSet("co","A");   // remember coordinates = A
+            Clr();
+        }
+        else if (message == "Absolute"){
+            relAbs = "Relative";
+            KeyValueSet("co","R");   // remember coordinates = R
+            Clr();
+        }
+        else if (message == "Recording"){
+            DoMenuForCommands();        // show them the recording menu
+        }
+        else if (message == "Owner Only") {
+            priPub = "Group";
+            KeyValueSet("pr","1");
+
+            llOwnerSay("Group members have control");
+            makeMainMenu();
+        }
+        else if (message == "Group") {
+            priPub = "Owner Only";
+            KeyValueSet("pr","0");
+            llOwnerSay("Only you have control");
+            makeMainMenu();
+        }
+        else if (message == "Sense is On") {
+            mSensor ="Sense is Off";
+            KeyValueSet("se", "off");
+            llOwnerSay(mSensor);
+            makeMainMenu();
+        }
+        else if (message == "Sense is Off") {
+            mSensor ="Sense is On";
+            llOwnerSay(mSensor);
+            KeyValueSet("se", "on");
+            
+            NPCEnabled = FALSE;
+            
+            integer count = checkNoteCards();
+            if (count >= 2)  {
+                DEBUG("Notecards ok, DoProcessNPCLine");
+                DoProcessNPCLine();
+                return;
+            }
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording and/or appearance, so you cannot start a NPC");
+            makeMainMenu();
+        }
+        else if (message == "Appearance")  {
+            llRemoveInventory(Appearance);            // delete the notecard
+            osAgentSaveAppearance(kUserKey,Appearance);    // make the ntecard 
+            llOwnerSay("Your outfit has been saved");
+            makeMainMenu();
+        }
+        else if (message == "Save") {
+            if (llGetListLength(lCommands) == 0) {
+                llOwnerSay("Nothing recorded, you need to make a recording first");
+                makeMainMenu();
+                return;
+            }
+            DoSave();
+        }
+        else if (message == "Help"){
+            llLoadURL(kUserKey,"Click to view help","http://www.outworldz.com/opensim/posts/NPC/");
+            makeMainMenu();
+        }
+        else if (message == "Start NPC")    {
+            integer count = checkNoteCards();
+
+            NPCEnabled = TRUE;
+
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+            
+            if (count >= 2) {
+                DEBUG("Notecards approved , calling DoProcessNPCLine");
+                SetStop(FALSE); // Let's run the notecard
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording or maybe an appearance, so we cannot start a NPC");
+      
+        }
+        else if (bNPC_STOP){
+            bNPC_STOP = FALSE;
+            Kill(message);
+        }
+        else if (message == ">>"){
+            makeMenu(lMenu2);
+        }
+        else if (message == ">>>"){
+            makeMenu(lMenu3);
+        }
+        else if (message == "<<") {
+            makeMenu(lAtButtons);
+        }
+        else if (message == "<<<") {
+            makeMenu(lMenu2);
+        }
+        else if (message == "@comment"){
+            Text("# ","Enter a comment","");
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@run"){
+            lCommands += "@run=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@fly"){
+            lCommands += "@fly=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@land"){
+            lCommands += "@land=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@walk") {
+            lCommands += "@walk=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@sound"){
+            Text("@sound=","Enter a sound name or UUID to trigger","");
+        }
+        else if (message == "@randsound"){
+            lCommands += "@randsound"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@say") {
+            Text("@say=","Enter what the NPC will say","");
+        }
+        else if (message == "@whisper"){
+            Text("@whisper=","Enter what the NPC will whisper","");
+        }
+        else if (message == "@shout"){
+            Text("@shout=","Enter what the NPC will shout","");
+        }
+        else if (message == "@wander") {
+            Text("@wander=","Enter radius to wander","Enter number of wanders");
+        }
+        else if (message == "@pause") {
+            Text("@pause=","Enter time to pause","");
+        }
+        else if (message == "@rotate") {
+            Text("@rotate=","Enter degrees to rotate","");
+        }
+        else if (message == "@sit"){
+            Text("@sit=","Enter name of object to sit on","");
+        }
+        else if (message == "@teleport"){
+            lCommands += "@teleport=" + Pos() + "\n";
+            llOwnerSay("teleport to position: " + Pos());
+            makeMenu(lMenu3);
+        }
+        else if (message == "@touch"){
+            Text("@touch=","Enter name of object to touch","");
+        }
+        else if (message == "@cmd"){
+            Text("@cmd=","Enter cjhannel to speak on","Enter text to speak");
+        }
+        else if (message == "@stand"){
+            lCommands += "@stand\n";
+            llOwnerSay("Stand Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@animate"){
+            Text("@animate=","Enter animation name to play","Enter time to play the animation");
+        }
+        else if (message == "@attach"){
+            Text("@animate=","Enter inventory name to attach","Enter number of the attachment point (1-40)");
+        }
+         else if (message == "@speed"){
+            Text("@speed=","Enter a speed for the NPC, 1=100% normal speed, 0.5=50% speed","");
+        }
+               
+
+        // Save NPC name
+        else if (MakeNotecard == STATE) {
+            sNPCName = message; // in case we need to kill it.
+            
+            vector  vDest = (vector)  Pos();
+
+            if (relAbs == "Relative")
+            {
+                vDest  -= llGetPos();    // just an offset for relative
+            }
+            sNotecard = "@spawn=" + message + "|" +  (string) vDest  + "\n";
+            integer i;
+            integer j = llGetListLength(lCommands);
+            for (; i < j; i++){
+                // get the command to save to the notecard
+                string line = llList2String(lCommands,i);
+                if (relAbs == "Absolute") {
+                    sNotecard += line;    // add the un-modified string to the notecard
+                } else {
+                        // since we have to record absolute coords since we do not know where the box goes until they press Save,
+                        // we process the absolute to relative conversion for walks here
+                        list parts = llParseString2List(line,["="],[]); //get the @command
+
+                    if (llList2String(parts,0) == "@walk") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@walk=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@fly") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@fly=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@run") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@run=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@land") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@land=" + (string) vec + "\n";
+                    }
+                    else {
+                        sNotecard += line;    // add the un-modified string to the notecard
+                    }
+                }
+            }
+            llRemoveInventory(Notecard);        // delete the old notecard
+            osMakeNotecard(Notecard,sNotecard); // Makes the notecard.
+            llSay(0,sNotecard);
+            llOwnerSay("Commands notecard has been written");
+            STATE = 0;
+        } // MakeNotecard
+
+        else  if (! llStringLength(sParam2)) {
+            lCommands +=  sCommand + message + "\n";
+            llOwnerSay("Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (llStringLength(sParam2)){
+            sCommand = sCommand + message + "|";
+            llOwnerSay("Recorded");
+            makeText(sParam2);
+            sParam2 = "";
+        }
+
+    }
+
+
+
+    timer(){
+       // DEBUG("tick");
+        
+        // if llDialog is up, kill the listener for the dialog box.
+        if (iHandle) {
+            llOwnerSay("Menu timed out");
+            llListenRemove(iHandle);
+            iHandle = 0;
+            return;             // ^^^^^^^^^^^^^^^^^^^^^^^
+        }
+        // if NoBodyHome, we are sensing for an avatar
+        else if (NobodyHome == STATE) {
+            ProcessSensor();
+            return;
+        }
+        // if we are spawning, we need time to rez the NPC, then start processing NPC Commands.
+        else if (Spawning == STATE) {
+            STATE = 0;
+            TimerEvent(TIMER);
+        }
+        // We end aniamtions with a timer
+        else if (Animate == STATE){
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+        }
+        
+        else if (Walking == STATE) {
+            if (--iWaitCounter) {
+                if (llVecDist(osNpcGetPos(NPCKey()), newDest) > MAXDIST)  {
+                    return;
+                }
+            }
+
+            DEBUG("At Destination: " + (string) newDest);
+            
+            // walk, fly, run, land
+            if (walkstate == 1) {
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 2)  {
+                    // nothing
+                } else if (walkstate == 3) {
+                     NPCAnimate(STAND);
+                     NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 4) {
+                llShout(FLIGHT,"landing");
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            }
+        }
+        // Wandering timer 
+        else if (Wander == STATE) {
+            if (--iWaitCounter) {          // wait 60 seconds to get to a destination.
+                if (llVecDist(osNpcGetPos(NPCKey()), vWanderPos) > MAXDIST)
+                    return;
+            }
+
+            // see if wander counter == 0, if so, stop walking, go to stand and process next line
+            if(RAMwc == 0) {
+                NPCAnimate(STAND);
+                DEBUG("Wander ended, calling DoProcessNPCLine");
+                STATE = 0;
+                DoProcessNPCLine();
+                return;
+            }
+            // one less time to wander around
+            RAMwc--;
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+            StateWanderhold();
+            return;
+        }
+        // Wandering requires us to re-wander when we reach a destination
+        else if (WanderHold == STATE) {
+            StateWander();
+            TimerEvent(TIMER);
+            return;
+        }
+        else if (DoProcess == STATE) {
+            TimerEvent(QUICK);
+        }
+
+       
+        STATE = 0;
+
+        // We always process a NPC line at end of timer.
+        DEBUG("Tick end, calling DoProcessNPCLine");
+        DoProcessNPCLine();
+    }
+
+    // sensors are used for sitting on prims
+    // Neo Cortex: added different SensorFunc states to trigger sit or touch
+    sensor(integer num) {
+        if (SensorFunc == 1) {
+            osNpcSit(NPCKey(), llDetectedKey(0), OS_NPC_SIT_NOW);
+            DEBUG("Seated, calling DoProcessNPCLine");
+            SensorFunc = 0;
+        } else if (SensorFunc == 2) {
+            osNpcTouch(NPCKey(), llDetectedKey(0), LINK_THIS);
+            DEBUG("Touched, calling DoProcessNPCLine");
+            SensorFunc = 0;
+        }
+        DoProcessNPCLine();
+    }
+    no_sensor(){
+        DEBUG ("no target prim located, calling DoProcessNPCLine");
+        SensorFunc = 0;
+        DoProcessNPCLine();
+    }
+
+    
+    link_message(integer sender, integer num, string str, key id){
+        ParseMsg(str);
+    }
+        
+}
+
+
+
+
+
+
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.5.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.5.lsl
new file mode 100644
index 00000000..ced2d987
--- /dev/null
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.5.lsl	
@@ -0,0 +1,1689 @@
+// :SHOW:1
+// :CATEGORY:NPC
+// :NAME:All In One NPC Recorder and Player
+// :AUTHOR:Ferd Frederix
+// :KEYWORDS:NPC, Puppeteer
+// :CREATED:2015-09-29 18:04:52
+// :EDITED:2015-09-29  17:04:52
+// :ID:27
+// :NUM:1831
+// :REV:4.5
+// :WORLD:OpenSim
+// :DESCRIPTION:
+// All in one NPC recorder player.
+// Supports both absolute and relative paths and many new commands
+// Add animations named "Fly, Walk, Stand and Run"
+// Click Prim to use.
+// Should be worn as a HUD to record.
+// Put it on the ground and click Sensor or Start NPC when done.
+// :CODE:
+// This is Rev 4.5  09/26/2015
+
+// Revision History
+// Rev 1.1 10-2-2014 @Sit did not work.  Minor tweaks to casting for lslEditor
+// Rev 1.2 10-14-2014 @ sit had wrong type.
+// Rev 1.3 relative movement fixed for @fly
+// Rev 1.4 4-3-2014 allow anyone to use this, non owners and non group members can only start and stop.
+// Rev 1.5 5-17-2014 set sensor to auto start on reboot of sim
+// Rev 1.6 5-24-2014 move menu so you can get it by touching, removed many of the KeyValues to RAM for efficiency
+// Rev 1.7 CHANGED_REGION_START, not CHANGED_REGION_START (Opensim difference)
+// Rev 1.8 tuned up Kill NPC, added more flexible upgrader
+// Rev 1.9 Better script injection by link message// Rev 2.0 Added osSetSpeed so you can speed up or slow down an NPC.
+// Rev 2.1 No laggy sensor used exept to sit on stuff
+// Rev 2.2 Various sensor fixes
+// Rev 2.3 Sets No Sensor in menu, must be started by hand
+// Rev 2.4 - reserved for patches to 2.3 if needed
+// Rev 3.0 Refactor out into subs, not states to make command injection easier
+//            New command: @appearance=Notecardname so you can switch to a new notecard on the fly
+//            New command: @speed=1.0  which slows up  ( < 1 )  or speeds up ( > 1)
+// Rev 3.1 Commands are not interruptible by Link Message
+// Rev 3.2 Sensor patches for consistency in removing the NPC
+// Rev 3.3 Added Touch command by Neo.Cortex@hbase42/hopto/org:8002
+//         Added Menu 3 for notecard and appearance commands
+// Rev 3.4 animation timer cannot be zero or it shuts off timer tweaked
+//         solves the NPC starting up when no sensor is set.
+// Rev 3.5 fixes saving to !Path  notecard
+// Rev 3.6 08-11-2015 @delete acts like @stop. TYjhe NPC now rezzes after an @go back in where it was deleted 
+// Rev 3.7 08-11-2015 @attach command added to load an attachment from the inventory to the NPC
+// Rev 3.8 08-17-2015 process queued commands one at a time without calling ProcessNPCLine on link message
+// Rev 3.9 08-23-2011 Queued command fixes including @delete which were not always working
+// Rev 4.0 09-15-2015 Fixes for Sensor functions which continually rezzed a NPC when no one was around.
+// Rev 4.1 09-20-2015 Added a Listener so link messages are not needed
+// Rev 4.2 09-23-2015 Added @teleport=<vector>
+// Rev 4.3 09-24-2015 Added @reset to restart the NPC at the very start of the !Path notecard
+//                    @teleport works for relative and absolute modes
+// Rev 4.4 09-26-2015 if it could not find the (deleted) NPC, it could not restart
+// Rev 4.5 09-29-2015 remove wait for STATE == 0
+//*******************************************************************//
+
+// Instructions on how to use this are at http://www.outworldz.com/opensim/posts/NPC/
+// This is an OpenSim-only script.
+// Author: Ferd Frederix aka Fred Beckhusen - fred@mitsi.com
+
+////////////////////////////////////////////////////////////////////////////////////////////
+//    Original code was Copyright (C) 2013 Wizardry and Steamworks - License: GNU GPLv3    //
+///////////////////////////////////////////////////////////////////////////////////////////
+//  Please see: http://www.gnu.org/licenses/gpl.html for legal details,                  //
+//  rights of fair usage, the disclaimer and warranty conditions.                        //
+///////////////////////////////////////////////////////////////////////////////////////////
+// The original NPC controller was from http://was.fm/opensim:npc
+// Extensive additions and bug fixes by Fred Beckhusen, aka Ferd Frederix
+// llSensor had two params swapped
+// @Wander would wander where it had rezzed, not where it was.
+// There was no 'no_sensor' event in sit, so if a @sit failed, the NPC got stuck
+// The animation and walks always stopped old, then started new.  It should be start new, then stop old so the default stand would be suppressed.
+// New code:
+// Merged with new Route recorder and notecard writer
+// If the NPC failed to reach a destination it never moved on.
+// Added WAIT global to tune this
+// Exposed many tunable variables and ported the code 
+// Added floating point to times in notecard.
+// Added @sound, @randsound, @whisper, @shout, and @cmd controls.
+// notecards integers are not floats for better control
+// 
+// Link Messages may be used to perform external control by injecting @commands into the stream of actions
+// Example:
+// To chat something, such as with a chat robot
+//  llMessageLinked(LINK_SET,0,"@npc_say=Hello","");
+
+// This script assumes that NPCs and OSSl scripting is enabled in the OpenSim configuration.
+// In order to enable them, the following changes must be made in the OpenSim.ini configuration file:
+//
+// ; Turn on OSSL
+// AllowOSFunctions = true
+// OSFunctionThreatLevel = Severe
+
+//[NPC]
+//    ;# {Enabled} {} {Enable Non Player Character (NPC) facilities} {true false}
+//    Enabled = true
+//
+// and then the server has to be restarted.
+// please note that there are better ways to enable NPC in the latest Opensim.  
+
+// Commands: All commands begin with an @ sign.  All other lines are ignored
+// @commands may have optional parameters.  The syntax is always:
+//  @cmd=parm1|parm2
+//  NaN in the table below meand Not a Number.   This means there is no parameter
+
+//Command     First Parameter             Second Parameter        Description
+//@spawn      name                        location (vector)       Rezzes an NPC with name at a location.
+//@appearance NoteCardName                NaN                     switch the NPC appearance to a new notecard
+//@walk       destination (vector)        NaN                     Makes the NPC walk to destination.
+//@fly        destination (vector)        NaN                     Makes the NPC fly to destination.
+//@land       destination (vector)        NaN                     Makes the NPC land at destination.
+//@say        string                      NaN                     Makes the NPC speak a phrase.
+//@whisper    string                      NaN                     Makes the NPC whisper a phrase.
+//@shout      string                      NaN                     Makes the NPC shout a phrase.
+//@pause      seconds (float)             NaN                     Makes the NPC wait for a multiple of seconds.
+//@wander     radius (float)              cycles (integer)        Makes the NPC wander in radius, for cycles seconds.
+//@delete     NaN                         NaN                     Removes the NPC.  Requires a link message to continue
+//@goto       label (string)              NaN                     Jump to the label label in the script.
+//@animate    animation (string)          time (float)            Makes the NPC trigger the animation animation for time seconds.
+//@sound      sound_name                  NaN                     plays a sound from inventory
+//@randsound  NaN                         NaN                     Plays a random sound from inventory
+//@rotate     degrees (float)             NaN                     Rotate the NPC degrees around the Z axis.
+//@sit        primitive name              NaN                     Sit on a primitive with a given name.
+//@touch      primitive name              NaN                     Touch on a primitive with a given name.
+//@stand      NaN                         NaN                     If sitting on a primitive, stand up.
+//@cmd        channel (integer)           string                  Says string on channel, for controlling external gadgets
+//@stop       NaN                         NaN                     Halts the NPC script indefinitely. Can be started with a link message
+//@go         NaN                         NaN                     Continues on next notecard line, for use in link messages
+//@speed      speed (float)               NaN                     from 0 to N, where 1.0 ius a normal speed of an avatar.  0.2 is a turtle.
+//@notecard   notename (string)           NaN                     load a new Path notecard
+//@attach     InventoryName               attachmentPoint         load an attachment from the inventory to the NPC onto point
+//@teleport   destination (vector)        NaN                     Makes the NPC teleport to destination in the same sim.  They cannot tp to another sim or across the HG
+//@reset      NaN                         NaN                     Deletes the NPC, starts the !Path notecard over.
+ 
+// Constant            attachmentPoint Comment
+// ATTACH_CHEST            1    chest/sternum
+// ATTACH_HEAD             2    head
+// ATTACH_LSHOULDER        3    left shoulder
+// ATTACH_RSHOULDER        4    right shoulder
+// ATTACH_LHAND            5    left hand
+// ATTACH_RHAND            6    right hand
+// ATTACH_LFOOT            7    left foot
+// ATTACH_RFOOT            8    right foot
+// ATTACH_BACK             9    back
+// ATTACH_PELVIS          10    pelvis
+// ATTACH_MOUTH           11    mouth
+// ATTACH_CHIN            12    chin
+// ATTACH_LEAR            13    left ear
+// ATTACH_REAR            14    right ear
+// ATTACH_LEYE            15    left eye
+// ATTACH_REYE            16    right eye
+// ATTACH_NOSE            17    nose
+// ATTACH_RUARM           18    right upper arm
+// ATTACH_RLARM           19    right lower arm
+// ATTACH_LUARM           20    left upper arm
+// ATTACH_LLARM           21    left lower arm
+// ATTACH_RHIP            22    right hip
+// ATTACH_RULEG           23    right upper leg
+// ATTACH_RLLEG           24    right lower leg
+// ATTACH_LHIP            25    left hip
+// ATTACH_LULEG           26    left upper leg
+// ATTACH_LLLEG           27    left lower leg
+// ATTACH_BELLY           28    belly/stomach/tummy
+// ATTACH_LEFT_PEC        29    left pectoral
+// ATTACH_RIGHT_PEC       30    right pectoral
+// ATTACH_HUD_CENTER_2    31    HUD Center 2
+// ATTACH_HUD_TOP_RIGHT   32    HUD Top Right
+// ATTACH_HUD_TOP_CENTER  33    HUD Top
+// ATTACH_HUD_TOP_LEFT    34    HUD Top Left
+// ATTACH_HUD_CENTER_1    35    HUD Center
+// ATTACH_HUD_BOTTOM_LEFT 36    HUD Bottom Left
+// ATTACH_HUD_BOTTOM      37    HUD Bottom
+// ATTACH_HUD_BOTTOM_RIGHT 38   HUD Bottom Right
+// ATTACH_NECK            39   neck
+// ATTACH_AVATAR_CENTER  40    avatar center/root
+
+
+  
+//////////////////////////////////////////////////////////
+//                  DEBUG                               //
+//////////////////////////////////////////////////////////
+integer debug = FALSE;         // set to TRUE or FALSE for debug chat on various actions
+integer LSLEditor = FALSE;        // set to to TRUE to working in  LSLEditor, FALSE for in-world.
+                              // you must also include the NPC commands found in the other script since LSLEditor does not support OpenSim
+integer iTitleText = FALSE;    // set to TRUE to see debug info in text above the controller
+ 
+//////////////////////////////////////////////////////////
+//                  TUNABLE CONFIGURATION               //
+//////////////////////////////////////////////////////////
+float     RANGE = 100;        // 1 to N meters  - anyone this close to the controller will start NPCS if Sensor button is clicked
+integer   allowListener = FALSE; // set to TRUE to anable a command listener. Usually, this is setto FALSE
+integer   link_Channel =   4223; // some random number you want to talk to this gadget on. Best if large and negative
+float     TIMER = 2;         // faster = less jerky stopping.  How often the system checks the distance traveled.  Fastest you can go is 0.5 seconds
+float     QUICK = 1;        // when we need to move to the next state, we use a QUICK timer
+string    Appearance = "!Appearance";  // The name of the recorded Appearance notecard
+string    Notecard = "!Path"; // The name of the recorded routes
+integer   allowUsers = FALSE;  // If true, any user can get a Start NPC and Stop NPC menu.  Only groups and owners can get all commands if TRUE, or FALSE
+float     MAXDIST = 2.0;       // how close a NPC has to get to a dest pos to continue to next state. Do not lower this too much, as it may miss the target
+integer   WANDERRAND = TRUE;   // set to TRUE and they will pause during wanders a random number of seconds
+float     WANDERTIME = 3.0;    // how long they stand after each @wander,if WANDERRAND is FALSE. If WANDERRAND is  TRUE, this is the max time
+integer   WAIT = 30;           // wait for this number of seconds for the NPC to reach a destination (for safety). If it fails to reach a target, it will move on after this time.
+
+float     REZTIME = 2.0;      // wait this long for NPC to rez in, then start the process
+string    STAND = "Stand";     // the name of the default Stand animation
+string    WALK = "Walk";       // the name of the default Walk animation
+string    FLY = "Fly";        // the name of the default Fly animation
+string    RUN = "Run";        // the name of the default Run animation
+string    LAND = "Land";      // the name of the default land animation ( for birds only)
+float     OffsetZ = 0.5;      // appear 0.5 meter above ground, this is added to all destinations to keep them from sinking in.  
+float    SPEEDMULT =0.8;     // 1.0 = regular avatar speed. Smaller numbers slow down walks. Large numbers speed them up.
+integer  FLIGHT = 299;        // For controlling wings.  A channel that is shouted at when flight starts and ends. "flying" or "landing" 
+
+// DESCRIPTIONS FIELDS HAVE TO SURVIVE A RESET
+//  These vars are stored  by saving them with KeyValueSet
+// "pr" is a 0 if it is set for Owner Only, 1 for Group control
+// "se" is "on" if Started
+// "co" = "R" or "A" for relative or absolute addressing mode
+// "key" = NPC key
+
+// These Globals used to be stored in description.   Moved to RAM in V1.6
+float RAMPause;          // @pause param
+float RAMwd ;            // @wander distance
+integer RAMwc;           // @wander count
+float RAMrot;            //  @rotate
+string RAMsit;           // @sit primname
+string RAMtouch;         // @touch primname
+string RAManimationName; // @animate animation (string) time (float)
+float RAManimationTime;
+
+// other globals section
+integer iChannel;        // a listen channel, randomly assigned
+integer iHandle;         // the handle to it
+
+// NPC controls
+vector newDest ;                // tmp storage for the walks
+integer iWaitCounter ;          // wait for this number of seconds for the NPC to reach a desrtination
+string sNPCName;                // the name of the NPC that may be in world. So we can remove it.
+integer bNPC_STOP = FALSE;      // boolean to reuse a listener
+integer Stopped = FALSE;        // set to TRUE by link messages so we do not remember them
+float  fTimerVal ;              // how long we wait when wandering (calculated)
+float NPCEnabled;               // true if the NPC is suppodes to be running
+
+// OS_NPC_CREATOR_OWNED will create an 'owned' NPC that will only respond to osNpc* commands issued from scripts that have the same owner as the one that created the NPC.
+// OS_NPC_NOT_OWNED will create an 'unowned' NPC that will respond to any script that has OSSL permissions to call osNpc* commands.
+integer  NPCOptions = OS_NPC_CREATOR_OWNED;    // only yhe owner of this box can control this NPC.
+
+integer walkstate = 0;  // helps us reshare the walk state for run, fly and land - a bit of a hack, but it saves RAM. Has to be done this way because some bits of NPCWalkOption are asserted as 0
+
+integer NPCWalkOption;   // Some notes for what happens to NPCWalkOption:
+// OS_NPC_FLY - Fly the avatar to the given position. The avatar will not land unless the OS_NPC_LAND_AT_TARGET option is also given.
+// OS_NPC_NO_FLY - Do not fly to the target. The NPC will attempt to walk to the location. If it's up in the air then the avatar will keep bouncing hopeless until another move target is given or the move is stopped
+//OS_NPC_LAND_AT_TARGET - If given and the avatar is flying, then it will land when it reaches the target. If OS_NPC_NO_FLY is given then this option has no effect.
+// OS_NPC_RUNNING - if given, NPC avatar moves at running/fast flying speed, otherwise moves at walking/slow flying speed.
+
+// menus
+string mSensor="Sense is Off";    // Sensor or "No Sensor"
+
+list lAtButtons = ["Menu","-",   ">>",         "@run",    "@walk",   "@fly",  "@land", "@wander",    "@sit",   "@stand","@animate","@rotate"];
+list lMenu2 = ["<<", "@comment", ">>>",        "@stop",      "@say",    "@whisper","@shout","@sound","@randsound","@cmd",  "@pause",  "@delete"];
+list lMenu3 = ["<<<","@notecard","@appearance", "@touch", "@speed",       "@attach",     "@teleport","-", "-", "-", "-", "-" ];
+
+string sCommand;  // place to store a command for two-prompted ones
+string sParam2;   // place to store a prompt for two-prompted ones
+string priPub = "Owner Only";    // Private or Group
+key kUserKey;        // the person who is controlling the avatar, not the Owner  
+// the command lists
+list lCommands;  // commands are stored here
+list lNpcCommandList; // Storage for the NPC script.
+string npcAction; // Storage for the next action. @cmd=0|hello, this becomes @cmd
+string npcParams; // Storage for the param, @cmd=0|hello, this becomes 0|hello
+
+// misc vars
+string sNotecard; // commands are stored here temporarily for dumping
+vector  vWanderPos; // a place to wander to
+string lastANIM ;   // last animation run
+// Sensor
+integer avatarPresent;   // Sensor sets this flag when people are within Range.
+
+// Coordinate control
+vector vInitialPos ; // Vector that will be filled by the script with the initial starting position in region coordinates.
+vector vDestPos = ZERO_VECTOR; // Storage for destination position.
+string relAbs = "Relative";    // absolute vs relative positioning
+
+
+// STATES
+integer MENU ;             // processing a dialog box state, may be concurrent with STATE
+integer STATE;             // state storage
+integer NULL = 0;          // the null state
+integer MakeNotecard = 1;  // displaying a text box for NPC name
+integer RecordPath = 2;    // displaying a path notecard menu
+integer NobodyHome = 3;    // looking for an avatar
+integer Spawning = 4;      // spawning an avatar
+integer Animate = 5;       // animation timer needed
+integer Walking = 6;       // Hey! I am walking here!
+integer Wander = 7;        // Wandering around neeeds a timer, too
+integer WanderHold = 8;    // We reached a wander point
+integer DoProcess = 9;     // Set this to make it process a new command
+integer Touch = 10;        // Timer is busy sensing something to touch
+integer Sit = 11;          // Timer is busy sensing something to sit on
+integer Paused = 12;       // Timer is busy pausing
+
+key gNpcKey = NULL_KEY;   // global key storage for the one NPC, to save CPU cycles
+list Stack ;              // a command stack from link message input
+
+///////////////////////////////////////////////////////////////////////////
+//                              FUNCTIONS                                //
+///////////////////////////////////////////////////////////////////////////
+
+
+TimerEvent(float timesent)
+{
+    if (LSLEditor)
+        timesent *= 5;   // slow thinggs doen when the LSLEDITOR is in use
+        
+    DEBUG("Setting  timer: " + (string) timesent);
+    llSetTimerEvent(timesent);
+}
+
+// for 4.1 parse a message from a Listen or a Link message
+ParseMsg(string str) {
+    DEBUG("Command In:" + str);
+    if (str=="@go") {
+        SetStop(FALSE); // Let's run the notecard
+        DEBUG("@go running");
+        DoProcessNPCLine();
+    } else {
+        Stack += [str];    // take anything, the controller will filter away non @ stuff
+        if (STATE == NULL)
+            DoProcessNPCLine(); // v 4.5 remove wait for STATE == 0
+    }
+}
+
+SetStop(integer what)
+{
+    DEBUG("Stopped set to " + (string ) what);
+    Stopped = what;
+}
+// Do* functions are much like states from the old V2 scripts.
+    
+// Save a Path notecard
+DoSave()
+{ 
+    STATE = MakeNotecard;
+    makeText("Stand where you want the NPC to appear, and enter the NPC Name");
+}
+
+// This function is used to record the path for the NPC
+// Each command can take 0, 1, or 2 params
+DoMenuForCommands() {
+    makeMenu(lAtButtons);
+}
+
+
+// No one is here when sensors were on, so we kill off the NPC
+DoNobodyHome()
+{
+    DEBUG("Nobody Home");
+    STATE = NobodyHome;
+    if (NPCKey() != NULL_KEY) {
+        osNpcRemove(NPCKey());
+        SaveKey(NULL_KEY);
+    }
+    TimerEvent(5);  // keep ticking to sense avatars   
+}
+
+///////////////////////  STATELIKE BEHAVIOUR  /////////////
+// these StateXX functions need to wait on a timer to fire. 
+// Create a NPC
+StateSpawn() {
+    DEBUG("state spawn");
+
+     
+    NPCEnabled = TRUE; //  in world
+    // see if there is already one out there.
+    if (NPCKey() != NULL_KEY) {
+        DEBUG("Already living");
+        return;
+    }
+    
+    STATE = Spawning;        
+    list name = llParseString2List(sNPCName, [" "], []);
+   
+    vector vRezPos = vInitialPos;
+    if (relAbs == "Relative"){
+        vRezPos += llGetPos();
+    }
+
+   // llSay(0,llDumpList2String(name,",")); 
+    DEBUG("Rezzing the  NPC:" + (string) vRezPos);
+    key aKey = osNpcCreate(llList2String(name, 0), llList2String(name, 1), vRezPos, Appearance, NPCOptions);
+
+    llMessageLinked(LINK_SET,-1,"",aKey);    // bboradcast the key on num = -1
+    SaveKey(aKey); // save in description and global, too
+    
+    osSetSpeed(aKey,SPEEDMULT);   // 1.9 speed multiplier
+    TimerEvent(REZTIME);
+    NPCAnimate(STAND);
+}
+
+StateSit() {
+    DEBUG ("state sit - looking for " + RAMsit);
+    STATE=Sit;
+    llSensor(RAMsit, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+
+StateTouch() {
+    DEBUG ("state touch - looking for " + RAMtouch);
+    STATE = Touch;
+    llSensor(RAMtouch, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+ 
+DoStand() {
+    DEBUG("state stand");
+    osNpcStand(NPCKey());
+}
+
+
+StateAnimate() {
+    
+    DEBUG("state animate");
+    STATE = Animate;
+    NPCAnimate(RAManimationName);
+    if (RAManimationTime <=0 )    // V 3.4 tweak
+        RAManimationTime = 1;
+    TimerEvent(RAManimationTime);
+}
+    
+StateWalk() {
+
+    DEBUG("Start Walk");
+    //DEBUG("NPCWalkOption = " + (string) NPCWalkOption);
+    STATE = Walking;
+            
+    // walk, fly, run, land
+   if (walkstate == 1) {
+        NPCAnimate(WALK);
+    } else if (walkstate == 2)  {
+        llShout(FLIGHT,"flying");
+        NPCAnimate(FLY);
+    } else if (walkstate == 3) {
+        NPCAnimate(RUN);
+    } else if (walkstate == 4) {
+        NPCAnimate(LAND);
+    } 
+    newDest = vDestPos ;
+    newDest.z += OffsetZ;
+        
+    // notecard is stored as offsets from this box with relative addressing.  Convert to absolute
+    if (relAbs == "Relative"){
+        newDest += llGetPos();
+    }
+
+    DEBUG("Moveto:" + (string) newDest);
+    osNpcMoveToTarget(NPCKey(), newDest, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);
+}
+
+
+StateWander(){
+    DEBUG("state wander");
+    STATE = Wander;
+    
+    vector point = CirclePoint(RAMwd);
+    DEBUG("CirclePoint:" + (string) point);
+    vWanderPos = vDestPos + point;
+    DEBUG("vWanderPos:" + (string) vWanderPos);
+
+    fTimerVal = WANDERTIME;    // default time to pause after each wander
+    if (WANDERRAND)
+        fTimerVal = llFrand(WANDERTIME) + 1;    // override, they want random times
+
+    NPCAnimate(WALK);
+
+    DEBUG("Wander to:" + (string) vWanderPos);
+
+    osNpcMoveToTarget(NPCKey(), vWanderPos, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);      
+}
+
+StateWanderhold() {
+
+    DEBUG("Wander Hold");
+    STATE = WanderHold;
+       
+     // now that we have reached a wander spot, slow the timer down to the desired value
+    TimerEvent(fTimerVal);
+}
+
+ 
+DoRotate() {
+    DEBUG("@rotate=" + (string) RAMrot); 
+    osNpcSetRot(NPCKey(), llEuler2Rot(<0,0,RAMrot> * DEG_TO_RAD));
+}  
+// @pause=10 will do nothing for 10 seconds
+DoPause() {
+    STATE = Paused;
+    if (RAMPause < 0.1)
+        RAMPause = 0.1;
+    DEBUG("@pause=" + (string)RAMPause);
+    TimerEvent(RAMPause);
+}
+
+
+// @stop makes the NPC stop moving in whatever state it is in.  You have to linkmessage to get moving again
+DoStop() {    
+    DEBUG("NPC is Stopped");
+    STATE   = 0;    // accept commands
+    SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+    
+// @delete removes the NPC forever. Next command starts it up again at the beginning
+DoDelete() {
+    DEBUG("state delete");
+    osNpcRemove(NPCKey());
+    SaveKey(NULL_KEY);
+    TimerEvent(0);
+    Stack = []; // v3.8
+    STATE = NULL;    // accept commands
+}
+
+// change the appearance of the NPC
+DoAppearance(string notecard) {
+    DEBUG("state appearance");
+    if (llGetInventoryType(notecard) == INVENTORY_NOTECARD){
+        DEBUG("Load appearance " + notecard);
+        osNpcLoadAppearance(NPCKey(),notecard);
+    }
+    STATE = NULL;    // accept commands
+}
+
+// Change the avatar speed
+DoSpeed(string speed) {
+    float newspeed = (float) speed;
+    if (newspeed > 0.1 && newspeed < 5.0) {// sanity check
+        osSetSpeed(NPCKey(),newspeed);
+    }
+    STATE = NULL;    // accept commands
+}
+
+DoTeleport(string params) {
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    vector Dest = (vector) itemName;
+    if (Dest != ZERO_VECTOR) {
+        if (relAbs == "Relative"){
+            Dest += llGetPos();
+        }
+        osTeleportAgent( NPCKey(), llGetRegionName(), Dest, ZERO_VECTOR );
+        
+    } else {
+        llSay(DEBUG_CHANNEL,"Attempt to teleport to <0,0,0> probably not what you intended: @teleport=<vector>");
+    }
+    STATE = NULL;    // accept commands
+}
+
+
+
+DoNewNote (string card) {
+    DEBUG("Load Notecard " + card);    
+    NPCReadNoteCard(card);
+    SetStop(FALSE);
+    STATE = NULL;    // accept commands
+}
+DoAttach(string params) {
+    
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    integer attachmentPoint  = (integer) llList2String(Data, 1);
+    if (attachmentPoint > 0
+        && attachmentPoint < 40
+        && llGetInventoryType(itemName) == INVENTORY_OBJECT
+       )
+    {
+        osForceAttachToOtherAvatarFromInventory(NPCKey(),itemName,attachmentPoint);
+    }
+    STATE = NULL;    // accept commands
+}
+
+// This loops over the notecard, processing each command
+DoProcessNPCLine() {
+    DEBUG("ProcessNPCLine, stopped = " + (string) Stopped);
+    
+    STATE = DoProcess;
+    
+        // auto load a notecard
+    if (! llGetListLength(lNpcCommandList)) {
+        DEBUG("Read Notecard");
+        NPCReadNoteCard(Notecard);
+    }
+
+    // look for link messages on the stack
+    string next = llList2String(Stack,0);    // lets see if there is anything from a link message
+    if (llStringLength(next))
+    {
+        Stack = llDeleteSubList(Stack,0,0);
+        ProcessCmd(next);        //lets do this command instead.
+        return;
+    }
+
+    // @stop issued?
+    if (Stopped) {
+        TimerEvent(0);
+        DEBUG("Stopped, waiting for input");
+        STATE = NULL;
+        return;
+    }
+
+    // No, we have an @go for liftoff
+    next = llList2String(lNpcCommandList, 0);        // get the next command
+    DEBUG("Execute:" + next);
+    lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);      // delete it
+        
+    if (llGetListLength(lNpcCommandList) == 0) {
+        DEBUG("EOF");
+    }
+    ProcessCmd(next);
+} 
+
+
+
+ProcessCmd(string cmd) {
+
+    DEBUG("ProcessCmd:" + cmd);
+
+    if (llGetSubString(cmd, 0, 0) != "@") {
+        DEBUG("ignoring");
+        TimerEvent(QUICK);  // this is so we do not recurse the stack
+        STATE = NULL;
+        return;
+    }
+
+    list data  = llParseString2List(cmd, ["="], []);
+    npcAction = llToLower(llStringTrim(llList2String(data, 0), STRING_TRIM));
+
+    DEBUG("Action:" + npcAction);
+    npcParams = llStringTrim(llList2String(data, 1), STRING_TRIM);
+    DEBUG("Params:" + npcParams);
+    
+    @commands;
+
+    ProcessSensor();
+    
+    if(npcAction == "@spawn" && avatarPresent) {
+        DEBUG("@spawn");
+        list spawnData = llParseString2List(npcParams, ["|"], []);
+        sNPCName =llList2String(spawnData, 0);    // V 1.6 name in RAM
+
+        list spawnDest = llParseString2List(llList2String(spawnData, 1), ["<", ",", ">"], []);
+        vInitialPos.x = llList2Float(spawnDest, 0);
+        vInitialPos.y = llList2Float(spawnDest, 1);
+        vInitialPos.z = llList2Float(spawnDest, 2);
+        
+        DEBUG("Coords for NPC at " + (string) vInitialPos);
+        StateSpawn();
+        return;
+    }
+    
+     if (! avatarPresent){
+        DoNobodyHome();
+        DEBUG("No avatar nearby");
+        STATE = NULL;
+        return;
+    } else {
+        if ( NPCKey() == NULL_KEY) {
+            StateSpawn();
+        }
+    }
+
+    
+    
+    
+    if(npcAction == "@stop") {
+        DoStop();
+        STATE = NULL;
+        return;
+    }
+    else if(npcAction == "@goto") {
+        DEBUG("goto");
+        integer lastIdx = llGetListLength(lNpcCommandList)-1;
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, lastIdx, lastIdx);
+        // Wind commands till goto label.
+        @wind;
+        string next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        if(next1 != npcParams) jump wind;
+        // Wind the label too.
+        next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        // Get next command.
+        list data1  = llParseString2List(next1, ["="], []);
+        npcAction = llToLower(llStringTrim(llList2String(data1, 0), STRING_TRIM));
+        npcParams = llStringTrim(llList2String(data1, 1), STRING_TRIM);
+        // Reschedule.
+        jump commands;
+    }
+    else if(npcAction == "@sound") {
+        DEBUG("sound");
+        llTriggerSound(npcParams,1.0);
+    }
+    else if(npcAction == "@randsound") {
+        DEBUG("@randsound");
+        integer N = llGetInventoryNumber(INVENTORY_SOUND);
+        integer rand = llCeil(llFrand(N)) -1;    // pick a random sound
+        string toPlay = llGetInventoryName(INVENTORY_SOUND,rand);
+        llTriggerSound(toPlay,1.0);
+    }
+    else if(npcAction == "@walk") {
+        DEBUG("@walk");
+        GetDest(npcParams);
+        walkstate = 1;//  walking
+        NPCWalkOption = OS_NPC_NO_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@fly") {
+        GetDest(npcParams);
+        walkstate = 2;//  flying
+        NPCWalkOption = OS_NPC_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@run") {
+        DEBUG("@run");
+        GetDest(npcParams);
+        walkstate = 3;//  running
+        NPCWalkOption = OS_NPC_NO_FLY | OS_NPC_RUNNING;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@land") {
+        DEBUG("@land");
+        GetDest(npcParams);
+        walkstate = 4;//  landing
+        NPCWalkOption= OS_NPC_FLY | OS_NPC_LAND_AT_TARGET ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@say") {
+        DEBUG("@say " + npcParams);
+        osNpcSay(NPCKey(), 0, npcParams);
+    }
+    else if(npcAction == "@shout") {
+        DEBUG("@shout");
+        osNpcShout(NPCKey(),0, npcParams);
+    }
+    else if(npcAction == "@whisper") {
+        DEBUG("@whisper " + npcParams);
+        osNpcWhisper(NPCKey(),0, npcParams);
+    }
+    // speak a command on a channel, so you can open doors and control stuff.
+    else if(npcAction == "@cmd") {
+        DEBUG("@cmd");
+        list dataToSpeak = llParseString2List(npcParams, ["|"], []);
+        string channel = llList2String(dataToSpeak,0);
+        DEBUG("Channel:"+(string) channel);
+        integer iChannel = (integer) channel;
+        string stringToSpeak = llList2String(dataToSpeak,1);
+        llSay(iChannel, stringToSpeak);
+    }
+    // stop everything
+    else if(npcAction == "@pause") {
+        RAMPause = (float) npcParams;
+        DoPause();
+        return;
+    }
+    else if(npcAction == "@wander") {
+        list wanderData = llParseString2List(npcParams, ["|"], []);
+        RAMwd = (float) llList2String(wanderData, 0);
+        RAMwc = (integer) llList2String(wanderData, 1);
+        vDestPos = osNpcGetPos(NPCKey());        // set the wander start
+        DEBUG("Starting at " + (string) vDestPos);
+        StateWander();
+        return;
+    }
+    else if(npcAction == "@rotate") {
+        RAMrot = (float) npcParams;
+        DoRotate();
+    }
+    else if(npcAction == "@sit") {
+        RAMsit= npcParams;
+        StateSit();
+        return;
+    }
+    else if(npcAction == "@touch") {
+        RAMtouch= npcParams;
+        StateTouch();
+        return;
+    }
+    else  if(npcAction == "@stand") {
+        DoStand();
+    }
+    else if(npcAction == "@delete") {
+        DoDelete();
+        SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+        return;
+    }
+    else if(npcAction == "@animate") {
+        list animateData = llParseString2List(npcParams, ["|"], []);
+        RAManimationName = llList2String(animateData, 0);
+        RAManimationTime = (float) llList2String(animateData, 1);
+        StateAnimate();
+        return;
+    }
+    else if(npcAction == "@appearance" ){
+        DoAppearance(npcParams);
+    }
+    else if (npcAction =="@speed") {
+        DoSpeed(npcParams);
+    }
+    else if (npcAction =="@notecard") {      
+        DoNewNote(npcParams);
+        Notecard = npcParams;
+    }
+    else if (npcAction == "@attach")
+    {
+        DoAttach(npcParams);
+    }
+    else if (npcAction == "@teleport")
+    {
+        DoTeleport(npcParams);
+    }
+    else if (npcAction == "@reset")
+    {
+        DoDelete();
+        SetStop(FALSE); // a @resst will restart the original !Path after deleting the notecard.
+    }
+
+    STATE = NULL;
+    TimerEvent(QUICK);  // yeah I know, not possible this fast, we just go as fast as we can go - this is so we do not recurse the stack 
+}
+ 
+
+
+/////////////////// UTILITY Functions, not state-like //////////////////
+
+// DEBUG(string) will chat a string or display it as hovertext if debug == TRUE
+DEBUG(string str) {
+    if (debug && ! LSLEditor)
+        llOwnerSay( str);                    // Send the owner debug info 
+    if (debug &&  LSLEditor)
+        llSay(0, str);                    // Send to the Console in LSLEDitor 
+    if (iTitleText) {
+        llSetText(str,<1.0,1.0,1.0>,1.0);    // show hovertext
+    
+    }
+} 
+
+GetDest(string npcParams) {
+    list dest = llParseString2List(npcParams, ["<", ",", ">"], []);
+    vDestPos.x = llList2Float(dest, 0);
+    vDestPos.y = llList2Float(dest, 1);
+    vDestPos.z = llList2Float(dest, 2);
+}
+
+NPCReadNoteCard(string Note) {
+    DEBUG("NPCReadNoteCard");             
+    lNpcCommandList = llParseString2List(osGetNotecard(Note), ["\n"], []);
+}  
+  
+integer SenseAvatar()
+{
+    //Returns a strided list of the UUID, position, and name of each avatar in the region
+    list avatars = llGetAgentList(AGENT_LIST_REGION ,[]);
+    integer numOfAvatars = llGetListLength(avatars);
+    if (numOfAvatars == 0)
+    {
+        DEBUG("No people");
+        return 0;
+    }
+    //DEBUG("Located " + (string)numOfAvatars + " avatars and NPC's"); 
+        
+    integer nAvatars;
+    integer i;
+    for( i = 0;i < numOfAvatars; i++) {
+        key aviKey = llList2Key(avatars,i);
+        if (!osIsNpc(aviKey)) {
+            list detail = llGetObjectDetails(aviKey,[OBJECT_POS]);
+            vector pos = llList2Vector(detail,0);
+            float dist = llVecDist(pos, llGetPos());
+            if (dist  < RANGE)
+            {
+                nAvatars++;
+                DEBUG("In range:" + llKey2Name(aviKey));
+            }
+        }
+    }
+    //DEBUG("Located " + (string) nAvatars + " avatars");
+    return nAvatars;
+} 
+ 
+// return TRUE if the avatar is owner when private is set, or TRUE if the avatar is in the same group and GROUP is set.
+integer checkPerms() {
+
+    integer group = (integer) KeyValueGet("pr");
+    if (! group)
+        priPub = "Owner Only";
+    else
+        priPub = "Group";
+    
+    
+    if (llDetectedKey(0) == llGetOwner()){
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+ 
+    if ( group && llDetectedGroup(0)) {
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+    kUserKey = llDetectedKey(0);
+    return FALSE;
+}
+
+
+
+NPCAnimate(string anim)
+{
+    DEBUG("Start Anim: " + anim);
+    if (llGetInventoryType(anim) == INVENTORY_ANIMATION ) {
+        
+        if (lastANIM != anim) {
+            if(llStringLength(lastANIM)) {
+                osNpcStopAnimation(NPCKey(), lastANIM);  
+            }
+            osNpcPlayAnimation(NPCKey(), anim);
+            lastANIM = anim;
+        }            
+    } else {
+        llSay(DEBUG_CHANNEL, "No animation named " + anim);
+    }
+} 
+
+// Kill a NPC by Name
+Kill(string param)
+{
+    integer count;
+    list avatars = osGetAvatarList(); // Returns a strided list of the UUID, position, and name of each avatar in the region except the owner.\    
+    integer i;
+    integer j = llGetListLength(avatars);
+    for (i=0 ; i <= j; i+=3){
+        
+        string desired = llList2String(avatars,i+2);
+        desired = llStringTrim(desired,STRING_TRIM);    // should not be needed but is needed
+        
+        if (desired == param){
+            vector v = llList2Vector(avatars,i+1);
+            key target = llList2Key(avatars,i);    // get the UUID of the avatar
+            osNpcRemove(target);
+            
+            llOwnerSay("Removed " + param+ " at  location " + (string) v);
+            count++;
+        }
+    }
+    
+    NPCEnabled = FALSE; // not in world
+    SaveKey(NULL_KEY );    // Rev 4.4
+    
+    if (count)
+        llOwnerSay("Removed " + (string) count + " NPC's");
+    else
+        llOwnerSay("Could not locate " + param);
+}
+
+
+// return a String for the position we are at. Strings used as the caller wants strings
+string Pos()
+{
+    vector where = llGetPos(); // find the box position
+   
+    where.z +=    OffsetZ;  // use the ground position + an offset 
+        
+    if (LSLEditor)
+        where  = <128,128,31 + llFrand(1)>; // force center of sim when editing
+   
+   // if attached the height will be too high by 1/2 the agent size
+    if (llGetAttached()) {
+        vector size = llGetAgentSize(llGetOwner());   
+        float Z = size.z;
+        where.z -= Z/2;  
+    }
+   
+    // DEBUG("Pos= " + (string) where);
+    return (string) where;
+}
+
+// setup a menu with a timer for timeouts, called by all make*()
+menu()
+{
+    llListenRemove(iHandle);
+    iChannel = llCeil(llFrand(100000) + 20000);
+    iHandle = llListen(iChannel,"","","");
+    TimerEvent(30.0);
+    MENU = TRUE;
+}
+
+// make a text box
+makeText(string Param)
+{ 
+    menu();
+    llTextBox(kUserKey, Param, iChannel);
+}
+
+// top level menu
+makeMainMenu()
+{
+    menu();
+    list buttons = ["Appearance","Recording","Save","Help","-","Erase RAM", priPub,relAbs,"-","Stop NPC",mSensor,"Start NPC"];
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Records",buttons,iChannel);
+}
+
+
+// Rev 1.4
+// top level menu for non group/ non owners
+makeUserMenu()
+{
+    if (!allowUsers) return;
+    
+    menu();
+    list buttons = ["Start NPC","Stop NPC"];
+    llDialog(kUserKey,"Choose",buttons,iChannel);
+}
+
+
+
+// programmable menu for @commands
+makeMenu(list buttons)
+{
+    menu();
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Record",buttons,iChannel);
+}
+
+
+// make one or two text boxes with prompts
+Text(string cmd, string p1, string p2)
+{
+    sCommand = cmd;
+     sParam2 = "";
+    if (llStringLength(p2))
+        sParam2 = p2;
+
+    makeText(p1);
+} 
+
+// Set the Avatar Present flag - if sensors are off and we are forece run, there will be one present.
+ProcessSensor()
+{
+    integer SensorOn;
+    if ("on" == KeyValueGet("se"))
+    {
+        SensorOn = TRUE;        // we need to scan for avatars
+    } else {
+        SensorOn = FALSE;        // we need to scan for avatars
+    }
+    //DEBUG("Sensor:" + (string) SensorOn);
+    
+    integer n = SenseAvatar();
+    
+    DEBUG("Avatars:" + (string) n);
+    if (SensorOn && n)
+        avatarPresent = TRUE;   // someone is here and we need to tell the system to run
+    else if (SensorOn && !n)
+        avatarPresent = FALSE;  // someone is not here and we need to tell the system to stop
+    else {       // sensor is off, lete see if there is a NPC. If so, we are ON 
+       // DEBUG("NPCEnabled:" + (string) NPCEnabled);
+        if (NPCEnabled)
+            avatarPresent = TRUE;  
+        else
+            avatarPresent = FALSE;   
+    }
+    
+    //  start up from when when no one is near
+    if (avatarPresent && STATE == NobodyHome)
+        NULL = 0;
+    
+    //DEBUG("Avatar Present: " + (string) avatarPresent);
+}
+
+vector CirclePoint(float radius) {
+    float x = llFrand(radius *2) - radius;        // +/- radius, randomized
+    float y = llFrand(radius *2) - radius;        // +/- radius, randomized
+    return <x, y, 0>;        // so this should always happen
+}
+
+string KeyValueGet(string var) {
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k != var) jump continue;
+        //DEBUG("got " + var + " = " +  llList2String(data, 1));
+        return llList2String(data, 1);
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    return "";
+} 
+
+KeyValueSet(string var, string val) {
+
+    //DEBUG("set " + var + " = " + val);
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    if(llGetListLength(dVars) == 0)
+    {
+        llSetObjectDesc(var + "=" + val);
+        return;
+    }
+    list result = [];
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k == "") jump continue;
+        if(k == var && val == "") jump continue;
+        if(k == var) {
+            result += k + "=" + val;
+            val = "";
+            jump continue;
+        }
+        string v = llList2String(data, 1);
+        if(v == "") jump continue;
+        result += k + "=" + v;
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    if(val != "") result += var + "=" + val;
+    llSetObjectDesc(llDumpList2String(result, "&"));
+}
+
+
+// clear RAM
+Clr() {
+
+    lCommands = [];
+    llOwnerSay("RAM Memory cleared. Notecards, if any, are not modified.");
+    makeMainMenu();
+}
+
+integer checkNoteCards()
+{
+    // Check that they have saved an Appeaance and Path notecard
+    integer num = llGetInventoryNumber(INVENTORY_NOTECARD);    // how many notecards overall
+    
+    integer i;
+    integer count;
+    for (; i < num; i++){
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Notecard)
+            count++;
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Appearance)
+            count++;
+    }
+    DEBUG("Checked " + (string) count + " Notecards");
+    // if we have both, run the NPC
+    return count;
+}
+
+Update(string SName) {
+         
+    // delete all NPC* scripts except myself
+    integer i;
+    integer j = llGetInventoryNumber(INVENTORY_SCRIPT);
+    for (i = 0; i < j; i++) {
+        string targetName = llGetInventoryName(INVENTORY_SCRIPT,i);
+        string match = llGetSubString(targetName,0,2);
+        
+        if (match == SName && llGetScriptName() != targetName){
+                llOwnerSay("Upgrading " + targetName);
+            if (! LSLEditor){        // lets not kill the editor
+                llRemoveInventory(targetName);
+            }
+        }
+    }
+}
+
+// Get all default saved params from the Description
+GetSwitches()
+{
+         string rA = KeyValueGet("co"); // Get the remembered menu setting for Abs Vs Relative
+        if (rA == "A")
+            relAbs = "Absolute";
+        else  if (rA == "R")
+            relAbs = "Relative";
+        else
+            relAbs = "Absolute";
+
+            
+        // reenable NPC if sensor is on.
+        if ("on" == KeyValueGet("se"))
+        {
+            NPCEnabled = TRUE;
+            mSensor  = "Sense is On";
+            ProcessSensor();       // fake 1 avatar to get it rezzed
+        } else {
+            mSensor  = "Sense is Off";
+        }
+    }
+
+
+SaveKey(key akey)
+{
+    DEBUG("Saving Key of " + (string) akey);
+    KeyValueSet("key", akey);
+    if (akey !=  (key) KeyValueGet("key") )
+    {
+        DEBUG("Fatal error, cannot save key");
+    }
+    gNpcKey = akey;
+}
+
+
+key NPCKey()
+{
+    key akey = gNpcKey;   // from cached copy
+    // gNpcKey saves a lot of CPU processing by caching the key, if blank we get it from the description
+    if (gNpcKey == NULL_KEY)
+    {
+        //DEBUG("Get DKey");
+        akey = KeyValueGet("key");    // from Description of the prim
+    }
+   // DEBUG("NPC KEY:" + (string) akey);   
+    return  akey;
+}
+
+
+/////////////////// CODE BEGINS //////////////////
+
+
+default
+{
+    changed(integer change) {
+        if(change & CHANGED_REGION_START) {
+            llResetScript();
+        }
+    }
+    
+    on_rez(integer start_param)
+    {
+        llResetScript();
+    }
+
+    state_entry() {
+        
+        llSetText("",<1,1,1>,1.0);  // clr all hovertext- we may not be using it.
+        DoDelete(); // kill any NPC that is out running
+        Update("NPC"); // If dragged and ropped into a prim with any script named "NPC...", this will replace it.
+        GetSwitches(); // Get all default saved params from the Description
+
+        // 4.1 allow listeners to send us commands
+        if (allowListener)
+            llListen(link_Channel,"","","");
+        TimerEvent(TIMER);
+    } 
+
+
+    touch_start(integer n) 
+    {           // if touched, make a menu
+    
+        if (checkPerms()) {
+            if (RecordPath == STATE) {
+                makeMenu(lAtButtons); 
+            }   else {
+                makeMainMenu();
+            }
+        } else {
+            makeUserMenu();
+        }
+    }
+
+    // menu listener
+    listen(integer iChannel, string name, key id, string message) {
+
+        // process @commands that come in via the listener
+        if (iChannel == link_Channel)
+        {
+            ParseMsg(message);
+            return;
+        }
+        
+        if (MENU) {
+            llListenRemove(iHandle);
+            MENU = 0;       // menu is off
+            iHandle = 0;
+        }
+        
+        if (message == "Stop NPC")
+        {
+            lNpcCommandList = []; // force reload of notecard
+            NPCEnabled = FALSE;
+            if (NPCKey() != NULL_KEY){
+                Kill(sNPCName);
+                sNPCName = "";
+            } else {
+                bNPC_STOP = TRUE;
+                makeText("Enter name of an NPC to stop");
+            }
+        }
+        else if (message == "Menu" ) {
+            makeMainMenu();
+        }
+        else if (message == "Erase RAM"){
+            Clr();
+        }
+        else if (message == "Relative"){
+            relAbs = "Absolute";
+            KeyValueSet("co","A");   // remember coordinates = A
+            Clr();
+        }
+        else if (message == "Absolute"){
+            relAbs = "Relative";
+            KeyValueSet("co","R");   // remember coordinates = R
+            Clr();
+        }
+        else if (message == "Recording"){
+            DoMenuForCommands();        // show them the recording menu
+        }
+        else if (message == "Owner Only") {
+            priPub = "Group";
+            KeyValueSet("pr","1");
+
+            llOwnerSay("Group members have control");
+            makeMainMenu();
+        }
+        else if (message == "Group") {
+            priPub = "Owner Only";
+            KeyValueSet("pr","0");
+            llOwnerSay("Only you have control");
+            makeMainMenu();
+        }
+        else if (message == "Sense is On") {
+            mSensor ="Sense is Off";
+            KeyValueSet("se", "off");
+            llOwnerSay(mSensor);
+            makeMainMenu();
+        }
+        else if (message == "Sense is Off") {
+            mSensor ="Sense is On";
+            llOwnerSay(mSensor);
+            KeyValueSet("se", "on");
+            
+            NPCEnabled = FALSE;
+            
+            integer count = checkNoteCards();
+            if (count >= 2)  {
+                DEBUG("Notecards ok, DoProcessNPCLine");
+                DoProcessNPCLine();
+                return;
+            }
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording and/or appearance, so you cannot start a NPC");
+            makeMainMenu();
+        }
+        else if (message == "Appearance")  {
+            llRemoveInventory(Appearance);            // delete the notecard
+            osAgentSaveAppearance(kUserKey,Appearance);    // make the ntecard 
+            llOwnerSay("Your outfit has been saved");
+            makeMainMenu();
+        }
+        else if (message == "Save") {
+            if (llGetListLength(lCommands) == 0) {
+                llOwnerSay("Nothing recorded, you need to make a recording first");
+                makeMainMenu();
+                return;
+            }
+            DoSave();
+        }
+        else if (message == "Help"){
+            llLoadURL(kUserKey,"Click to view help","http://www.outworldz.com/opensim/posts/NPC/");
+            makeMainMenu();
+        }
+        else if (message == "Start NPC")    {
+            integer count = checkNoteCards();
+
+            NPCEnabled = TRUE;
+
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+            
+            if (count >= 2) {
+                DEBUG("Notecards approved , calling DoProcessNPCLine");
+                SetStop(FALSE); // Let's run the notecard
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording or maybe an appearance, so we cannot start a NPC");
+      
+        }
+        else if (bNPC_STOP){
+            bNPC_STOP = FALSE;
+            Kill(message);
+        }
+        else if (message == ">>"){
+            makeMenu(lMenu2);
+        }
+        else if (message == ">>>"){
+            makeMenu(lMenu3);
+        }
+        else if (message == "<<") {
+            makeMenu(lAtButtons);
+        }
+        else if (message == "<<<") {
+            makeMenu(lMenu2);
+        }
+        else if (message == "@comment"){
+            Text("# ","Enter a comment","");
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@run"){
+            lCommands += "@run=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@fly"){
+            lCommands += "@fly=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@land"){
+            lCommands += "@land=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@walk") {
+            lCommands += "@walk=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@sound"){
+            Text("@sound=","Enter a sound name or UUID to trigger","");
+        }
+        else if (message == "@randsound"){
+            lCommands += "@randsound"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@say") {
+            Text("@say=","Enter what the NPC will say","");
+        }
+        else if (message == "@whisper"){
+            Text("@whisper=","Enter what the NPC will whisper","");
+        }
+        else if (message == "@shout"){
+            Text("@shout=","Enter what the NPC will shout","");
+        }
+        else if (message == "@wander") {
+            Text("@wander=","Enter radius to wander","Enter number of wanders");
+        }
+        else if (message == "@pause") {
+            Text("@pause=","Enter time to pause","");
+        }
+        else if (message == "@rotate") {
+            Text("@rotate=","Enter degrees to rotate","");
+        }
+        else if (message == "@sit"){
+            Text("@sit=","Enter name of object to sit on","");
+        }
+        else if (message == "@teleport"){
+            lCommands += "@teleport=" + Pos() + "\n";
+            llOwnerSay("teleport to position: " + Pos());
+            makeMenu(lMenu3);
+        }
+        else if (message == "@touch"){
+            Text("@touch=","Enter name of object to touch","");
+        }
+        else if (message == "@cmd"){
+            Text("@cmd=","Enter cjhannel to speak on","Enter text to speak");
+        }
+        else if (message == "@stand"){
+            lCommands += "@stand\n";
+            llOwnerSay("Stand Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@animate"){
+            Text("@animate=","Enter animation name to play","Enter time to play the animation");
+        }
+        else if (message == "@attach"){
+            Text("@animate=","Enter inventory name to attach","Enter number of the attachment point (1-40)");
+        }
+         else if (message == "@speed"){
+            Text("@speed=","Enter a speed for the NPC, 1=100% normal speed, 0.5=50% speed","");
+        }
+               
+
+        // Save NPC name
+        else if (MakeNotecard == STATE) {
+            sNPCName = message; // in case we need to kill it.
+            
+            vector  vDest = (vector)  Pos();
+
+            if (relAbs == "Relative")
+            {
+                vDest  -= llGetPos();    // just an offset for relative
+            }
+            sNotecard = "@spawn=" + message + "|" +  (string) vDest  + "\n";
+            integer i;
+            integer j = llGetListLength(lCommands);
+            for (; i < j; i++){
+                // get the command to save to the notecard
+                string line = llList2String(lCommands,i);
+                if (relAbs == "Absolute") {
+                    sNotecard += line;    // add the un-modified string to the notecard
+                } else {
+                        // since we have to record absolute coords since we do not know where the box goes until they press Save,
+                        // we process the absolute to relative conversion for walks here
+                        list parts = llParseString2List(line,["="],[]); //get the @command
+
+                    if (llList2String(parts,0) == "@walk") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@walk=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@fly") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@fly=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@run") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@run=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@land") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@land=" + (string) vec + "\n";
+                    }
+                    else {
+                        sNotecard += line;    // add the un-modified string to the notecard
+                    }
+                }
+            }
+            llRemoveInventory(Notecard);        // delete the old notecard
+            osMakeNotecard(Notecard,sNotecard); // Makes the notecard.
+            llSay(0,sNotecard);
+            llOwnerSay("Commands notecard has been written");
+            STATE = NULL;
+        } // MakeNotecard
+
+        else  if (! llStringLength(sParam2)) {
+            lCommands +=  sCommand + message + "\n";
+            llOwnerSay("Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (llStringLength(sParam2)){
+            sCommand = sCommand + message + "|";
+            llOwnerSay("Recorded");
+            makeText(sParam2);
+            sParam2 = "";
+        }
+
+    }
+
+
+
+    timer(){
+       // DEBUG("tick");
+        
+        // if llDialog is up, kill the listener for the dialog box.
+        if (iHandle) {
+            llOwnerSay("Menu timed out");
+            llListenRemove(iHandle);
+            iHandle = 0;
+            return;             // ^^^^^^^^^^^^^^^^^^^^^^^
+        }
+        // if NoBodyHome, we are sensing for an avatar
+        else if (NobodyHome == STATE) {
+            ProcessSensor();
+            return;
+        }
+        // if we are spawning, we need time to rez the NPC, then start processing NPC Commands.
+        else if (Spawning == STATE) {
+            STATE = NULL;
+            TimerEvent(TIMER);
+        }
+        // We end aniamtions with a timer
+        else if (Animate == STATE){
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+        }
+        
+        else if (Walking == STATE) {
+            if (--iWaitCounter) {
+                DEBUG("still walking...");
+                if (llVecDist(osNpcGetPos(NPCKey()), newDest) > MAXDIST)  {
+                    return;
+                }
+            }
+
+            DEBUG("At Destination: " + (string) newDest);
+            
+            // walk, fly, run, land
+            if (walkstate == 1) {
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 2)  {
+                    // nothing
+                } else if (walkstate == 3) {
+                     NPCAnimate(STAND);
+                     NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 4) {
+                llShout(FLIGHT,"landing");
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            }
+        }
+        // Wandering timer 
+        else if (Wander == STATE) {
+            if (--iWaitCounter) {          // wait 60 seconds to get to a destination.
+                if (llVecDist(osNpcGetPos(NPCKey()), vWanderPos) > MAXDIST)
+                    return;
+            }
+
+            // see if wander counter == 0, if so, stop walking, go to stand and process next line
+            if(RAMwc == 0) {
+                NPCAnimate(STAND);
+                DEBUG("Wander ended, calling DoProcessNPCLine");
+                STATE = NULL;
+                return;
+            }
+            // one less time to wander around
+            RAMwc--;
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+            StateWanderhold();
+            return;
+        }
+        // Wandering requires us to re-wander when we reach a destination
+        else if (WanderHold == STATE) {
+            StateWander();
+        }
+        else if (DoProcess == STATE) {
+            TimerEvent(QUICK);
+        }
+
+        STATE = NULL;
+
+        // We always process a NPC line at end of timer.
+        DEBUG("Tick end, calling DoProcessNPCLine");
+        DoProcessNPCLine();
+    }
+
+    // sensors are used for sitting on prims
+    // Neo Cortex: added different states to trigger sit or touch
+    sensor(integer num) {
+        if (Sit == STATE ) {
+            osNpcSit(NPCKey(), llDetectedKey(0), OS_NPC_SIT_NOW);
+            DEBUG("Seated, calling DoProcessNPCLine");
+            
+            STATE = 0;
+        } else if (Touch == STATE) {
+            osNpcTouch(NPCKey(), llDetectedKey(0), LINK_THIS);
+            DEBUG("Touched, calling DoProcessNPCLine");
+            STATE = 0;
+        }
+        DoProcessNPCLine();
+    }
+    no_sensor(){
+        DEBUG ("no target prim located, calling DoProcessNPCLine");
+        DoProcessNPCLine();
+        STATE = NULL;
+    }
+
+    
+    link_message(integer sender, integer num, string str, key id){
+        if (num == 0)
+        ParseMsg(str);
+    }
+        
+}
+
+// __ END__
+
+
+
+
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.6.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.6.lsl
new file mode 100644
index 00000000..1fe37a0c
--- /dev/null
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Object/NPC Recorder Script v 4.6.lsl	
@@ -0,0 +1,1692 @@
+// :SHOW:1
+// :CATEGORY:NPC
+// :NAME:All In One NPC Recorder and Player
+// :AUTHOR:Ferd Frederix
+// :KEYWORDS:NPC, Puppeteer
+// :CREATED:2015-10-12 18:07:40
+// :EDITED:2015-10-12  17:07:40
+// :ID:27
+// :NUM:1832
+// :REV:4.6
+// :WORLD:OpenSim
+// :DESCRIPTION:
+// All in one NPC recorder player.
+// Supports both absolute and relative paths and many new commands
+// Add animations named "Fly, Walk, Stand and Run"
+// Click Prim to use.
+// Should be worn as a HUD to record.
+// Put it on the ground and click Sensor or Start NPC when done.
+// :CODE:
+// This is Rev 4.5  09/26/2015
+
+// Revision History
+// Rev 1.1 10-2-2014 @Sit did not work.  Minor tweaks to casting for lslEditor
+// Rev 1.2 10-14-2014 @ sit had wrong type.
+// Rev 1.3 relative movement fixed for @fly
+// Rev 1.4 4-3-2014 allow anyone to use this, non owners and non group members can only start and stop.
+// Rev 1.5 5-17-2014 set sensor to auto start on reboot of sim
+// Rev 1.6 5-24-2014 move menu so you can get it by touching, removed many of the KeyValues to RAM for efficiency
+// Rev 1.7 CHANGED_REGION_START, not CHANGED_REGION_START (Opensim difference)
+// Rev 1.8 tuned up Kill NPC, added more flexible upgrader
+// Rev 1.9 Better script injection by link message// Rev 2.0 Added osSetSpeed so you can speed up or slow down an NPC.
+// Rev 2.1 No laggy sensor used exept to sit on stuff
+// Rev 2.2 Various sensor fixes
+// Rev 2.3 Sets No Sensor in menu, must be started by hand
+// Rev 2.4 - reserved for patches to 2.3 if needed
+// Rev 3.0 Refactor out into subs, not states to make command injection easier
+//            New command: @appearance=Notecardname so you can switch to a new notecard on the fly
+//            New command: @speed=1.0  which slows up  ( < 1 )  or speeds up ( > 1)
+// Rev 3.1 Commands are not interruptible by Link Message
+// Rev 3.2 Sensor patches for consistency in removing the NPC
+// Rev 3.3 Added Touch command by Neo.Cortex@hbase42/hopto/org:8002
+//         Added Menu 3 for notecard and appearance commands
+// Rev 3.4 animation timer cannot be zero or it shuts off timer tweaked
+//         solves the NPC starting up when no sensor is set.
+// Rev 3.5 fixes saving to !Path  notecard
+// Rev 3.6 08-11-2015 @delete acts like @stop. TYjhe NPC now rezzes after an @go back in where it was deleted 
+// Rev 3.7 08-11-2015 @attach command added to load an attachment from the inventory to the NPC
+// Rev 3.8 08-17-2015 process queued commands one at a time without calling ProcessNPCLine on link message
+// Rev 3.9 08-23-2011 Queued command fixes including @delete which were not always working
+// Rev 4.0 09-15-2015 Fixes for Sensor functions which continually rezzed a NPC when no one was around.
+// Rev 4.1 09-20-2015 Added a Listener so link messages are not needed
+// Rev 4.2 09-23-2015 Added @teleport=<vector>
+// Rev 4.3 09-24-2015 Added @reset to restart the NPC at the very start of the !Path notecard
+//                    @teleport works for relative and absolute modes
+// Rev 4.4 09-26-2015 if it could not find the (deleted) NPC, it could not restart
+// Rev 4.5 09-29-2015 remove wait for STATE == 0
+//*******************************************************************//
+
+// Instructions on how to use this are at http://www.outworldz.com/opensim/posts/NPC/
+// This is an OpenSim-only script.
+// Author: Ferd Frederix aka Fred Beckhusen - fred@mitsi.com
+
+////////////////////////////////////////////////////////////////////////////////////////////
+//    Original code was Copyright (C) 2013 Wizardry and Steamworks - License: GNU GPLv3    //
+///////////////////////////////////////////////////////////////////////////////////////////
+//  Please see: http://www.gnu.org/licenses/gpl.html for legal details,                  //
+//  rights of fair usage, the disclaimer and warranty conditions.                        //
+///////////////////////////////////////////////////////////////////////////////////////////
+// The original NPC controller was from http://was.fm/opensim:npc
+// Extensive additions and bug fixes by Fred Beckhusen, aka Ferd Frederix
+// llSensor had two params swapped
+// @Wander would wander where it had rezzed, not where it was.
+// There was no 'no_sensor' event in sit, so if a @sit failed, the NPC got stuck
+// The animation and walks always stopped old, then started new.  It should be start new, then stop old so the default stand would be suppressed.
+// New code:
+// Merged with new Route recorder and notecard writer
+// If the NPC failed to reach a destination it never moved on.
+// Added WAIT global to tune this
+// Exposed many tunable variables and ported the code 
+// Added floating point to times in notecard.
+// Added @sound, @randsound, @whisper, @shout, and @cmd controls.
+// notecards integers are not floats for better control
+// 
+// Link Messages may be used to perform external control by injecting @commands into the stream of actions
+// Example:
+// To chat something, such as with a chat robot
+//  llMessageLinked(LINK_SET,0,"@npc_say=Hello","");
+
+// This script assumes that NPCs and OSSl scripting is enabled in the OpenSim configuration.
+// In order to enable them, the following changes must be made in the OpenSim.ini configuration file:
+//
+// ; Turn on OSSL
+// AllowOSFunctions = true
+// OSFunctionThreatLevel = Severe
+
+//[NPC]
+//    ;# {Enabled} {} {Enable Non Player Character (NPC) facilities} {true false}
+//    Enabled = true
+//
+// and then the server has to be restarted.
+// please note that there are better ways to enable NPC in the latest Opensim.  
+
+// Commands: All commands begin with an @ sign.  All other lines are ignored
+// @commands may have optional parameters.  The syntax is always:
+//  @cmd=parm1|parm2
+//  NaN in the table below meand Not a Number.   This means there is no parameter
+
+//Command     First Parameter             Second Parameter        Description
+//@spawn      name                        location (vector)       Rezzes an NPC with name at a location.
+//@appearance NoteCardName                NaN                     switch the NPC appearance to a new notecard
+//@walk       destination (vector)        NaN                     Makes the NPC walk to destination.
+//@fly        destination (vector)        NaN                     Makes the NPC fly to destination.
+//@land       destination (vector)        NaN                     Makes the NPC land at destination.
+//@say        string                      NaN                     Makes the NPC speak a phrase.
+//@whisper    string                      NaN                     Makes the NPC whisper a phrase.
+//@shout      string                      NaN                     Makes the NPC shout a phrase.
+//@pause      seconds (float)             NaN                     Makes the NPC wait for a multiple of seconds.
+//@wander     radius (float)              cycles (integer)        Makes the NPC wander in radius, for cycles seconds.
+//@delete     NaN                         NaN                     Removes the NPC.  Requires a link message to continue
+//@goto       label (string)              NaN                     Jump to the label label in the script.
+//@animate    animation (string)          time (float)            Makes the NPC trigger the animation animation for time seconds.
+//@sound      sound_name                  NaN                     plays a sound from inventory
+//@randsound  NaN                         NaN                     Plays a random sound from inventory
+//@rotate     degrees (float)             NaN                     Rotate the NPC degrees around the Z axis.
+//@sit        primitive name              NaN                     Sit on a primitive with a given name.
+//@touch      primitive name              NaN                     Touch on a primitive with a given name.
+//@stand      NaN                         NaN                     If sitting on a primitive, stand up.
+//@cmd        channel (integer)           string                  Says string on channel, for controlling external gadgets
+//@stop       NaN                         NaN                     Halts the NPC script indefinitely. Can be started with a link message
+//@go         NaN                         NaN                     Continues on next notecard line, for use in link messages
+//@speed      speed (float)               NaN                     from 0 to N, where 1.0 ius a normal speed of an avatar.  0.2 is a turtle.
+//@notecard   notename (string)           NaN                     load a new Path notecard
+//@attach     InventoryName               attachmentPoint         load an attachment from the inventory to the NPC onto point
+//@teleport   destination (vector)        NaN                     Makes the NPC teleport to destination in the same sim.  They cannot tp to another sim or across the HG
+//@reset      NaN                         NaN                     Deletes the NPC, starts the !Path notecard over.
+ 
+// Constant            attachmentPoint Comment
+// ATTACH_CHEST            1    chest/sternum
+// ATTACH_HEAD             2    head
+// ATTACH_LSHOULDER        3    left shoulder
+// ATTACH_RSHOULDER        4    right shoulder
+// ATTACH_LHAND            5    left hand
+// ATTACH_RHAND            6    right hand
+// ATTACH_LFOOT            7    left foot
+// ATTACH_RFOOT            8    right foot
+// ATTACH_BACK             9    back
+// ATTACH_PELVIS          10    pelvis
+// ATTACH_MOUTH           11    mouth
+// ATTACH_CHIN            12    chin
+// ATTACH_LEAR            13    left ear
+// ATTACH_REAR            14    right ear
+// ATTACH_LEYE            15    left eye
+// ATTACH_REYE            16    right eye
+// ATTACH_NOSE            17    nose
+// ATTACH_RUARM           18    right upper arm
+// ATTACH_RLARM           19    right lower arm
+// ATTACH_LUARM           20    left upper arm
+// ATTACH_LLARM           21    left lower arm
+// ATTACH_RHIP            22    right hip
+// ATTACH_RULEG           23    right upper leg
+// ATTACH_RLLEG           24    right lower leg
+// ATTACH_LHIP            25    left hip
+// ATTACH_LULEG           26    left upper leg
+// ATTACH_LLLEG           27    left lower leg
+// ATTACH_BELLY           28    belly/stomach/tummy
+// ATTACH_LEFT_PEC        29    left pectoral
+// ATTACH_RIGHT_PEC       30    right pectoral
+// ATTACH_HUD_CENTER_2    31    HUD Center 2
+// ATTACH_HUD_TOP_RIGHT   32    HUD Top Right
+// ATTACH_HUD_TOP_CENTER  33    HUD Top
+// ATTACH_HUD_TOP_LEFT    34    HUD Top Left
+// ATTACH_HUD_CENTER_1    35    HUD Center
+// ATTACH_HUD_BOTTOM_LEFT 36    HUD Bottom Left
+// ATTACH_HUD_BOTTOM      37    HUD Bottom
+// ATTACH_HUD_BOTTOM_RIGHT 38   HUD Bottom Right
+// ATTACH_NECK            39   neck
+// ATTACH_AVATAR_CENTER  40    avatar center/root
+
+
+  
+//////////////////////////////////////////////////////////
+//                  DEBUG                               //
+//////////////////////////////////////////////////////////
+integer debug = FALSE;         // set to TRUE or FALSE for debug chat on various actions
+integer LSLEditor = FALSE;        // set to to TRUE to working in  LSLEditor, FALSE for in-world.
+                              // you must also include the NPC commands found in the other script since LSLEditor does not support OpenSim
+integer iTitleText = TRUE;    // set to TRUE to see debug info in text above the controller
+ 
+//////////////////////////////////////////////////////////
+//                  TUNABLE CONFIGURATION               //
+//////////////////////////////////////////////////////////
+integer keyNum = -1;    // (namaka) special number for link message to broadcast the NPC key
+integer   allowListener = TRUE; // set to TRUE to anable a command listener. Usually, this is setto FALSE
+integer   link_Channel =   4223; // some random number you want to talk to this gadget on. Best if large and negative
+float     TIMER = 2;         // faster = less jerky stopping.  How often the system checks the distance traveled.  Fastest you can go is 0.5 seconds
+float     QUICK = 1;        // when we need to move to the next state, we use a QUICK timer
+string    Appearance = "!Appearance";  // The name of the recorded Appearance notecard
+string    Notecard = "!Path"; // The name of the recorded routes
+integer   allowUsers = FALSE;  // If true, any user can get a Start NPC and Stop NPC menu.  Only groups and owners can get all commands if TRUE, or FALSE
+float     MAXDIST = 2.0;       // how close a NPC has to get to a dest pos to continue to next state. Do not lower this too much, as it may miss the target
+integer   WANDERRAND = TRUE;   // set to TRUE and they will pause during wanders a random number of seconds
+float     WANDERTIME = 3.0;    // how long they stand after each @wander,if WANDERRAND is FALSE. If WANDERRAND is  TRUE, this is the max time
+integer   WAIT = 30;           // wait for this number of seconds for the NPC to reach a destination (for safety). If it fails to reach a target, it will move on after this time.
+float     RANGE = 150;        // 1 to N meters  - anyone this close to the controller will start NPCS if Sensor button is clicked
+float     REZTIME = 2.0;      // wait this long for NPC to rez in, then start the process
+string    STAND = "Stand";     // the name of the default Stand animation
+string    WALK = "Walk";       // the name of the default Walk animation
+string    FLY = "Fly";        // the name of the default Fly animation
+string    RUN = "Run";        // the name of the default Run animation
+string    LAND = "Land";      // the name of the default land animation ( for birds only)
+float     OffsetZ = 0.5;      // appear 0.5 meter above ground, this is added to all destinations to keep them from sinking in.  
+float    SPEEDMULT =0.8;     // 1.0 = regular avatar speed. Smaller numbers slow down walks. Large numbers speed them up.
+integer  FLIGHT = 299;        // For controlling wings.  A channel that is shouted at when flight starts and ends. "flying" or "landing" 
+
+// DESCRIPTIONS FIELDS HAVE TO SURVIVE A RESET
+//  These vars are stored  by saving them with KeyValueSet
+// "pr" is a 0 if it is set for Owner Only, 1 for Group control
+// "se" is "on" if Started
+// "co" = "R" or "A" for relative or absolute addressing mode
+// "key" = NPC key
+
+// These Globals used to be stored in description.   Moved to RAM in V1.6
+float RAMPause;          // @pause param
+float RAMwd ;            // @wander distance
+integer RAMwc;           // @wander count
+float RAMrot;            //  @rotate
+string RAMsit;           // @sit primname
+string RAMtouch;         // @touch primname
+string RAManimationName; // @animate animation (string) time (float)
+float RAManimationTime;
+
+// other globals section
+integer iChannel;        // a listen channel, randomly assigned
+integer iHandle;         // the handle to it
+
+// NPC controls
+vector newDest ;                // tmp storage for the walks
+integer iWaitCounter ;          // wait for this number of seconds for the NPC to reach a desrtination
+string sNPCName;                // the name of the NPC that may be in world. So we can remove it.
+integer bNPC_STOP = FALSE;      // boolean to reuse a listener
+integer Stopped = FALSE;        // set to TRUE by link messages so we do not remember them
+float  fTimerVal ;              // how long we wait when wandering (calculated)
+float NPCEnabled;               // true if the NPC is suppodes to be running
+
+// OS_NPC_CREATOR_OWNED will create an 'owned' NPC that will only respond to osNpc* commands issued from scripts that have the same owner as the one that created the NPC.
+// OS_NPC_NOT_OWNED will create an 'unowned' NPC that will respond to any script that has OSSL permissions to call osNpc* commands.
+integer  NPCOptions = OS_NPC_CREATOR_OWNED;    // only yhe owner of this box can control this NPC.
+
+integer walkstate = 0;  // helps us reshare the walk state for run, fly and land - a bit of a hack, but it saves RAM. Has to be done this way because some bits of NPCWalkOption are asserted as 0
+
+integer NPCWalkOption;   // Some notes for what happens to NPCWalkOption:
+// OS_NPC_FLY - Fly the avatar to the given position. The avatar will not land unless the OS_NPC_LAND_AT_TARGET option is also given.
+// OS_NPC_NO_FLY - Do not fly to the target. The NPC will attempt to walk to the location. If it's up in the air then the avatar will keep bouncing hopeless until another move target is given or the move is stopped
+//OS_NPC_LAND_AT_TARGET - If given and the avatar is flying, then it will land when it reaches the target. If OS_NPC_NO_FLY is given then this option has no effect.
+// OS_NPC_RUNNING - if given, NPC avatar moves at running/fast flying speed, otherwise moves at walking/slow flying speed.
+
+// menus
+string mSensor="Sense is Off";    // Sensor or "No Sensor"
+
+list lAtButtons = ["Menu","-",   ">>",         "@run",    "@walk",   "@fly",  "@land", "@wander",    "@sit",   "@stand","@animate","@rotate"];
+list lMenu2 = ["<<", "@comment", ">>>",        "@stop",      "@say",    "@whisper","@shout","@sound","@randsound","@cmd",  "@pause",  "@delete"];
+list lMenu3 = ["<<<","@notecard","@appearance", "@touch", "@speed",       "@attach",     "@teleport","-", "-", "-", "-", "-" ];
+
+string sCommand;  // place to store a command for two-prompted ones
+string sParam2;   // place to store a prompt for two-prompted ones
+string priPub = "Owner Only";    // Private or Group
+key kUserKey;        // the person who is controlling the avatar, not the Owner  
+// the command lists
+list lCommands;  // commands are stored here
+list lNpcCommandList; // Storage for the NPC script.
+string npcAction; // Storage for the next action. @cmd=0|hello, this becomes @cmd
+string npcParams; // Storage for the param, @cmd=0|hello, this becomes 0|hello
+
+// misc vars
+string sNotecard; // commands are stored here temporarily for dumping
+vector  vWanderPos; // a place to wander to
+string lastANIM ;   // last animation run
+// Sensor
+integer avatarPresent;   // Sensor sets this flag when people are within Range.
+
+// Coordinate control
+vector vInitialPos ; // Vector that will be filled by the script with the initial starting position in region coordinates.
+vector vDestPos = ZERO_VECTOR; // Storage for destination position.
+string relAbs = "Relative";    // absolute vs relative positioning
+
+
+// STATES
+integer MENU ;             // processing a dialog box state, may be concurrent with STATE
+integer STATE;             // state storage
+integer NULL = 0;          // the null state
+integer MakeNotecard = 1;  // displaying a text box for NPC name
+integer RecordPath = 2;    // displaying a path notecard menu
+integer NobodyHome = 3;    // looking for an avatar
+integer Spawning = 4;      // spawning an avatar
+integer Animate = 5;       // animation timer needed
+integer Walking = 6;       // Hey! I am walking here!
+integer Wander = 7;        // Wandering around neeeds a timer, too
+integer WanderHold = 8;    // We reached a wander point
+integer DoProcess = 9;     // Set this to make it process a new command
+integer Touch = 10;        // Timer is busy sensing something to touch
+integer Sit = 11;          // Timer is busy sensing something to sit on
+integer Paused = 12;       // Timer is busy pausing
+
+key gNpcKey = NULL_KEY;   // global key storage for the one NPC, to save CPU cycles
+list Stack ;              // a command stack from link message input
+
+///////////////////////////////////////////////////////////////////////////
+//                              FUNCTIONS                                //
+///////////////////////////////////////////////////////////////////////////
+
+
+TimerEvent(float timesent)
+{
+    if (LSLEditor)
+        timesent *= 5;   // slow thinggs doen when the LSLEDITOR is in use
+        
+    DEBUG("Setting  timer: " + (string) timesent);
+    llSetTimerEvent(timesent);
+}
+
+// for 4.1 parse a message from a Listen or a Link message
+ParseMsg(string str) {
+    DEBUG("Command In:" + str);
+    if (str=="@go") {
+        SetStop(FALSE); // Let's run the notecard
+        DEBUG("@go running");
+        DoProcessNPCLine();
+    } else {
+        Stack += [str];    // take anything, the controller will filter away non @ stuff
+        if (STATE == NULL)
+            DoProcessNPCLine(); // v 4.5 remove wait for STATE == 0
+    }
+}
+
+SetStop(integer what)
+{
+    DEBUG("Stopped set to " + (string ) what);
+    Stopped = what;
+}
+// Do* functions are much like states from the old V2 scripts.
+    
+// Save a Path notecard
+DoSave()
+{ 
+    STATE = MakeNotecard;
+    makeText("Stand where you want the NPC to appear, and enter the NPC Name");
+}
+
+// This function is used to record the path for the NPC
+// Each command can take 0, 1, or 2 params
+DoMenuForCommands() {
+    makeMenu(lAtButtons);
+}
+
+
+// No one is here when sensors were on, so we kill off the NPC
+DoNobodyHome()
+{
+    DEBUG("Nobody Home");
+    STATE = NobodyHome;
+    if (NPCKey() != NULL_KEY) {
+        osNpcRemove(NPCKey());
+        SaveKey(NULL_KEY);
+    }
+    TimerEvent(5);  // keep ticking to sense avatars   
+}
+
+
+///////////////////////  STATELIKE BEHAVIOUR  /////////////
+// these StateXX functions need to wait on a timer to fire. 
+
+// Create a NPC
+StateSpawn() {
+    DEBUG("state spawn " + sNPCName);
+     
+    NPCEnabled = TRUE; //  in world
+    // see if there is already one out there.
+    if (NPCKey() != NULL_KEY) {
+        DEBUG("Already living");
+        return;
+    }
+    
+    STATE = Spawning;        
+    list name = llParseString2List(sNPCName, [" "], []);
+   
+    vector vRezPos = vInitialPos;
+    if (relAbs == "Relative"){
+        vRezPos += llGetPos();
+    }
+
+   // llSay(0,llDumpList2String(name,",")); 
+
+    DEBUG("Rezzing NPC name " +llList2String(name, 0)+ llList2String(name, 1) + " at "+ (string) vRezPos);
+    key aKey = osNpcCreate(llList2String(name, 0), llList2String(name, 1), vRezPos, Appearance, NPCOptions);
+
+    llMessageLinked(LINK_SET,keyNum,"",aKey);    // bboradcast the key on num = -1
+    SaveKey(aKey); // save in description and global, too
+    
+    osSetSpeed(aKey,SPEEDMULT);   // 1.9 speed multiplier
+    TimerEvent(REZTIME);
+    NPCAnimate(STAND);
+}
+
+StateSit() {
+    DEBUG ("state sit - looking for " + RAMsit);
+    STATE=Sit;
+    llSensor(RAMsit, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+
+StateTouch() {
+    DEBUG ("state touch - looking for " + RAMtouch);
+    STATE = Touch;
+    llSensor(RAMtouch, "", PASSIVE|ACTIVE|SCRIPTED,  96, PI);
+}
+ 
+DoStand() {
+    DEBUG("state stand");
+    osNpcStand(NPCKey());
+}
+
+
+StateAnimate() {
+    
+    DEBUG("state animate");
+    STATE = Animate;
+    NPCAnimate(RAManimationName);
+    if (RAManimationTime <=0 )    // V 3.4 tweak
+        RAManimationTime = 1;
+    TimerEvent(RAManimationTime);
+}
+    
+StateWalk() {
+
+    DEBUG("Start Walk");
+    //DEBUG("NPCWalkOption = " + (string) NPCWalkOption);
+    STATE = Walking;
+            
+    // walk, fly, run, land
+   if (walkstate == 1) {
+        NPCAnimate(WALK);
+    } else if (walkstate == 2)  {
+        llShout(FLIGHT,"flying");
+        NPCAnimate(FLY);
+    } else if (walkstate == 3) {
+        NPCAnimate(RUN);
+    } else if (walkstate == 4) {
+        NPCAnimate(LAND);
+    } 
+    newDest = vDestPos ;
+    newDest.z += OffsetZ;
+        
+    // notecard is stored as offsets from this box with relative addressing.  Convert to absolute
+    if (relAbs == "Relative"){
+        newDest += llGetPos();
+    }
+
+    DEBUG("Moveto:" + (string) newDest);
+    osNpcMoveToTarget(NPCKey(), newDest, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);
+}
+
+
+StateWander(){
+    DEBUG("state wander");
+    STATE = Wander;
+    
+    vector point = CirclePoint(RAMwd);
+    DEBUG("CirclePoint:" + (string) point);
+    vWanderPos = vDestPos + point;
+    DEBUG("vWanderPos:" + (string) vWanderPos);
+
+    fTimerVal = WANDERTIME;    // default time to pause after each wander
+    if (WANDERRAND)
+        fTimerVal = llFrand(WANDERTIME) + 1;    // override, they want random times
+
+    NPCAnimate(WALK);
+
+    DEBUG("Wander to:" + (string) vWanderPos);
+
+    osNpcMoveToTarget(NPCKey(), vWanderPos, NPCWalkOption);
+    iWaitCounter = WAIT;            // wait 60 seconds to get to a destination.
+    TimerEvent(TIMER);      
+}
+
+StateWanderhold() {
+
+    DEBUG("Wander Hold");
+    STATE = WanderHold;
+       
+     // now that we have reached a wander spot, slow the timer down to the desired value
+    TimerEvent(fTimerVal);
+}
+
+
+ 
+DoRotate() {
+    DEBUG("@rotate=" + (string) RAMrot); 
+    osNpcSetRot(NPCKey(), llEuler2Rot(<0,0,RAMrot> * DEG_TO_RAD));
+}  
+
+
+
+// @pause=10 will do nothing for 10 seconds
+DoPause() {
+    STATE = Paused;
+    if (RAMPause < 0.1)
+        RAMPause = 0.1;
+    DEBUG("@pause=" + (string)RAMPause);
+    TimerEvent(RAMPause);
+}
+
+
+// @stop makes the NPC stop moving in whatever state it is in.  You have to linkmessage to get moving again
+DoStop() {    
+    DEBUG("NPC is Stopped");
+    STATE   = 0;    // accept commands
+    SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+    TimerEvent(0);
+    Stack = []; // v3.8
+}
+    
+// @delete removes the NPC forever. Next command starts it up again at the beginning
+DoDelete() {
+    DEBUG("state delete");
+    osNpcRemove(NPCKey());
+    SaveKey(NULL_KEY);
+    TimerEvent(0);
+    Stack = []; // v3.8
+    STATE = NULL;    // accept commands
+}
+
+// change the appearance of the NPC
+DoAppearance(string notecard) {
+    DEBUG("state appearance");
+    if (llGetInventoryType(notecard) == INVENTORY_NOTECARD){
+        DEBUG("Load appearance " + notecard);
+        osNpcLoadAppearance(NPCKey(),notecard);
+    }
+    STATE = NULL;    // accept commands
+}
+
+// Change the avatar speed
+DoSpeed(string speed) {
+    float newspeed = (float) speed;
+    if (newspeed > 0.1 && newspeed < 5.0) {// sanity check
+        osSetSpeed(NPCKey(),newspeed);
+    }
+    STATE = NULL;    // accept commands
+}
+
+DoTeleport(string params) {
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    vector Dest = (vector) itemName;
+    if (Dest != ZERO_VECTOR) {
+        if (relAbs == "Relative"){
+            Dest += llGetPos();
+        }
+        osTeleportAgent( NPCKey(), llGetRegionName(), Dest, ZERO_VECTOR );
+        
+    } else {
+        llSay(DEBUG_CHANNEL,"Attempt to teleport to <0,0,0> probably not what you intended: @teleport=<vector>");
+    }
+    STATE = NULL;    // accept commands
+}
+
+
+
+DoNewNote (string card) {
+    DEBUG("Load Notecard " + card);    
+    NPCReadNoteCard(card);
+    SetStop(FALSE);
+    STATE = NULL;    // accept commands
+}
+DoAttach(string params) {
+    
+    list Data = llParseString2List(params, ["|"], []);
+    string itemName = llList2String(Data, 0);
+    integer attachmentPoint  = (integer) llList2String(Data, 1);
+    if (attachmentPoint > 0
+        && attachmentPoint < 40
+        && llGetInventoryType(itemName) == INVENTORY_OBJECT
+       )
+    {
+        osForceAttachToOtherAvatarFromInventory(NPCKey(),itemName,attachmentPoint);
+    }
+    STATE = NULL;    // accept commands
+}
+
+// This loops over the notecard, processing each command
+DoProcessNPCLine() {
+    DEBUG("ProcessNPCLine, stopped = " + (string) Stopped);
+    
+    STATE = DoProcess;
+    
+        // auto load a notecard
+    if (! llGetListLength(lNpcCommandList)) {
+        DEBUG("Read Notecard");
+        NPCReadNoteCard(Notecard);
+    }
+
+    // look for link messages on the stack
+    string next = llList2String(Stack,0);    // lets see if there is anything from a link message
+    if (llStringLength(next))
+    {
+        Stack = llDeleteSubList(Stack,0,0);
+        ProcessCmd(next);        //lets do this command instead.
+        return;
+    }
+
+    // @stop issued?
+    if (Stopped) {
+        TimerEvent(0);
+        DEBUG("Stopped, waiting for input");
+        STATE = NULL;
+        return;
+    }
+
+    // No, we have an @go for liftoff
+    next = llList2String(lNpcCommandList, 0);        // get the next command
+    DEBUG("Execute:" + next);
+    lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);      // delete it
+        
+    if (llGetListLength(lNpcCommandList) == 0) {
+        DEBUG("EOF");
+    }
+    ProcessCmd(next);
+} 
+
+
+
+ProcessCmd(string cmd) {
+
+    DEBUG("ProcessCmd:" + cmd);
+
+    llMessageLinked(LINK_SET,keyNum,"",NPCKey());    // bboradcast the key on num = -1
+    if (llGetSubString(cmd, 0, 0) != "@") {
+        DEBUG("ignoring");
+        TimerEvent(QUICK);  // this is so we do not recurse the stack
+        STATE = NULL;
+        return;
+    }
+
+    list data  = llParseString2List(cmd, ["="], []);
+    npcAction = llToLower(llStringTrim(llList2String(data, 0), STRING_TRIM));
+
+    DEBUG("Action:" + npcAction);
+    npcParams = llStringTrim(llList2String(data, 1), STRING_TRIM);
+    DEBUG("Params:" + npcParams);
+    
+    @commands;
+
+    ProcessSensor();
+    
+    if(npcAction == "@spawn") {
+        DEBUG("@spawn npcParams ");
+        list spawnData = llParseString2List(npcParams, ["|"], []);
+        sNPCName =llList2String(spawnData, 0);    // V 1.6 name in RAM
+
+        vInitialPos = (vector) llList2String(spawnData, 1);        
+        DEBUG("Coords for NPC at " + (string) vInitialPos);
+        StateSpawn();
+        return;
+    }
+    
+     if (! avatarPresent){
+        DoNobodyHome();
+        DEBUG("No avatar nearby");
+        STATE = NULL;
+        return;
+    } else {
+        if ( NPCKey() == NULL_KEY) {
+            StateSpawn();
+        }
+    }
+
+    
+    
+    
+    if(npcAction == "@stop") {
+        DoStop();
+        STATE = NULL;
+        return;
+    }
+    else if(npcAction == "@goto") {
+        DEBUG("goto");
+        integer lastIdx = llGetListLength(lNpcCommandList)-1;
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, lastIdx, lastIdx);
+        // Wind commands till goto label.
+        @wind;
+        string next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        if(next1 != npcParams) jump wind;
+        // Wind the label too.
+        next1 = llList2String(lNpcCommandList, 0);
+        lNpcCommandList = llDeleteSubList(lNpcCommandList, 0, 0);
+        lNpcCommandList += next1;
+        // Get next command.
+        list data1  = llParseString2List(next1, ["="], []);
+        npcAction = llToLower(llStringTrim(llList2String(data1, 0), STRING_TRIM));
+        npcParams = llStringTrim(llList2String(data1, 1), STRING_TRIM);
+        // Reschedule.
+        jump commands;
+    }
+    else if(npcAction == "@sound") {
+        DEBUG("sound");
+        llTriggerSound(npcParams,1.0);
+    }
+    else if(npcAction == "@randsound") {
+        DEBUG("@randsound");
+        integer N = llGetInventoryNumber(INVENTORY_SOUND);
+        integer rand = llCeil(llFrand(N)) -1;    // pick a random sound
+        string toPlay = llGetInventoryName(INVENTORY_SOUND,rand);
+        llTriggerSound(toPlay,1.0);
+    }
+    else if(npcAction == "@walk") {
+        DEBUG("@walk");
+        GetDest(npcParams);
+        walkstate = 1;//  walking
+        NPCWalkOption = OS_NPC_NO_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@fly") {
+        GetDest(npcParams);
+        walkstate = 2;//  flying
+        NPCWalkOption = OS_NPC_FLY ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@run") {
+        DEBUG("@run");
+        GetDest(npcParams);
+        walkstate = 3;//  running
+        NPCWalkOption = OS_NPC_NO_FLY | OS_NPC_RUNNING;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@land") {
+        DEBUG("@land");
+        GetDest(npcParams);
+        walkstate = 4;//  landing
+        NPCWalkOption= OS_NPC_FLY | OS_NPC_LAND_AT_TARGET ;
+        StateWalk();
+        return;
+    }
+    else if(npcAction == "@say") {
+        DEBUG("@say " + npcParams);
+        osNpcSay(NPCKey(), 0, npcParams);
+    }
+    else if(npcAction == "@shout") {
+        DEBUG("@shout");
+        osNpcShout(NPCKey(),0, npcParams);
+    }
+    else if(npcAction == "@whisper") {
+        DEBUG("@whisper " + npcParams);
+        osNpcWhisper(NPCKey(),0, npcParams);
+    }
+    // speak a command on a channel, so you can open doors and control stuff.
+    else if(npcAction == "@cmd") {
+        DEBUG("@cmd");
+        list dataToSpeak = llParseString2List(npcParams, ["|"], []);
+        string channel = llList2String(dataToSpeak,0);
+        DEBUG("Channel:"+(string) channel);
+        integer iChannel = (integer) channel;
+        string stringToSpeak = llList2String(dataToSpeak,1);
+        llSay(iChannel, stringToSpeak);
+    }
+    // stop everything
+    else if(npcAction == "@pause") {
+        RAMPause = (float) npcParams;
+        DoPause();
+        return;
+    }
+    else if(npcAction == "@wander") {
+        list wanderData = llParseString2List(npcParams, ["|"], []);
+        RAMwd = (float) llList2String(wanderData, 0);
+        RAMwc = (integer) llList2String(wanderData, 1);
+        vDestPos = osNpcGetPos(NPCKey());        // set the wander start
+        DEBUG("Starting at " + (string) vDestPos);
+        StateWander();
+        return;
+    }
+    else if(npcAction == "@rotate") {
+        RAMrot = (float) npcParams;
+        DoRotate();
+    }
+    else if(npcAction == "@sit") {
+        RAMsit= npcParams;
+        StateSit();
+        return;
+    }
+    else if(npcAction == "@touch") {
+        RAMtouch= npcParams;
+        StateTouch();
+        return;
+    }
+    else  if(npcAction == "@stand") {
+        DoStand();
+    }
+    else if(npcAction == "@delete") {
+        DoDelete();
+        SetStop(TRUE); // Link controlled - we mnust have a @go to continue with notecards
+        return;
+    }
+    else if(npcAction == "@animate") {
+        list animateData = llParseString2List(npcParams, ["|"], []);
+        RAManimationName = llList2String(animateData, 0);
+        RAManimationTime = (float) llList2String(animateData, 1);
+        StateAnimate();
+        return;
+    }
+    else if(npcAction == "@appearance" ){
+        DoAppearance(npcParams);
+    }
+    else if (npcAction =="@speed") {
+        DoSpeed(npcParams);
+    }
+    else if (npcAction =="@notecard") {      
+        DoNewNote(npcParams);
+        Notecard = npcParams;
+    }
+    else if (npcAction == "@attach")
+    {
+        DoAttach(npcParams);
+    }
+    else if (npcAction == "@teleport")
+    {
+        DoTeleport(npcParams);
+    }
+    else if (npcAction == "@reset")
+    {
+        DoDelete();
+        SetStop(FALSE); // a @resst will restart the original !Path after deleting the notecard.
+    }
+
+    STATE = NULL;
+    TimerEvent(QUICK);  // yeah I know, not possible this fast, we just go as fast as we can go - this is so we do not recurse the stack 
+}
+ 
+
+
+/////////////////// UTILITY Functions, not state-like //////////////////
+
+// DEBUG(string) will chat a string or display it as hovertext if debug == TRUE
+DEBUG(string str) {
+    if (debug && ! LSLEditor)
+        llOwnerSay( str);                    // Send the owner debug info 
+    if (debug &&  LSLEditor)
+        llSay(0, str);                    // Send to the Console in LSLEDitor 
+    if (iTitleText) {
+        llSetText(str,<1.0,1.0,1.0>,1.0);    // show hovertext
+    
+    }
+} 
+
+GetDest(string npcParams) {
+    list dest = llParseString2List(npcParams, ["<", ",", ">"], []);
+    vDestPos.x = llList2Float(dest, 0);
+    vDestPos.y = llList2Float(dest, 1);
+    vDestPos.z = llList2Float(dest, 2);
+}
+
+NPCReadNoteCard(string Note) {
+    DEBUG("NPCReadNoteCard");             
+    lNpcCommandList = llParseString2List(osGetNotecard(Note), ["\n"], []);
+}  
+  
+integer SenseAvatar()
+{
+    //Returns a strided list of the UUID, position, and name of each avatar in the region
+    list avatars = llGetAgentList(AGENT_LIST_REGION ,[]);
+    integer numOfAvatars = llGetListLength(avatars);
+    if (numOfAvatars == 0)
+    {
+        DEBUG("No people");
+        return 0;
+    }
+    //DEBUG("Located " + (string)numOfAvatars + " avatars and NPC's"); 
+        
+    integer nAvatars;
+    integer i;
+    for( i = 0;i < numOfAvatars; i++) {
+        key aviKey = llList2Key(avatars,i);
+        if (!osIsNpc(aviKey)) {
+            list detail = llGetObjectDetails(aviKey,[OBJECT_POS]);
+            vector pos = llList2Vector(detail,0);
+            float dist = llVecDist(pos, llGetPos());
+            if (dist  < RANGE)
+            {
+                nAvatars++;
+                DEBUG("In range:" + llKey2Name(aviKey));
+            }
+        }
+    }
+    //DEBUG("Located " + (string) nAvatars + " avatars");
+    return nAvatars;
+} 
+ 
+// return TRUE if the avatar is owner when private is set, or TRUE if the avatar is in the same group and GROUP is set.
+integer checkPerms() {
+
+    integer group = (integer) KeyValueGet("pr");
+    if (! group)
+        priPub = "Owner Only";
+    else
+        priPub = "Group";
+    
+    
+    if (llDetectedKey(0) == llGetOwner()){
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+ 
+    if ( group && llDetectedGroup(0)) {
+        kUserKey = llDetectedKey(0);
+        return TRUE;
+    }
+    kUserKey = llDetectedKey(0);
+    return FALSE;
+}
+
+
+
+NPCAnimate(string anim)
+{
+    DEBUG("Start Anim: " + anim);
+    if (llGetInventoryType(anim) == INVENTORY_ANIMATION ) {
+        
+        if (lastANIM != anim) {
+            if(llStringLength(lastANIM)) {
+                osNpcStopAnimation(NPCKey(), lastANIM);  
+            }
+            osNpcPlayAnimation(NPCKey(), anim);
+            lastANIM = anim;
+        }            
+    } else {
+        llSay(DEBUG_CHANNEL, "No animation named " + anim);
+    }
+} 
+
+// Kill a NPC by Name
+Kill(string param)
+{
+    integer count;
+    list avatars = osGetAvatarList(); // Returns a strided list of the UUID, position, and name of each avatar in the region except the owner.\    
+    integer i;
+    integer j = llGetListLength(avatars);
+    for (i=0 ; i <= j; i+=3){
+        
+        string desired = llList2String(avatars,i+2);
+        desired = llStringTrim(desired,STRING_TRIM);    // should not be needed but is needed
+        
+        if (desired == param){
+            vector v = llList2Vector(avatars,i+1);
+            key target = llList2Key(avatars,i);    // get the UUID of the avatar
+            osNpcRemove(target);
+            
+            llOwnerSay("Removed " + param+ " at  location " + (string) v);
+            count++;
+        }
+    }
+    
+    NPCEnabled = FALSE; // not in world
+    SaveKey(NULL_KEY );    // Rev 4.4
+    
+    if (count)
+        llOwnerSay("Removed " + (string) count + " NPC's");
+    else
+        llOwnerSay("Could not locate " + param);
+}
+
+
+// return a String for the position we are at. Strings used as the caller wants strings
+string Pos()
+{
+    vector where = llGetPos(); // find the box position
+   
+    where.z +=    OffsetZ;  // use the ground position + an offset 
+        
+    if (LSLEditor)
+        where  = <128,128,31 + llFrand(1)>; // force center of sim when editing
+   
+   // if attached the height will be too high by 1/2 the agent size
+    if (llGetAttached()) {
+        vector size = llGetAgentSize(llGetOwner());   
+        float Z = size.z;
+        where.z -= Z/2;  
+    }
+   
+    // DEBUG("Pos= " + (string) where);
+    return (string) where;
+}
+
+// setup a menu with a timer for timeouts, called by all make*()
+menu()
+{
+    llListenRemove(iHandle);
+    iChannel = llCeil(llFrand(100000) + 20000);
+    iHandle = llListen(iChannel,"","","");
+    TimerEvent(30.0);
+    MENU = TRUE;
+}
+
+// make a text box
+makeText(string Param)
+{ 
+    menu();
+    llTextBox(kUserKey, Param, iChannel);
+}
+
+// top level menu
+makeMainMenu()
+{
+    menu();
+    list buttons = ["Appearance","Recording","Save","Help","-","Erase RAM", priPub,relAbs,"-","Stop NPC",mSensor,"Start NPC"];
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Records",buttons,iChannel);
+}
+
+
+// Rev 1.4
+// top level menu for non group/ non owners
+makeUserMenu()
+{
+    if (!allowUsers) return;
+    
+    menu();
+    list buttons = ["Start NPC","Stop NPC"];
+    llDialog(kUserKey,"Choose",buttons,iChannel);
+}
+
+
+
+// programmable menu for @commands
+makeMenu(list buttons)
+{
+    menu();
+    llDialog(kUserKey,(string) llGetListLength(lCommands) + " Record",buttons,iChannel);
+}
+
+
+// make one or two text boxes with prompts
+Text(string cmd, string p1, string p2)
+{
+    sCommand = cmd;
+     sParam2 = "";
+    if (llStringLength(p2))
+        sParam2 = p2;
+
+    makeText(p1);
+} 
+
+// Set the Avatar Present flag - if sensors are off and we are force run, there will be one present.
+ProcessSensor()
+{
+    integer SensorOn;
+    if ("on" == KeyValueGet("se"))
+    {
+        SensorOn = TRUE;        // we need to scan for avatars
+    } else {
+        SensorOn = FALSE;        // we need to scan for avatars
+    }
+    DEBUG("Sensor:" + (string) SensorOn);
+    
+    integer n = SenseAvatar();
+    
+    DEBUG("Avatars:" + (string) n);
+    if (SensorOn && n)
+        avatarPresent = TRUE;   // someone is here and we need to tell the system to run
+    else if (SensorOn && !n)
+        avatarPresent = FALSE;  // someone is not here and we need to tell the system to stop
+    else {       // sensor is off, lete see if there is a NPC. If so, we are ON 
+       // DEBUG("NPCEnabled:" + (string) NPCEnabled);
+       
+        if (NPCEnabled)
+            avatarPresent = TRUE;  
+        else
+            avatarPresent = FALSE;   
+    }
+    
+    //  start up from when when no one is near
+    if (avatarPresent && STATE == NobodyHome)
+        STATE = NULL;
+    
+    DEBUG("Avatar Present: " + (string) avatarPresent);
+}
+
+vector CirclePoint(float radius) {
+    float x = llFrand(radius *2) - radius;        // +/- radius, randomized
+    float y = llFrand(radius *2) - radius;        // +/- radius, randomized
+    return <x, y, 0>;        // so this should always happen
+}
+
+string KeyValueGet(string var) {
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k != var) jump continue;
+        //DEBUG("got " + var + " = " +  llList2String(data, 1));
+        return llList2String(data, 1);
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    return "";
+} 
+
+KeyValueSet(string var, string val) {
+
+    //DEBUG("set " + var + " = " + val);
+    list dVars = llParseString2List(llGetObjectDesc(), ["&"], []);
+    if(llGetListLength(dVars) == 0)
+    {
+        llSetObjectDesc(var + "=" + val);
+        return;
+    }
+    list result = [];
+    do {
+        list data = llParseString2List(llList2String(dVars, 0), ["="], []);
+        string k = llList2String(data, 0);
+        if(k == "") jump continue;
+        if(k == var && val == "") jump continue;
+        if(k == var) {
+            result += k + "=" + val;
+            val = "";
+            jump continue;
+        }
+        string v = llList2String(data, 1);
+        if(v == "") jump continue;
+        result += k + "=" + v;
+        @continue;
+        dVars = llDeleteSubList(dVars, 0, 0);
+    } while(llGetListLength(dVars));
+    if(val != "") result += var + "=" + val;
+    llSetObjectDesc(llDumpList2String(result, "&"));
+}
+
+
+// clear RAM
+Clr() {
+
+    lCommands = [];
+    llOwnerSay("RAM Memory cleared. Notecards, if any, are not modified.");
+    makeMainMenu();
+}
+
+integer checkNoteCards()
+{
+    // Check that they have saved an Appeaance and Path notecard
+    integer num = llGetInventoryNumber(INVENTORY_NOTECARD);    // how many notecards overall
+    
+    integer i;
+    integer count;
+    for (; i < num; i++){
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Notecard)
+            count++;
+        if (llGetInventoryName(INVENTORY_NOTECARD,i) == Appearance)
+            count++;
+    }
+    DEBUG("Checked " + (string) count + " Notecards");
+    // if we have both, run the NPC
+    return count;
+}
+
+Update(string SName) {
+         
+    // delete all NPC* scripts except myself
+    integer i;
+    integer j = llGetInventoryNumber(INVENTORY_SCRIPT);
+    for (i = 0; i < j; i++) {
+        string targetName = llGetInventoryName(INVENTORY_SCRIPT,i);
+        string match = llGetSubString(targetName,0,2);
+        
+        if (match == SName && llGetScriptName() != targetName){
+                llOwnerSay("Upgrading " + targetName);
+            if (! LSLEditor){        // lets not kill the editor
+                llRemoveInventory(targetName);
+            }
+        }
+    }
+}
+
+// Get all default saved params from the Description
+GetSwitches()
+{
+         string rA = KeyValueGet("co"); // Get the remembered menu setting for Abs Vs Relative
+        if (rA == "A")
+            relAbs = "Absolute";
+        else  if (rA == "R")
+            relAbs = "Relative";
+        else
+            relAbs = "Absolute";
+
+            
+        // reenable NPC if sensor is on.
+        if ("on" == KeyValueGet("se"))
+        {
+            NPCEnabled = TRUE;
+            mSensor  = "Sense is On";
+            ProcessSensor();       // fake 1 avatar to get it rezzed
+        } else {
+            mSensor  = "Sense is Off";
+        }
+    }
+
+
+SaveKey(key akey)
+{
+    DEBUG("Saving Key of " + (string) akey);
+    KeyValueSet("key", akey);
+    if (akey !=  (key) KeyValueGet("key") )
+    {
+        DEBUG("Fatal error, cannot save key");
+    }
+    gNpcKey = akey;
+}
+
+
+key NPCKey()
+{
+    key akey = gNpcKey;   // from cached copy
+    // gNpcKey saves a lot of CPU processing by caching the key, if blank we get it from the description
+    if (gNpcKey == NULL_KEY)
+    {
+        //DEBUG("Get DKey");
+        akey = KeyValueGet("key");    // from Description of the prim
+    }
+   // DEBUG("NPC KEY:" + (string) akey);   
+    return  akey;
+}
+
+
+/////////////////// CODE BEGINS //////////////////
+
+
+default
+{
+    changed(integer change) {
+        if(change & CHANGED_REGION_START) {
+            llResetScript();
+        }
+    }
+    
+    on_rez(integer start_param)
+    {
+        llResetScript();
+    }
+
+    state_entry() {
+        
+        llSetText("",<1,1,1>,1.0);  // clr all hovertext- we may not be using it.
+        DoDelete(); // kill any NPC that is out running
+        Update("NPC"); // If dragged and ropped into a prim with any script named "NPC...", this will replace it.
+        GetSwitches(); // Get all default saved params from the Description
+
+        // 4.1 allow listeners to send us commands
+        if (allowListener)
+            llListen(link_Channel,"","","");
+        TimerEvent(TIMER);
+    } 
+
+
+    touch_start(integer n) 
+    {           // if touched, make a menu
+    
+        if (checkPerms()) {
+            if (RecordPath == STATE) {
+                makeMenu(lAtButtons); 
+            }   else {
+                makeMainMenu();
+            }
+        } else {
+            makeUserMenu();
+        }
+    }
+
+    // menu listener
+    listen(integer iChannel, string name, key id, string message) {
+
+        // process @commands that come in via the listener
+        if (iChannel == link_Channel)
+        {
+            ParseMsg(message);
+            return;
+        }
+        
+        if (MENU) {
+            llListenRemove(iHandle);
+            MENU = 0;       // menu is off
+            iHandle = 0;
+        }
+        
+        if (message == "Stop NPC")
+        {
+            lNpcCommandList = []; // force reload of notecard
+            NPCEnabled = FALSE;
+            if (NPCKey() != NULL_KEY){
+                Kill(sNPCName);
+            } else {
+                bNPC_STOP = TRUE;
+                makeText("Enter name of an NPC to stop");
+            }
+        }
+        else if (message == "Menu" ) {
+            makeMainMenu();
+        }
+        else if (message == "Erase RAM"){
+            Clr();
+        }
+        else if (message == "Relative"){
+            relAbs = "Absolute";
+            KeyValueSet("co","A");   // remember coordinates = A
+            Clr();
+        }
+        else if (message == "Absolute"){
+            relAbs = "Relative";
+            KeyValueSet("co","R");   // remember coordinates = R
+            Clr();
+        }
+        else if (message == "Recording"){
+            DoMenuForCommands();        // show them the recording menu
+        }
+        else if (message == "Owner Only") {
+            priPub = "Group";
+            KeyValueSet("pr","1");
+
+            llOwnerSay("Group members have control");
+            makeMainMenu();
+        }
+        else if (message == "Group") {
+            priPub = "Owner Only";
+            KeyValueSet("pr","0");
+            llOwnerSay("Only you have control");
+            makeMainMenu();
+        }
+        else if (message == "Sense is On") {
+            mSensor ="Sense is Off";
+            KeyValueSet("se", "off");
+            llOwnerSay(mSensor);
+            makeMainMenu();
+        }
+        else if (message == "Sense is Off") {
+            mSensor ="Sense is On";
+            llOwnerSay(mSensor);
+            KeyValueSet("se", "on");
+            
+            NPCEnabled = TRUE;
+            
+            integer count = checkNoteCards();
+            if (count >= 2)  {
+                DEBUG("Notecards ok, DoProcessNPCLine");
+                DoProcessNPCLine();
+                return;
+            }
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording and/or appearance, so you cannot start a NPC");
+            makeMainMenu();
+        }
+        else if (message == "Appearance")  {
+            llRemoveInventory(Appearance);            // delete the notecard
+            osAgentSaveAppearance(kUserKey,Appearance);    // make the ntecard 
+            llOwnerSay("Your outfit has been saved");
+            makeMainMenu();
+        }
+        else if (message == "Save") {
+            if (llGetListLength(lCommands) == 0) {
+                llOwnerSay("Nothing recorded, you need to make a recording first");
+                makeMainMenu();
+                return;
+            }
+            DoSave();
+        }
+        else if (message == "Help"){
+            llLoadURL(kUserKey,"Click to view help","http://www.outworldz.com/opensim/posts/NPC/");
+            makeMainMenu();
+        }
+        else if (message == "Start NPC")    {
+            integer count = checkNoteCards();
+
+            NPCEnabled = TRUE;
+
+            if (LSLEditor) {
+                DoProcessNPCLine();
+                return;
+            }
+            
+            if (count >= 2) {
+                DEBUG("Notecards approved , calling DoProcessNPCLine");
+                SetStop(FALSE); // Let's run the notecard
+                DoProcessNPCLine();
+                return;
+            }
+
+            llOwnerSay("You have not saved a recording or maybe an appearance, so we cannot start a NPC");
+      
+        }
+        else if (bNPC_STOP){
+            bNPC_STOP = FALSE;
+            Kill(message);
+        }
+        else if (message == ">>"){
+            makeMenu(lMenu2);
+        }
+        else if (message == ">>>"){
+            makeMenu(lMenu3);
+        }
+        else if (message == "<<") {
+            makeMenu(lAtButtons);
+        }
+        else if (message == "<<<") {
+            makeMenu(lMenu2);
+        }
+        else if (message == "@comment"){
+            Text("# ","Enter a comment","");
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@run"){
+            lCommands += "@run=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@fly"){
+            lCommands += "@fly=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@land"){
+            lCommands += "@land=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@walk") {
+            lCommands += "@walk=" + Pos() + "\n";
+            llOwnerSay("Recorded position: " + Pos());
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@stop"){
+            lCommands += "@stop"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@sound"){
+            Text("@sound=","Enter a sound name or UUID to trigger","");
+        }
+        else if (message == "@randsound"){
+            lCommands += "@randsound"+  "\n";
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@say") {
+            Text("@say=","Enter what the NPC will say","");
+        }
+        else if (message == "@whisper"){
+            Text("@whisper=","Enter what the NPC will whisper","");
+        }
+        else if (message == "@shout"){
+            Text("@shout=","Enter what the NPC will shout","");
+        }
+        else if (message == "@wander") {
+            Text("@wander=","Enter radius to wander","Enter number of wanders");
+        }
+        else if (message == "@pause") {
+            Text("@pause=","Enter time to pause","");
+        }
+        else if (message == "@rotate") {
+            Text("@rotate=","Enter degrees to rotate","");
+        }
+        else if (message == "@sit"){
+            Text("@sit=","Enter name of object to sit on","");
+        }
+        else if (message == "@teleport"){
+            lCommands += "@teleport=" + Pos() + "\n";
+            llOwnerSay("teleport to position: " + Pos());
+            makeMenu(lMenu3);
+        }
+        else if (message == "@touch"){
+            Text("@touch=","Enter name of object to touch","");
+        }
+        else if (message == "@cmd"){
+            Text("@cmd=","Enter cjhannel to speak on","Enter text to speak");
+        }
+        else if (message == "@stand"){
+            lCommands += "@stand\n";
+            llOwnerSay("Stand Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (message == "@animate"){
+            Text("@animate=","Enter animation name to play","Enter time to play the animation");
+        }
+        else if (message == "@attach"){
+            Text("@animate=","Enter inventory name to attach","Enter number of the attachment point (1-40)");
+        }
+         else if (message == "@speed"){
+            Text("@speed=","Enter a speed for the NPC, 1=100% normal speed, 0.5=50% speed","");
+        }
+               
+
+        // Save NPC name
+        else if (MakeNotecard == STATE) {
+            sNPCName = message; // in case we need to kill it.
+            
+            vector  vDest = (vector)  Pos();
+
+            if (relAbs == "Relative")
+            {
+                vDest  -= llGetPos();    // just an offset for relative
+            }
+            sNotecard = "@spawn=" + message + "|" +  (string) vDest  + "\n";
+            integer i;
+            integer j = llGetListLength(lCommands);
+            for (; i < j; i++){
+                // get the command to save to the notecard
+                string line = llList2String(lCommands,i);
+                if (relAbs == "Absolute") {
+                    sNotecard += line;    // add the un-modified string to the notecard
+                } else {
+                        // since we have to record absolute coords since we do not know where the box goes until they press Save,
+                        // we process the absolute to relative conversion for walks here
+                        list parts = llParseString2List(line,["="],[]); //get the @command
+
+                    if (llList2String(parts,0) == "@walk") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@walk=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@fly") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@fly=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@run") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@run=" + (string) vec + "\n";
+                    }
+                    else if (llList2String(parts,0) == "@land") {
+                        vector vec = (vector) llList2String(parts,1) - llGetPos();
+                        sNotecard += "@land=" + (string) vec + "\n";
+                    }
+                    else {
+                        sNotecard += line;    // add the un-modified string to the notecard
+                    }
+                }
+            }
+            llRemoveInventory(Notecard);        // delete the old notecard
+            osMakeNotecard(Notecard,sNotecard); // Makes the notecard.
+            llSay(0,sNotecard);
+            llOwnerSay("Commands notecard has been written");
+            STATE = NULL;
+        } // MakeNotecard
+
+        else  if (! llStringLength(sParam2)) {
+            lCommands +=  sCommand + message + "\n";
+            llOwnerSay("Recorded");
+            makeMenu(lAtButtons);
+        }
+        else if (llStringLength(sParam2)){
+            sCommand = sCommand + message + "|";
+            llOwnerSay("Recorded");
+            makeText(sParam2);
+            sParam2 = "";
+        }
+
+    }
+
+
+
+    timer(){
+       // DEBUG("tick");
+        
+        // if llDialog is up, kill the listener for the dialog box.
+        if (iHandle) {
+            llOwnerSay("Menu timed out");
+            llListenRemove(iHandle);
+            iHandle = 0;
+            return;             // ^^^^^^^^^^^^^^^^^^^^^^^
+        }
+        // if NoBodyHome, we are sensing for an avatar
+        else if (NobodyHome == STATE) {
+            ProcessSensor();
+            return;
+        }
+        // if we are spawning, we need time to rez the NPC, then start processing NPC Commands.
+        else if (Spawning == STATE) {
+            STATE = NULL;
+            TimerEvent(TIMER);
+        }
+        // We end aniamtions with a timer
+        else if (Animate == STATE){
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+        }
+        
+        else if (Walking == STATE) {
+            if (--iWaitCounter) {
+                DEBUG("still walking...");
+                if (llVecDist(osNpcGetPos(NPCKey()), newDest) > MAXDIST)  {
+                    return;
+                }
+            }
+
+            DEBUG("At Destination: " + (string) newDest);
+            
+            // walk, fly, run, land
+            if (walkstate == 1) {
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 2)  {
+                    // nothing
+                } else if (walkstate == 3) {
+                     NPCAnimate(STAND);
+                     NPCWalkOption = OS_NPC_NO_FLY;
+            } else if (walkstate == 4) {
+                llShout(FLIGHT,"landing");
+                NPCAnimate(STAND);
+                NPCWalkOption = OS_NPC_NO_FLY;
+            }
+        }
+        // Wandering timer 
+        else if (Wander == STATE) {
+            if (--iWaitCounter) {          // wait 60 seconds to get to a destination.
+                if (llVecDist(osNpcGetPos(NPCKey()), vWanderPos) > MAXDIST)
+                    return;
+            }
+
+            // see if wander counter == 0, if so, stop walking, go to stand and process next line
+            if(RAMwc == 0) {
+                NPCAnimate(STAND);
+                DEBUG("Wander ended, calling DoProcessNPCLine");
+                STATE = NULL;
+                return;
+            }
+            // one less time to wander around
+            RAMwc--;
+            NPCAnimate(STAND);
+            TimerEvent(TIMER);
+            StateWanderhold();
+            return;
+        }
+        // Wandering requires us to re-wander when we reach a destination
+        else if (WanderHold == STATE) {
+            StateWander();
+        }
+        else if (DoProcess == STATE) {
+            TimerEvent(QUICK);
+        }
+
+        STATE = NULL;
+
+        // We always process a NPC line at end of timer.
+        DEBUG("Tick end, calling DoProcessNPCLine");
+        DoProcessNPCLine();
+    }
+
+    // sensors are used for sitting on prims
+    // Neo Cortex: added different states to trigger sit or touch
+    sensor(integer num) {
+        if (Sit == STATE ) {
+            osNpcSit(NPCKey(), llDetectedKey(0), OS_NPC_SIT_NOW);
+            DEBUG("Seated, calling DoProcessNPCLine");
+            
+            STATE = 0;
+        } else if (Touch == STATE) {
+            osNpcTouch(NPCKey(), llDetectedKey(0), LINK_THIS);
+            DEBUG("Touched, calling DoProcessNPCLine");
+            STATE = 0;
+        }
+        DoProcessNPCLine();
+    }
+    no_sensor(){
+        DEBUG ("no target prim located, calling DoProcessNPCLine");
+        DoProcessNPCLine();
+        STATE = NULL;
+    }
+
+    
+    link_message(integer sender, integer num, string str, key id){
+        if (num == 0)
+            ParseMsg(str);
+    }
+        
+}
+
+// __ END__
+
+
+
+
diff --git a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Test Object/Collision test.lsl b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Test Object/Collision test.lsl
index 6802ef61..59aaac7f 100644
--- a/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Test Object/Collision test.lsl	
+++ b/All In One NPC Recorder and Player/All In One NPC Recorder and Player/Test Object/Collision test.lsl	
@@ -4,20 +4,22 @@
 // :AUTHOR:Ferd Frederix
 // :KEYWORDS:
 // :CREATED:2015-07-17 13:15:49
-// :EDITED:2015-07-20  00:23:28
+// :EDITED:2015-09-23  12:06:52
 // :ID:27
 // :NUM:1808
-// :REV:2
+// :REV:3
 // :WORLD:Second Life
 // :DESCRIPTION:
 // Sample collision script for NPC animator
 // :CODE:
+// rev 3: added on_rez()  and STATUS_PHANTOM to state_entry - otherwise reset on Linux boxes did no collide any more.
 default
 {
     state_entry()
     {
-        llSetText("",<1,1,1>,1.0);
+        llSetStatus(STATUS_PHANTOM,FALSE);
         llVolumeDetect(FALSE);
+        llSleep(0.1);
         llVolumeDetect(TRUE);
     }
     
@@ -38,4 +40,8 @@ default
             llResetScript();
         }
     }
+    on_rez(integer p)
+    {
+        llResetScript();
+    }
 }
diff --git a/Endless Loop Mover/Endless Loop Mover/Object/10.lsl.bak b/Endless Loop Mover/Endless Loop Mover/Object/10.lsl.bak
deleted file mode 100644
index eef77605..00000000
--- a/Endless Loop Mover/Endless Loop Mover/Object/10.lsl.bak	
+++ /dev/null
@@ -1,86 +0,0 @@
-// :SHOW:
-// :CATEGORY:Tour
-// :NAME:Endless Loop Mover
-// :AUTHOR:Ferd Frederix
-// :KEYWORDS: Movement, Walking, Teleporting
-// :CREATED:2013-09-06
-// :ID:1084
-// :NUM:1817
-// :REV:1
-// :WORLD:OpenSim
-// :DESCRIPTION:
-// Rez this from inventory to make a route.  Use the recorder to gather the route.
-// :CODE:
-
-// name this prim '10' without the double quotes.   You will use the prim #10 to establish a path of waypoints to follow.
-// Rez a prim ad name it '10', or any other number without the double quotes, at a spot at the beginning of the ride.
-// Mark the prim as 'Phantom'. The final gadget will pass through the #10 prim on its route.
-// Put the following script in it. Take a copy of that prim back into inventory.
-// Left-click and drag from inventory the '10' prim at a spot nearby, in the direction you want the object to travel.
-// If you use shift-copy, move it slightly, then grab the one you r left behind!
-//  The prim you shift copy will be in reverse order, as the original #10 moves, and leaves behind a copy.
-//  You canm also just drag out a new one each time you need another waypoint.
-
-// Each prim will rename itself to the largest number found +10, about 5 seconds after it rezzes.
-// Since you started with prim #10, the second prim will rename itself as #20, the next will be 30, and so on.
-// When finsihes, click the tour object
-
-
-integer wanted = 0;
-integer debugger = 1;
-
-list prims;
-
-
-debug(string message)
-{
-    if (debugger)
-        llOwnerSay(message);
-}
-
-default
-{
-    state_entry()
-    {
-        llListen(300,"","","");
-        wanted++;
-        llRegionSay(300,"number");
-        llSetTimerEvent(5.0);   // 5 seconds to hear from all prims
-        llOwnerSay("Setting coordinates");
-    }
-
-    listen(integer channel,string name, key id, string message)
-    {
-        if (message == "die")
-            llDie();
-        
-        else if (message =="where")
-            llRegionSay(300,llGetObjectName() + "|" + (string) llGetPos() + "|" + (string)  llGetRot() + "|" + llGetObjectDesc());
-            
-        else if (message =="number")
-            llRegionSay(300,llGetObjectName());
-                        
-        else if (wanted)
-        {
-            prims += (integer) message; // add to memory list                
-        }
-        
-            
-    }
-    
-    timer()
-    {
-        wanted = 0;
-        prims = llListSort(prims,1,0);  // sort descending
-        integer num = (integer) llList2Integer(prims,0); // get highest number
-        llSetObjectName((string) (num + 10));  // leave room for more prims to be added
-        llOwnerSay("Name set to " + llGetObjectName() + ".  You can add text to be spoken when the tour reaches this location by adding some text to the description of this object.");
-
-        llSetTimerEvent(0);
-    }
-
-    on_rez(integer p)
-    {
-        llResetScript();
-    }
-}
\ No newline at end of file
diff --git a/Endless Loop Mover/Endless Loop Mover/Object/ReadMe.txt.bak b/Endless Loop Mover/Endless Loop Mover/Object/ReadMe.txt.bak
deleted file mode 100644
index 84ae7932..00000000
--- a/Endless Loop Mover/Endless Loop Mover/Object/ReadMe.txt.bak	
+++ /dev/null
@@ -1,51 +0,0 @@
-// :SHOW:
-// :CATEGORY:Tour
-// :NAME:Endless Loop Mover
-// :AUTHOR:Ferd Frederix
-// :KEYWORDS: Movement, Walking, Teleporting
-// :CREATED:2013-09-06
-// :ID:1084
-// :REV:1
-// :WORLD:OpenSim
-// :DESCRIPTION:
-// Help notecard for the walker
-// :CODE:
-
-// Open Source CC-BY-NC by Ferd Frederix
-================
-
-The walker can be set to auto start in an endless loop(default), or it can be set to wait for a NPC to sit on it.  It then unsits the NPC at the end of the route, and returns to the start at high speed.  
-
-The default route I set is a square in mid-air.   Rez the prim, it should start moving. Sit on it, you should start walking.  In production, make the box invsiible for a NPC to appear to walk at any orientation.
-
-
-
-'10' Box
-
-Name this prim '10' without the double quotes.   You will use the prim #10 to establish a path of waypoints to follow. It can actually be named any INTEGER such as a 0 ot the number 310,  but 10 is the standard start point.
-
-Rez this at the beginning of the ride.
-
-The final gadget will start at the #10 prim location and rotation/
-
-Shift-copy the 10 prim,  move it slightly, then GRAB THE ONE YOU LEFT BEHIND and move it to the next place.  The prim you shift-copy will be #10, the one left behind will become #20.  The original #10 moves, and leaves behind a copy.  This copy will automatically make it itself the next larger number.   
-
-You can also just drag out a new one each time you need another waypoint.
-
-Each prim will rename itself to the largest number found ANYWHERE in the sim,  plus 10, about 5 seconds after it rezzes.  Since you started with prim #10, the second prim will rename itself as #20, the next will be 30, and so on.
-
-When finished, click the tour object.
-
-If you make a mistake, and need to fix it, you can move the prims around. You can renumber them.  You can add more prims in between 10 and 20, just renumber them 11, 12, 13, or whatever.
-
-==============================
-Walker Prim - rez the #10 prims, and then touch the tour prim to record a route
-
-The route prim will follow the route. Fix any issues by replacing, removing or adding the numbered prims, and touch to save
-
-When finished, delete the Recorder script that is inside the walker as it is not needed.
-
-The walker can be set to auto start in an endless loop(default), or it can be set to wait for a NPC to sit on it.  It then unsits the NPC at the end of the route, and returns to the start at high speed.
-
-. 
-
diff --git a/Endless Loop Mover/Endless Loop Mover/Object/Route.bak b/Endless Loop Mover/Endless Loop Mover/Object/Route.bak
deleted file mode 100644
index 19e4d0c5..00000000
--- a/Endless Loop Mover/Endless Loop Mover/Object/Route.bak	
+++ /dev/null
@@ -1,21 +0,0 @@
-// :SHOW:
-// :CATEGORY:Tour
-// :NAME:Endless Loop Mover
-// :AUTHOR:Ferd Frederix
-// :KEYWORDS: Movement, Walking, Teleporting
-// :CREATED:2013-09-06
-// :ID:1084
-// :REV:1
-// :WORLD:OpenSim
-// :DESCRIPTION:
-// Sample route card to walk in a vertical square
-// :CODE:
-
-130|<133.538467,130.615784,23.190590>|<0.000000,0.026177,0.000000,0.999657>|
-140|<133.779236,130.620636,24.137348>|<0.000000,-0.719340,0.000000,0.694658>|
-150|<133.779236,130.620636,26.521872>|<0.000000,-0.719340,0.000000,0.694658>|
-160|<133.310989,130.620636,27.378088>|<0.000000,-0.999962,0.000000,0.008728>|
-170|<131.158035,130.620636,27.165934>|<0.000000,-0.999962,0.000000,0.008728>|
-180|<130.844910,130.620636,26.573608>|<0.000000,0.700910,0.000000,0.713250>|
-210|<130.844910,130.620636,24.083681>|<0.006117,0.700884,-0.006224,0.713222>|
-220|<131.174484,130.620636,23.452608>|<0.008725,-0.034897,0.000152,0.999353>|
\ No newline at end of file
diff --git a/Endless Loop Mover/Endless Loop Mover/Object/recorder.lsl.bak b/Endless Loop Mover/Endless Loop Mover/Object/recorder.lsl.bak
deleted file mode 100644
index 35d6ac03..00000000
--- a/Endless Loop Mover/Endless Loop Mover/Object/recorder.lsl.bak	
+++ /dev/null
@@ -1,122 +0,0 @@
-// :SHOW:
-// :CATEGORY:Telepad
-// :NAME:Endless Loop Mover
-// :AUTHOR:Ferd Frederix
-// :KEYWORDS:
-// :CREATED:2015-08-05 09:56:03
-// :ID:1084
-// :NUM:1818
-// :REV:1
-// :WORLD:Opensim
-// :DESCRIPTION:
-// Route Recorder Script - touch to make a route
-// :CODE:
-// Open Source CC-BY-NC
-
-// Recorder script - put this in the touring prim, rez thre #10 prims, and then touch the tour prim to record a route
-// the route prim will follow the route. Fix any issues by replacing, removing or adding the numbered prims, and touch to save
-// When finished, delete this script as it is not needed.
-
-integer debugger = FALSE;
-list prims;
-
-debug(string message)
-{
-    if (debugger)
-        llOwnerSay(message);
-}
-
-
-
-string left(string src, string divider) {
-    integer index = llSubStringIndex( src, divider );
-    if(~index)
-        return llDeleteSubString( src, index , -1);
-    return src;
-}
-
-string right(string src, string divider) {
-    integer index = llSubStringIndex( src, divider );
-    if(~index)
-        return llDeleteSubString( src, 0, index + llStringLength(divider) - 1);
-    return src;
-}
-
-
-list lines;
-
-default
-{
-    state_entry()
-    {
-        llSetText("Click after setting up all tour prims.  \nShout on channel '/300 die' to clear all prims", <1.0, 1.0, 1.0>, 2.0);
-        
-    }
-
-    touch_start(integer n)
-    {
-        if (llDetectedKey(0) == llGetOwner()) {
-            llOwnerSay("Looking for Route Prims, please wait");
-            prims = [];
-
-            lines = [];
-
-            llListen(300,"","","");
-            llRegionSay(300,"where");
-        }    
-    }
-
-    listen(integer channel,string name, key id, string message)
-    {
-        debug(llGetObjectName() + " heard  " + message);
-        list parts = llParseString2List(message,["|"],[]);
-        
-        integer l = (integer) llList2String(parts,0);
-        vector  p = (vector) llList2String(parts,1);
-        rotation r = (rotation) llList2String(parts,2);
-        string text = llList2String(parts,3);
-        
-        integer  isthere = llListFindList(prims,[(integer) l]);
-        
-        if (isthere > -1)
-        {
-            llOwnerSay("Error, there are two prims named " + l + ".  Please make sure each prim is uniquely numbered from - to N in sequence from the start prim to the finish prim. Gaps in the sequence are allowed.");
-        }
-        prims += (integer) l;
-        prims += (vector) p;
-        prims += (rotation) r;
-        prims += text;
-        llSetTimerEvent(5.0);
-    
-    }
-    
-    timer()
-    {
-        llSetTimerEvent(0);
-        integer i = 0;
-        
-        prims = llListSort(prims,4,1);
-        
-        for (i = 0; i < llGetListLength(prims); i+=4)
-        {
-            integer primnum = llList2Integer(prims,i);
-            vector loc = llList2Vector(prims,i+1);
-            rotation rot = llList2Rot(prims,i+2);
-            string text = llList2String(prims,i+3);
-            lines += [(string) primnum + "|" + (string) loc + "|" + (string) rot + "|" + text];
- 
-        }
-        if (llGetInventoryType("Route") == INVENTORY_NOTECARD)
-            llRemoveInventory("Route");
-            
-        osMakeNotecard("Route",lines);  
-        llOwnerSay("Route updated");  
-        llResetOtherScript("Walker");    
-        llSetText("",<1,1,1>,1.0);                        
-    }
-
-    on_rez(integer p)
-    {
-        llResetScript();
-    }
-}
\ No newline at end of file
diff --git a/Endless Loop Mover/Endless Loop Mover/Object/walker.lsl.bak b/Endless Loop Mover/Endless Loop Mover/Object/walker.lsl.bak
deleted file mode 100644
index a50639fa..00000000
--- a/Endless Loop Mover/Endless Loop Mover/Object/walker.lsl.bak	
+++ /dev/null
@@ -1,264 +0,0 @@
-// :SHOW:
-// :CATEGORY:Telepad
-// :NAME:Endless Loop Mover
-// :AUTHOR:Ferd Frederix
-// :KEYWORDS:
-// :CREATED:2015-08-05 09:54:56
-// :ID:1084
-// :NUM:1816
-// :REV:1
-// :WORLD:OpenSim
-// :DESCRIPTION:
-// Sit on this prim, it will move you to a destination and unseat you, optionally repeat forever.
-// :CODE:
-// Open Source CC-BY-NC
-// Please keep open source Open!
-
-
-integer _debug = FALSE; // print in chats what i s happening.
-integer Endless = TRUE;
-vector  OFFSET = <0,0,0>; // if you want the tour to ride hiogher or lower or to one side...
-
-float SPEED = 1.0; // speed of vehicle  in meters per second
-
-// Sit for the NPC
-vector TARGET = <0,0,.7>; 
-vector ROT = <0, 0, 0>; 
-key av;
-
-float INTERVAL = 0.5;   // how often we check
-float TOLERANCE = 1;   // how close to get
- 
-vector startPos;    
-list lCoordinate;
-list lRotation ;
-list lText;
-
-string NOTECARD = "Route";        // the notecard for configuring
-
-integer count = 0;
-    
-vector TargetLocation;
-rotation TargetRotation;
-   
-     
-Goto(float speed)
-{
-    if (_debug) 
-        llOwnerSay("Looking at Target Location = " + (string) TargetLocation);
-
-    vector ownPosition = llGetPos();    
-    float dist = llVecDist(ownPosition, TargetLocation);
-    
-    float rate = dist / speed;
-        
-    rotation ownRotation = llGetRot();
- 
-    llSetKeyframedMotion(
-            [(TargetLocation - ownPosition) + <0.0, 0.0, -.5> * TargetRotation,
-            NormRot(TargetRotation/ownRotation), rate],
-            []);
-     
-}
-
-rotation NormRot(rotation Q)
-{
-    float MagQ = llSqrt(Q.x*Q.x + Q.y*Q.y +Q.z*Q.z + Q.s*Q.s);
- 
-    return
-        <Q.x/MagQ, Q.y/MagQ, Q.z/MagQ, Q.s/MagQ>;
-}
-
-integer locationLength;
-
- 
-default
-{
-    on_rez(integer param)
-    {
-        llResetScript();
-    }
-    state_entry() 
-    {       
-        if (_debug) 
-            llOwnerSay("Reset");
-
-     
-        rotation rot     = llEuler2Rot(ROT * DEG_TO_RAD);     // convert the degrees to radians, then convert that vector into a rotation, rot30x 
-        llSitTarget(TARGET, rot); // where they sit
-        
-        // read the notecard
-        string data = osGetNotecard(NOTECARD);
-        list lLine = llParseString2List(data, ["\n"], []);
-        integer i;
-        integer j = llGetListLength(lLine);
-        for (i = 0; i < j; i++)
-        {
-            string aLine = llList2String(lLine,i);
-            
-            list iList =  llParseString2List(aLine, ["|"], []);
-            if (_debug )    llOwnerSay("Line = " + llDumpList2String(iList,":")); 
-
-            vector TempLocation = (vector) llList2Vector(iList,1); 
-            if (TempLocation != ZERO_VECTOR)
-            {
-                rotation Rot = (rotation) llList2String(iList,2);
-                string text = llList2String(iList,3);
-    
-                if (_debug) llOwnerSay((string)TempLocation);
-                    
-                TempLocation += OFFSET;
-                    
-                lCoordinate += [TempLocation];
-                    
-                lRotation +=  [Rot];
-                lText += [text];
-                    
-                locationLength = (llGetListLength(lCoordinate));
-            } 
-        }
-        state paused;
-    }
-
-}
-
-state paused {
-    
-    state_entry()
-    {   
-        if (_debug) llOwnerSay("Pause");
-
-        if (!Endless) {
-
-            av =  llAvatarOnSitTarget();
-            if (av != NULL_KEY) {
-                llStopAnimation("avatar_walk");
-                llUnSit(av);
-            }
-        }
-                            
-        TargetLocation = llList2Vector(lCoordinate, 0);  // Look at 0th
-        TargetRotation = llList2Rot(lRotation, 0);  // Look at 0th
-        startPos = TargetLocation;  
-        Goto(50);       // go fast
-        
-        count = 0;
-        
-                
-        if (Endless)
-            state moving;
-    }
-    
-    changed(integer change)
-    {
-         if (change & CHANGED_LINK) 
-         { 
-            key av = llAvatarOnSitTarget();
-            if (_debug) llOwnerSay("Sit by " + (string) av);
-            
-            if (av!= NULL_KEY) 
-            {
-                llRequestPermissions(av,PERMISSION_TRIGGER_ANIMATION);
-            }
-        }
-        
-        if (change & CHANGED_REGION_START)
-        {
-            llResetScript();
-        }
-    }   
-    
-    run_time_permissions(integer n)
-    {
-        if (n & PERMISSION_TRIGGER_ANIMATION) {
-            
-            llStopAnimation("sit");
-            llStartAnimation("avatar_walk");
-            state moving;
-        }
-    } 
-}
- 
- 
-state moving
-{
-    state_entry()
-    {
-        if (_debug) llOwnerSay("State Moving entered, is pointing to target " + (string) TargetLocation );
-
-        count ++;
-         
-        TargetLocation = llList2Vector(lCoordinate, count);  // Look at nth
-        TargetRotation = llList2Rot(lRotation, count);  // Look at nth
-        string SpeakThis =  llList2String(lText, count); 
-    
-        if (llStringLength(SpeakThis))
-            llSay(0,SpeakThis);
-            
-        Goto(SPEED);
-        llSetTimerEvent(INTERVAL);
-    }
-    
-    changed(integer change)
-    {
-         if (change & CHANGED_LINK) 
-         { 
-            av = llAvatarOnSitTarget();
-            if (av == NULL_KEY) //evaluated as true if not NULL_KEY or invalid
-            {
-                state paused;
-            } else {
-                llRequestPermissions(av,PERMISSION_TRIGGER_ANIMATION);
-            }
-        }
-        if (change & CHANGED_REGION_START)
-        {
-            llResetScript();
-        }
-        
-        
-    }    
-     
-    run_time_permissions(integer n)
-    {
-        if (n & PERMISSION_TRIGGER_ANIMATION) {
-            
-            llStopAnimation("sit");
-            llStartAnimation("avatar_walk");
-        }
-    } 
-    
-    
-    on_rez(integer param)
-    {
-        llResetScript();
-    }
-    
-    timer()   
-    {
-         if (_debug) llOwnerSay("tick"); 
-        if (llVecMag(llGetPos() - TargetLocation) <= TOLERANCE) {   
-            if (_debug) llOwnerSay("At location: " + (string) llGetPos());
-
-            count ++;
-             
-            if (count >= locationLength) {   
-                 if (_debug) llOwnerSay("EOF"); 
-                state paused;
-                
-            } else {
-                TargetLocation = llList2Vector(lCoordinate, count);  // Look at nth
-                TargetRotation = llList2Rot(lRotation, count);  // Look at nth
-                
-                Goto(SPEED);
-                if (_debug) llOwnerSay("New Target: " + (string) TargetLocation); 
-            }  
-        }
-    }    
-    
-    state_exit()
-    {
-        llSetTimerEvent(0);
-    }  
-}
- 
\ No newline at end of file
diff --git a/Phaze TipJar/Phaze TipJar.sol b/Phaze TipJar/Phaze TipJar.sol
deleted file mode 100644
index 0ab21c06..00000000
--- a/Phaze TipJar/Phaze TipJar.sol	
+++ /dev/null
@@ -1,3 +0,0 @@
-<Solution name="Phaze TipJar">
-	<Project name="Phaze TipJar" path="Phaze TipJar\Phaze TipJar.prj" active="true"/>
-</Solution>
diff --git a/Phaze TipJar/Phaze TipJar/Base/Butterflies.lsl b/Phaze TipJar/Phaze TipJar/Base/Butterflies.lsl
deleted file mode 100644
index 0fb1c03e..00000000
--- a/Phaze TipJar/Phaze TipJar/Base/Butterflies.lsl	
+++ /dev/null
@@ -1,168 +0,0 @@
-// Particle Script 0.4j
-// Created by Ama Omega 3-7-2004
-// Updated by Jopsy Pendragon 5-11-2004
-// For classes/tutorials/tricks, visit the Particle Labratory in Teal
-// Values marked with (*) are defaults.
-
-integer flagger = 0;
-
-// SECTION ONE: APPEARANCE -- These settings affect how each particle LOOKS.
-integer      glow = TRUE;        // TRUE or FALSE(*)
-vector startColor = <1,1,1>;     // RGB color, black<0,0,0> to white<1,1,1>(*)
-vector   endColor = <1,1,1>;     // 
-float  startAlpha = 1.0;         // 0.0 to 1.0(*), lower = more transparent
-float    endAlpha = 1.0;         // 
-vector  startSize = <0.0,0.0,0>; // <0.04,0.04,0>(min) to <10,10,0>(max>, <1,1,0>(*)
-vector    endSize = <0.05,0.05,0>; // (Z part of vector is discarded)  
-string    texture = "44c04376-637b-ef18-9404-723acd0fce91";          // Texture used for particles. Texture must be in prim's inventory.
-
-// SECTION TWO: FLOW -- These settings affect how Many, how Quickly, and for how Long particles are created.
-//     Note, 
-integer count = 1;    // Number of particles created per burst, 1(*) to 4096
-float    rate = 1;   // Delay between bursts of new particles, 0.0 to 60, 0.1(*)
-float     age = 5.0;   // How long each particle lives, 0.1 to 60, 10.0(*)
-float    life = 0.0;   // When to stop creating new particles. never stops if 0.0(*)
-
-// SECTION THREE: PLACEMENT -- Where are new particles created, and what direction are they facing?
-float      radius = 0.15;      // 0.0(default) to 64?  Distance from Emitter where new particles are created.
-float  innerAngle = .1 ;  // "spread", for all ANGLE patterns, 0(default) to PI
-float  outerAngle = .1;        // "tilt", for ANGLE patterns,  0(default) to TWO_PI, can use PI_BY_TWO or PI as well.
-integer   pattern = PSYS_SRC_PATTERN_ANGLE_CONE; // Choose one of the following:
-                // PSYS_SRC_PATTERN_EXPLODE (sends particles in all directions)
-                // PSYS_SRC_PATTERN_DROP  (ignores minSpeed and maxSpeed.  Don't bother with count>1 )
-                // PSYS_SRC_PATTERN_ANGLE_CONE (set innerangle/outerange to make rings/cones of particles)
-                // PSYS_SRC_PATTERN_ANGLE (set innerangle/outerangle to make flat fanshapes of particles)
-vector      omega = <0,0,0>; // How much to rotate the emitter around the <X,Y,Z> axises. <0,0,0>(*)
-                             // Warning, there's no way to RESET the emitter direction once you use Omega!!
-                             // You must attach the script to a new prim to clear the effect of omega.
-
-// SECTION FOUR: MOVEMENT -- How do the particles move once they're created?
-integer followSource = FALSE;   // TRUE or FALSE(*), Particles move as the emitter moves, (TRUE disables radius!)
-integer    followVel = TRUE;    // TRUE or FALSE(*), Particles rotate towards their direction
-integer         wind = FALSE;   // TRUE or FALSE(*), Particles get blown away by wind in the sim
-integer       bounce = FALSE;   // TRUE or FALSE(*), Make particles bounce on Z altitude of emitter
-float       minSpeed = 0.04;     // 0.01 to ? Min speed each particle is spit out at, 1.0(*)
-float       maxSpeed = 0.08;     // 0.01 to ? Max speed each particle is spit out at, 1.0(*)
-vector          push = <0,0,-0.03>; // Continuous force pushed on particles, use small settings for long lived particles
-key           target = "";      // Select a target for particles to arrive at when they die
-                                // can be "self" (emitter), "owner" (you), "" or any prim/persons KEY.
-
-// SECTION FIVE:   Ama's "Create Short Particle Settings List"
-integer  enableoutput = FALSE; // If this is TRUE, clicking on your emitter prim will cause it to speak
-                // very terse "shorthand" version of your particle settings.  You can cut'n'paste
-                // this abbreviated version into a call to llParticleSystem([ ]); in another script.
-                // Pros:  Takes up far less scripting space, letting you focus on the rest of your code.
-                // Cons:  makes tune your settings afterwards rather awkward
-
-// === Don't muck about below this line unless you're comfortable with the LSL scripting language ====
-
-// Script variables
-integer pre = 2;          //Adjust the precision of the generated list.
-integer flags;
-list sys;
-integer type;
-vector tempVector;
-rotation tempRot;
-string tempString;
-integer i;
-
-
-Play()
-{
-        //llOwnerSay("Touched");
-        count = 10;
-        age = 30;  
-        //minSpeed = 1.0;
-        maxSpeed = 0.5 ;
-        endSize = <1.5,1.5,0>; // (Z part of vector is discarded)  
-        float x = llFrand(0.1);
-        float y = llFrand(0.1);
-        push = <x,y,0.03>; // Continuous force pushed on particles
-        wind = TRUE; 
-        updateParticles();
-        llSleep(8);
-        reset();
-        updateParticles();
-}
-
-
-
-reset()
-{
-    
-    count = 1;    // Number of particles created per burst, 1(*) to 4096
-    age = 5.0;   // How long each particle lives, 0.1 to 60, 10.0(*)
-    maxSpeed = 0.08; // speed issued at 
-    endSize = <0.05,0.05,0>; // (Z part of vector is discarded)  
-    push = <0,0,-0.03>; // Continuous force pushed on particles
-    wind = FALSE; 
-
-    
-}
-
-updateParticles()
-{
-    flags = 0;
-    if (target == "owner") target = llGetOwner();
-    if (target == "self") target = llGetKey();
-    if (glow) flags = flags | PSYS_PART_EMISSIVE_MASK;
-    if (bounce) flags = flags | PSYS_PART_BOUNCE_MASK;
-    if (startColor != endColor) flags = flags | PSYS_PART_INTERP_COLOR_MASK;
-    if (startSize != endSize) flags = flags | PSYS_PART_INTERP_SCALE_MASK;
-    if (wind) flags = flags | PSYS_PART_WIND_MASK;
-    if (followSource) flags = flags | PSYS_PART_FOLLOW_SRC_MASK;
-    if (followVel) flags = flags | PSYS_PART_FOLLOW_VELOCITY_MASK;
-    if (target != "") flags = flags | PSYS_PART_TARGET_POS_MASK;
-    sys = [  PSYS_PART_MAX_AGE,age,
-                        PSYS_PART_FLAGS,flags,
-                        PSYS_PART_START_COLOR, startColor,
-                        PSYS_PART_END_COLOR, endColor,
-                        PSYS_PART_START_SCALE,startSize,
-                        PSYS_PART_END_SCALE,endSize, 
-                        PSYS_SRC_PATTERN, pattern,
-                        PSYS_SRC_BURST_RATE,rate,
-                        PSYS_SRC_ACCEL, push,
-                        PSYS_SRC_BURST_PART_COUNT,count,
-                        PSYS_SRC_BURST_RADIUS,radius,
-                        PSYS_SRC_BURST_SPEED_MIN,minSpeed,
-                        PSYS_SRC_BURST_SPEED_MAX,maxSpeed,
-                        PSYS_SRC_TARGET_KEY,target,
-                        PSYS_SRC_INNERANGLE,innerAngle, 
-                        PSYS_SRC_OUTERANGLE,outerAngle,
-                        PSYS_SRC_OMEGA, omega,
-                        PSYS_SRC_MAX_AGE, life,
-                        PSYS_SRC_TEXTURE, texture,
-                        PSYS_PART_START_ALPHA, startAlpha,
-                        PSYS_PART_END_ALPHA, endAlpha
-                            ];
-    float newrate = rate;
-    if (newrate == 0.0) newrate=.01;
-    if ( (age/rate)*count < 4096) llParticleSystem(sys);
-    else {
-        llInstantMessage(llGetOwner(),"Your particle system creates too many concurrent particles.");
-        llInstantMessage(llGetOwner(),"Reduce count or age, or increate rate.");
-        llParticleSystem( [ ] );
-    }
-
-}
-
-default
-{
-    state_entry()
-    {
-        reset();
-        updateParticles();
-    }
-    
-    touch_start(integer total_number)
-    {
-        llSay(0,"Butterfly Tip Jar for 'Phase Demesnes', pay it to pop!");  
-    }
-    
-     link_message(integer sender_num, integer num, string msg, key id) 
-     {
-         Play();
-     }
-
-
-}
\ No newline at end of file
diff --git a/Phaze TipJar/Phaze TipJar/Phaze TipJar.prj b/Phaze TipJar/Phaze TipJar/Phaze TipJar.prj
deleted file mode 100644
index 2582a26b..00000000
--- a/Phaze TipJar/Phaze TipJar/Phaze TipJar.prj	
+++ /dev/null
@@ -1,12 +0,0 @@
-<Project name="Phaze TipJar" guid="5fa87a8e-5e68-4972-ae51-a87b1e11106c">
-	<Object name="Top Half sphere" guid="1299d0f3-3612-47a7-b21c-133cb6e1577d" active="true">
-		<Script name="Script.lsl" guid="7133cfe5-b191-4fbd-ae69-0694b05b539d">
-		</Script>
-		<Sound name="pop" guid="0e0d8c3d-c207-4cb3-9840-b17650dca9e2">
-		</Sound>
-	</Object>
-	<Object name="Base" guid="ac61b009-a6d6-470f-a53f-0dfd1caf34bf">
-		<Script name="Butterflies.lsl" guid="46fb3504-f57f-4595-ad42-4cc7aaa61bb3">
-		</Script>
-	</Object>
-</Project>
diff --git a/Phaze TipJar/Phaze TipJar/Top Half sphere/Script.lsl b/Phaze TipJar/Phaze TipJar/Top Half sphere/Script.lsl
deleted file mode 100644
index 507c0e8f..00000000
--- a/Phaze TipJar/Phaze TipJar/Top Half sphere/Script.lsl	
+++ /dev/null
@@ -1,66 +0,0 @@
-//Keknehv Psaltery Updated Version of DONATION BOX By jean cook, ama omega, and nada epoch Debugged by YadNi Monde.
-// changed into a butterfly dispenser by Ferd Frederix
-// (LoL) Yea, that s a Bunch O Peeps =)
-
-//Summary: The following script will make an object accept donations on your behalf.
-//Usage: stick it on any object you own(my favorite is a top hat), and it will promptly display:
-//"<your name>'s donation hat.
-//Donate if you are so inclined."
-//at which point anyone can right click on it and give you a tip. also, the script tells the donator thanks, and then tells you who donated how much
-//also shows the total amount donated
-
-
-
-integer totaldonated = 103793;
-string owner;
-
-default
-{
-    on_rez( integer sparam )
-    {
-        llResetScript();
-    }
-    state_entry()
-    {
-        llSetPayPrice(PAY_HIDE, [50 ,100, 200, 500]);
-        owner = llKey2Name( llGetOwner() );
-        llSetText( owner + "'s Tip Jar.\nRelease the butterflies!",<.25,1,.65>,1);
-    }
-
-    money(key id, integer amount)
-    {
-            
-        totaldonated += amount;
-        string name= llKey2Name(id);
-        llSetText( owner + "'s Tip Jar.\nRelease the butterflies!\n  \nLast Donor:\n " + name + " gave $L" + (string)amount ,<.25,1,.65>,1);
-        //llInstantMessage(id,"Thanks for the tip!  I really appreciate it. ~ Ferd Frederix");
-     
-        if (amount == 1)
-            llSay(0,"Uhh, thanks I think, " + name );
-        
-        if (amount > 0)
-            llSay(0,"Thanks for the tip, " + name +"! I really appreciate it. ~ Ferd Frederix");
-        else if (amount > 100)
-            llSay(0,"Thanks for the awesome tip, " + name +"!  I  appreciate it. ~ Ferd Frederix");
-        else if (amount > 300)
-            llSay(0,"Thanks for the AWESOME tip, " + name +"!  I really appreciate it. ~ Ferd Frederix");
-                
-        llInstantMessage(llGetOwner(),(string)llKey2Name(id)+" donated $" + (string)amount);
-        
-        llMessageLinked(LINK_ALL_OTHERS, 0, "touched", "");
-        llPlaySound("pop",1.0);
-        llSetAlpha(0,ALL_SIDES);   
-        llSetTimerEvent(10.0);
-        llEmail("fred@mitsi.com",(string)llKey2Name(id)+" donated $" + (string)amount,"");
-    }
-    touch_start(integer total_number)
-    {
-        llWhisper(0,"Butterfly Tip Jar for 'Phase Demesnes', total donated so far: " + (string) totaldonated );  
-    }
-    
-    timer()
-    {
-        llSetAlpha(0.1,ALL_SIDES);  
-        llSetTimerEvent(0.0); 
-    }
-}     
\ No newline at end of file
diff --git a/Phaze TipJar/Phaze TipJar/Top Half sphere/pop b/Phaze TipJar/Phaze TipJar/Top Half sphere/pop
deleted file mode 100644
index e69de29b..00000000
diff --git a/Security Orb/Security Orb/Orb/html/default.htm b/Security Orb/Security Orb/Orb/html/default.htm
index a7120ce4..e8e03115 100644
--- a/Security Orb/Security Orb/Orb/html/default.htm	
+++ b/Security Orb/Security Orb/Orb/html/default.htm	
@@ -26,7 +26,7 @@
 <h1>Home Security Prim Documentation</h1>
 <h2><span editable="true" id="PageTitle">Index</span></h2>
 <h3><span editable="true" id="SectionTitle1">Chapters</span></h3>
-<!--center><img src="http://www.outworldz.com/images/warn40px.png" align="middle"> <a href="/mediaprivacy"><font color="red">Important message about Second Life Shared Media security risks.</font></a></center-->
+<!--center><img src="/images/warn40px.png" align="middle"> <a href="/mediaprivacy"><font color="red">Important message about Second Life Shared Media security risks.</font></a></center-->
 <ul>
   <li style="text-align: left;"><a href="what.html">What does it do?</a></li>
 
diff --git a/Synced Pose balls/Synced Pose balls.sol b/Synced Pose balls/Synced Pose balls.sol
deleted file mode 100644
index 0349b64b..00000000
--- a/Synced Pose balls/Synced Pose balls.sol	
+++ /dev/null
@@ -1,3 +0,0 @@
-<Solution name="Synced Pose balls">
-	<Project name="Synced Pose balls" path="Synced Pose balls\Synced Pose balls.prj" active="true"/>
-</Solution>
diff --git a/Synced Pose balls/Synced Pose balls/Poseball1/Animation.ani b/Synced Pose balls/Synced Pose balls/Poseball1/Animation.ani
deleted file mode 100644
index e69de29b..00000000
diff --git a/Synced Pose balls/Synced Pose balls/Poseball1/Animation2.ani b/Synced Pose balls/Synced Pose balls/Poseball1/Animation2.ani
deleted file mode 100644
index e69de29b..00000000
diff --git a/Synced Pose balls/Synced Pose balls/Poseball1/Script.lsl b/Synced Pose balls/Synced Pose balls/Poseball1/Script.lsl
deleted file mode 100644
index aaf9a1c5..00000000
--- a/Synced Pose balls/Synced Pose balls/Poseball1/Script.lsl	
+++ /dev/null
@@ -1,89 +0,0 @@
-//:AUTHOR: Ferd Frederix
-//:DESCRIPTION: Two Or more people sit on two or more pose balls.  The pose balls play a series of animation in sync
-//:CODE:
-// To use this, just put several dances in a prim and add this script.
-// Shift-copy the prim.  Anyone who touches it will dance in sync with anyone else who touches it.
-
-
-float RATE = 10.0;  // rate to play animations
-
-string lastDance;  // the last dance played on the slave script
-string animation ; // the currwent animation name we must play
-integer index;     // the num,ber of that animation found in inventory
-key avatarK;       // the key of tjhe seated avatar
-integer channel = -12134;    // some random number
-integer granted = FALSE;
-
-default
-{
-    state_entry()
-    {
-        llSetClickAction(CLICK_ACTION_SIT);
-        llListen(channel,"","","");
-    }
-
-    on_rez(integer p)
-    {
-        llResetScript();
-    }
-
-
-    changed (integer detected)
-    {
-        if (detected & CHANGED_LINK)
-        {
-            avatarK = llAvatarOnSitTarget();
-            if (avatarK != NULL_KEY)
-            {
-                index = 0;
-                llRequestPermissions(avatarK, PERMISSION_TRIGGER_ANIMATION);
-            } else {
-                granted = FALSE;
-                llSetTimerEvent(0);
-            }
-        }
-    
-    }
-
-
-    run_time_permissions(integer perm)
-    {
-        if (perm & PERMISSION_TRIGGER_ANIMATION)
-        {
-            granted = TRUE;
-            animation = llGetInventoryName(INVENTORY_ANIMATION, index);    // first animation
-            llSay(channel,animation); // tell another poseball to let them dance.
-            llStartAnimation(animation);
-            llSetTimerEvent(RATE);
-        }
-    }
-
-    timer()
-    {
-        integer newindex = index;     // We must stop old animation
-        newindex++;                    // and play new one
-
-        // test to see if we are past the end
-        if (newindex >= llGetInventoryNumber(INVENTORY_ANIMATION))
-            newindex = 0;
-
-        llSay(channel,llGetInventoryName(INVENTORY_ANIMATION, newindex)); // tell another poseball to let them dance.
-        llStartAnimation(llGetInventoryName(INVENTORY_ANIMATION, newindex));
-        llStopAnimation(llGetInventoryName(INVENTORY_ANIMATION, index));
-        
-        index = newindex; // get ready for the next animation
-    }
-
-    listen(integer channel, string name, key id, string message) 
-    {
-        llSetTimerEvent(0);        // last one to send a message wins control
-        
-        if (granted)
-        {
-            llStartAnimation(message);
-            if (llStringLength(lastDance))
-                llStopAnimation(lastDance);
-            lastDance = message;
-        }
-    }
-}
diff --git a/Synced Pose balls/Synced Pose balls/Synced Pose balls.prj b/Synced Pose balls/Synced Pose balls/Synced Pose balls.prj
deleted file mode 100644
index 129c400f..00000000
--- a/Synced Pose balls/Synced Pose balls/Synced Pose balls.prj	
+++ /dev/null
@@ -1,10 +0,0 @@
-<Project name="Synced Pose balls" guid="c2feccdf-1f0e-4cf5-adfb-832e917d81d0">
-	<Object name="Poseball1" guid="6ea403c0-3678-43b6-9f73-c96eccbe6cda" active="true">
-		<Animation name="Animation.ani" guid="fb23999c-ea78-4011-9712-9cd225b7488b">
-		</Animation>
-		<Animation name="Animation2.ani" guid="2d4132a9-c6ac-497d-bafc-3f620746db17">
-		</Animation>
-		<Script name="Script.lsl" guid="6b443a7a-d27a-4773-82d8-010adca31758">
-		</Script>
-	</Object>
-</Project>
diff --git a/ThingSpeak Chart/Opensim - ThingSpeak.url b/ThingSpeak Chart/Opensim - ThingSpeak.url
deleted file mode 100644
index e5b381dd..00000000
--- a/ThingSpeak Chart/Opensim - ThingSpeak.url	
+++ /dev/null
@@ -1,2 +0,0 @@
-[InternetShortcut]
-URL=https://thingspeak.com/channels/47964
diff --git a/ThingSpeak Chart/ThingSpeak Chart.sol b/ThingSpeak Chart/ThingSpeak Chart.sol
deleted file mode 100644
index ba340ea4..00000000
--- a/ThingSpeak Chart/ThingSpeak Chart.sol	
+++ /dev/null
@@ -1,3 +0,0 @@
-<Solution name="ThingSpeak Chart">
-	<Project name="ThingSpeak Chart" path="ThingSpeak Chart\ThingSpeak Chart.prj" active="true"/>
-</Solution>
diff --git a/ThingSpeak Chart/ThingSpeak Chart/ThingSpeak Chart.prj b/ThingSpeak Chart/ThingSpeak Chart/ThingSpeak Chart.prj
deleted file mode 100644
index f31466bd..00000000
--- a/ThingSpeak Chart/ThingSpeak Chart/ThingSpeak Chart.prj	
+++ /dev/null
@@ -1,6 +0,0 @@
-<Project name="ThingSpeak Chart" guid="7baf63b5-8d5e-4185-9a19-f63fa9137e66">
-	<Object name="Web Chart Sender" guid="55798561-38d6-4ad2-91fc-d8ea5997ad19" active="true">
-		<Script name="Script.lsl" guid="255edfda-df79-4ddd-aa76-c67ed1b0859d">
-		</Script>
-	</Object>
-</Project>
diff --git a/ThingSpeak Chart/ThingSpeak Chart/Web Chart Sender/Script.lsl b/ThingSpeak Chart/ThingSpeak Chart/Web Chart Sender/Script.lsl
deleted file mode 100644
index 0e81cc32..00000000
--- a/ThingSpeak Chart/ThingSpeak Chart/Web Chart Sender/Script.lsl	
+++ /dev/null
@@ -1,131 +0,0 @@
-
-integer osIsNpc(key UUID) { return 0; }
-
-
-string wAPIKey = "419JVLGPPTCM5TZ1";
-
-string ChannelID = "47964";
-string fieldID = "field1";
-
-list exclude = [];
-// You can add a list of name of people to exclude, such as your name.
-// list exclude = ["Nara Malone","Ferd Frederix"];
-
-integer debug = FALSE;
-integer hovertext = TRUE;    // shows visitor count, or not
-integer ToDo;
-integer timeGoneBy = 0;
-
-DEBUG(string msg)
-{
-    if (debug ) llOwnerSay(msg);
-}
-
-key http_request_id;
-list ToDoURL;
-
-default
-{
-
-    state_entry()
-    {
-        llSetText("", <1,1,1>, 1);
-
-        string url = "https://api.thingspeak.com/update?api_key="
-                                + wAPIKey
-                                + "&"
-                                + "title"
-                                + "="
-                                + "Visitors";
-                            
-        http_request_id = llHTTPRequest(llList2String(ToDoURL,0), [], "");
-        llSetTimerEvent(1);
-    }
-    
-    timer()
-    {
-        if (ToDo == 0 &&  timeGoneBy )
-        {
-            DEBUG((string) timeGoneBy);
-            timeGoneBy--;
-            return;
-        }
-
-        if (ToDo == 0 &&  !timeGoneBy )
-        {
-            timeGoneBy = 60;
-            
-            ToDoURL = [];
-            
-            list keys = llGetAgentList(AGENT_LIST_REGION,[]);
-            
-            integer i;
-            for (i=0; i < llGetListLength(keys); ++i)
-            {
-                key UUID = llList2Key(keys,i);
-                if (!osIsNpc(UUID)) {
-                    string name = llKey2Name(UUID);    // name
-                    DEBUG("Checking " + name);
-
-                    if (hovertext)    llSetText(name, <1,1,1>, 1);
-                    if (llListFindList(exclude,[name]) == -1)
-                    {
-                        list details = llGetObjectDetails(UUID, [OBJECT_POS]) ; // pos
-                        vector pos = llList2Vector(details,0);
-                        string x = (string) pos.x;
-                        string y = (string) pos.y;
-                        string z = (string) pos.z;
-
-                        // parcel
-                        details = llGetParcelDetails(pos,[PARCEL_DETAILS_NAME]);
-                        string parcel = llList2String(details,0); 
- 
-                        string url = "https://api.thingspeak.com/update?api_key=" + wAPIKey
-                                + "&field1=" + x;
-                                + "&field2=" + y;
-
-                        DEBUG(url);
-                        ToDoURL += url;
-                    }
-                }
-            }
-            ToDo = 1;   // send them
-        }
-        else if (ToDo == 1)
-        {
-            if (llGetListLength(ToDoURL) == 0)
-            {
-                ToDo = 0;
-                return;
-            }
-
-            DEBUG(llList2String(ToDoURL,0));
-            http_request_id = llHTTPRequest(llList2String(ToDoURL,0), [], "");
-
-            ToDoURL  = llDeleteSubList(ToDoURL,0,0);
-        }
-    }
-
-    http_response(key request_id, integer status, list metadata, string body)
-    {
-        if (request_id == http_request_id)
-        {
-            if (hovertext)
-                llSetText("Click for Stats", <0,0,1>, 1);
-            
-            DEBUG(body);
-        }
-    }
-
-    touch_start(integer p)
-    {
-        if (llDetectedKey(0) == llGetOwner())
-        {
-            llLoadURL(llGetOwner(), "Click to view vistors", "https://thingspeak.com/channels/"
-                + ChannelID
-                + "/"
-                + fieldID);
-        }
-    }
-
-}
\ No newline at end of file
diff --git a/XS Pet Robot/XS Robot/Server/Breeds b/XS Pet Robot/XS Robot/Server/Breeds
index d2cdae25..4f649a2a 100644
--- a/XS Pet Robot/XS Robot/Server/Breeds	
+++ b/XS Pet Robot/XS Robot/Server/Breeds	
@@ -11,7 +11,6 @@
 // :DESCRIPTION:
 // A list of breed names notecard.  Use one line per breed name.  The lines that begin with // are ignored.
 // :CODE:
-
 // could be anything, such as 
 // Fat Yellow Chicken
 // Scrawny Red Chicken