Miko/LSL-Scripts
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

removed useless _ folders

Browse Source
This commit is contained in:
Fred Beckhusen
2015-08-09 16:54:31 -05:00
parent fde850293c
commit 948a44dfba
5204 changed files with 2425579 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

80
TransmogrifyAvatar/Transmogrify/Object/Accessories.lsl Normal file
View File

@@ -0,0 +1,80 @@
// :CATEGORY:Transmogrify
// :NAME:TransmogrifyAvatar
// :AUTHOR:Ferd Frederix
// :CREATED:2013-09-08
// :EDITED:2014-01-01 12:18:57
// :ID:921
// :NUM:1321
// :REV:1
// :WORLD:Second Life
// :DESCRIPTION:
// for anything you wear
// :CODE:
// Transmogrifyer script
// License: CC-BY. Please do not remove the copyright or this notice
// Author: Ferd Frederix
// For all your worn accessories (not the pet)
// makes accessories like shoes and hair disappear when you fly.
integer ownerchannel;
integer listener;
setlisten()
{
if (listener) {
llListenRemove(listener);
}
listener = llListen(ownerchannel,"","","");
}
hide_show( float alpha)
{
integer j = llGetNumberOfPrims();
integer k = 2; // do it twice to get rid of lost packets
while (k--)
{
integer i;
for ( i = 0; i <= j; i++) {
llSetLinkAlpha(i,alpha, ALL_SIDES);
}
}
}
default
{
state_entry()
{
ownerchannel = (integer)("0xF" + llGetSubString( (string)llGetOwner(), 0, 6 ));
hide_show(0); // 0 = invisible
setlisten();
}
on_rez(integer param)
{
hide_show(1); // 1= visible
setlisten();
}
changed(integer what)
{
// no reset needed, we just need to re-establish a listener
if (what & CHANGED_REGION)
setlisten();
if(what & CHANGED_OWNER)
llResetScript();
}
listen(integer channel, string name, key id, string msg)
{
if (msg == "pet") {
hide_show(0);
} else if (msg == "avatar") {
hide_show(1);
}
}
}

87
TransmogrifyAvatar/Transmogrify/Object/Controller.lsl Normal file
View File

@@ -0,0 +1,87 @@
// :CATEGORY:Transmogrify
// :NAME:TransmogrifyAvatar
// :AUTHOR:Ferd Frederix
// :KEYWORDS:
// :CREATED:2013-09-08
// :EDITED:2014-09-24
// :ID:921
// :NUM:1323
// :REV:1.1
// :WORLD:Second Life
// :DESCRIPTION:
// FOr the head of the avatar
// :CODE:
// Transmogrifyer script
// License: CC-BY. Please do not remove the copyright or this notice
// Author: Ferd Frederix
// 8-25-2013
// Controller goes in the root prim of the body.
// V 1.1 Edited on 9/22/2014 to fix "in air" bug to be "Flying"
integer type = -1;
integer ownerchannel;
integer person = TRUE;
hide_show( float alpha)
{
integer j = llGetNumberOfPrims();
integer k = 2; // do it twice to get rid of lost packets
while (k--)
{
integer i;
for ( i = 0; i <= j; i++) {
llSetLinkAlpha(i,alpha, ALL_SIDES);
}
}
}
// flop and send a link message for particle effects
switch(string what)
{
if (what == "avatar" && ! person)
{
llMessageLinked(LINK_SET,0,"switch","");
llSay(ownerchannel,"avatar");
person = TRUE;
hide_show(1.0); // invisible
}
else if (what == "pet" && person)
{
llMessageLinked(LINK_SET,0,"switch","");
llSay(ownerchannel,"pet");
person = FALSE;
hide_show(0.0);
}
}
default
{
on_rez(integer p)
{
llResetScript(); // so we can change owner
}
state_entry()
{
// Make this prim an invisiprim.
ownerchannel = (integer)("0xF" + llGetSubString( (string)llGetOwner(), 0, 6 ));
hide_show(1.0);
llSetTimerEvent(0.5);
}
timer()
{
integer flight = llGetAgentInfo(llGetOwner());
if (flight & AGENT_FLYING) // V 1.1
{
switch("pet");
}
else
{
switch("avatar");
}
}
}

143
TransmogrifyAvatar/Transmogrify/Object/Particles.lsl Normal file
View File

@@ -0,0 +1,143 @@
// :CATEGORY:Transmogrify
// :NAME:TransmogrifyAvatar
// :AUTHOR:Ferd Frederix
// :CREATED:2013-09-08
// :EDITED:2014-01-01 12:18:57
// :ID:921
// :NUM:1324
// :REV:1
// :WORLD:Second Life
// :DESCRIPTION:
// makes a flash of smoke when you transmogrify
// :CODE:
// Transmogrifyer script
// License: CC-BY. Please do not remove the copyright or this notice
// Author: Ferd Frederix
// Particles is a poofer effect for changing. Put it in the head, body and feet section of the avatar and in the pet.
// Easy to change the colors, or add a texture.
// Sends a RED flash of 400 particles for 1 second.
// If you add a texture to it, put the same texture on the side of a small box inside your pet so it will be cached and appear instantly.
// MASK FLAGS: set to "TRUE" to enable
integer glow = TRUE; // Makes the particles glow
integer bounce = FALSE; // Make particles bounce on Z plane of objects
integer interpColor = TRUE; // Color - from start value to end value
integer interpSize = TRUE; // Size - from start value to end value
integer wind = FALSE; // Particles effected by wind
integer followSource = FALSE; // Particles follow the source
integer followVel = TRUE; // Particles turn to velocity direction
// Choose a pattern from the following:
// PSYS_SRC_PATTERN_EXPLODE
// PSYS_SRC_PATTERN_DROP
// PSYS_SRC_PATTERN_ANGLE_CONE_EMPTY
// PSYS_SRC_PATTERN_ANGLE_CONE
// PSYS_SRC_PATTERN_ANGLE
// PSYS_SRC_PATTERN_EXPLODE;
integer pattern = PSYS_SRC_PATTERN_EXPLODE;
// Select a target for particles to go towards
// "" for no target, "owner" will follow object owner
// and "self" will target this object
// or put the key of an object for particles to go to
key target = ""; // if set to a UUID, such as llGetOwner(0), the particles go that-away
// PARTICLE PARAMETERS
float age = 0.1; // Life of each particle
float maxSpeed = 10.0; // Max speed each particle is spit out at
float minSpeed = 3; // Min speed each particle is spit out at
string texture = ""; // Texture used for particles, default used if blank
float startAlpha = 0.5; // Start alpha (transparency) value
float endAlpha = 0.5; // End alpha (transparency) value
vector startColor = <0,0,1>; // Start color of particles <R,G,B>
vector endColor = <0,0,1>; // End color of particles <R,G,B> (if interpColor == TRUE)
vector startSize = <1.0,2.0,1.0>; // Start size of particles
vector endSize = <1,2,1.0>; // End size of particles (if interpSize == TRUE)
vector push = <0.0,0.0,0.0>; // Force pushed on particles
// SYSTEM PARAMETERS
float rate = 0.1; // How fast (rate) to emit particles
float life = 1.0; // Life in seconds for the system to make particles
integer count = 40; // How many particles to emit per BURST
// life (1) / age (.1) * count (4) = 400 particles, about 10% of what anyone can see
float radius = 0.25; // Radius to emit particles for BURST pattern, helps cover up the avatar
float outerAngle = TWO_PI; // Outer angle for all ANGLE patterns, TWO_PI is a full sphere
float innerAngle = 0.5; // Inner angle for all ANGLE patterns
vector omega = <0,0,0>; // Rotation of ANGLE patterns around the source
// SCRIPT VARIABLES
integer flags;
// nothing to see here. Go play somewhere else
StartSteam()
{
flags = 0;
if (glow) flags = flags | PSYS_PART_EMISSIVE_MASK;
if (bounce) flags = flags | PSYS_PART_BOUNCE_MASK;
if (interpColor) flags = flags | PSYS_PART_INTERP_COLOR_MASK;
if (interpSize) flags = flags | PSYS_PART_INTERP_SCALE_MASK;
if (wind) flags = flags | PSYS_PART_WIND_MASK;
if (followSource) flags = flags | PSYS_PART_FOLLOW_SRC_MASK;
if (followVel) flags = flags | PSYS_PART_FOLLOW_VELOCITY_MASK;
if (target != "") flags = flags | PSYS_PART_TARGET_POS_MASK;
llParticleSystem([ PSYS_PART_MAX_AGE,age,
PSYS_PART_FLAGS,flags,
PSYS_PART_START_COLOR, startColor,
PSYS_PART_END_COLOR, endColor,
PSYS_PART_START_SCALE,startSize,
PSYS_PART_END_SCALE,endSize,
PSYS_SRC_PATTERN, pattern,
PSYS_SRC_BURST_RATE,rate,
PSYS_SRC_ACCEL, push,
PSYS_SRC_BURST_PART_COUNT,count,
PSYS_SRC_BURST_RADIUS,radius,
PSYS_SRC_BURST_SPEED_MIN,minSpeed,
PSYS_SRC_BURST_SPEED_MAX,maxSpeed,
PSYS_SRC_TARGET_KEY,target,
PSYS_SRC_INNERANGLE,innerAngle,
PSYS_SRC_OUTERANGLE,outerAngle,
PSYS_SRC_OMEGA, omega,
PSYS_SRC_MAX_AGE, life,
PSYS_SRC_TEXTURE, texture,
PSYS_PART_START_ALPHA, startAlpha,
PSYS_PART_END_ALPHA, endAlpha
]);
}
default
{
state_entry()
{
StartSteam(); // show the flash when it resets
}
link_message(integer sender_number, integer number, string message, key id)
{
if (message == "switch")
{
StartSteam();
}
}
}

76
TransmogrifyAvatar/Transmogrify/Object/Pet.lsl Normal file
View File

@@ -0,0 +1,76 @@
// :CATEGORY:Transmogrify
// :NAME:TransmogrifyAvatar
// :AUTHOR:Ferd Frederix
// :CREATED:2013-09-08
// :EDITED:2014-01-01 12:18:57
// :ID:921
// :NUM:1325
// :REV:1
// :WORLD:Second Life
// :DESCRIPTION:
// For any attached pet that is to appear when you Transmogrify
// :CODE:
// Transmogrifyer script
// License: CC-BY. Please do not remove the copyright or this notice
// Author: Ferd Frederix
// For your pet
// makes the pet appear when you fly
integer ownerchannel;
integer listener;
setlisten()
{
if (listener) {
llListenRemove(listener);
}
listener = llListen(ownerchannel,"","","");
}
hide_show( float alpha)
{
integer j = llGetNumberOfPrims();
integer i;
for ( i = 0; i <= j; i++) {
llSetLinkAlpha(i,alpha,ALL_SIDES);
}
}
default
{
state_entry()
{
ownerchannel = (integer)("0xF" + llGetSubString( (string)llGetOwner(), 0, 6 ));
hide_show(1); // 1 = visible
setlisten();
}
on_rez(integer param)
{
hide_show(0); // 0= invisible
setlisten();
}
changed(integer what)
{
if (what & CHANGED_REGION)
setlisten();
if(what & CHANGED_OWNER)
llResetScript();
}
listen(integer channel, string name, key id, string msg)
{
if (msg == "pet") {
hide_show(1);
} else if (msg == "avatar") {
hide_show(0);
}
}
}

80
TransmogrifyAvatar/Transmogrify/Object/anti-no-script.lsl Normal file
View File

@@ -0,0 +1,80 @@
// :CATEGORY:Transmogrify
// :NAME:TransmogrifyAvatar
// :AUTHOR:Ferd Frederix
// :CREATED:2013-09-08
// :EDITED:2014-01-01 12:18:57
// :ID:921
// :NUM:1322
// :REV:1
// :WORLD:Second Life
// :DESCRIPTION:
// for any prim so it works in no script zones
// :CODE:
// Script Name: Anti_no-script_script.lsl
// Author: Ferd Frederix
// Lets any attachment with scripts work in a no-script zone.
// Downloaded from : http://www.outworldz.com/cgi/freescripts.plx?ID=1644
// This program is free software; you can redistribute it and/or modify it.
// Additional Licenes may apply that prevent you from selling this code
// You must leave any author credits and any headers intact in any script you use or publish.
///////////////////////////////////////////////////////////////////////////////////////////////////
// If you don't like these restrictions and licenses, then don't use these scripts.
//////////////////////// ORIGINAL AUTHORS CODE BEGINS ////////////////////////////////////////////
// The Script
//
//
// ______ _ ______ _ _
// | ___| | | | ___| | | (_)
// | |_ ___ _ __ __| | | |_ _ __ ___ __| | ___ _ __ ___ __
// | _/ _ \ '__/ _` | | _| '__/ _ \/ _` |/ _ \ '__| \ \/ /
// | || __/ | | (_| | | | | | | __/ (_| | __/ | | |> <
// \_| \___|_| \__,_| \_| |_| \___|\__,_|\___|_| |_/_/\_\
//
// fred@mitsi.com
// author Ferd Frederix
//
// anti-no-script script
// makes attached prims into a vehicle so they work in no-script zones.
// If you attach the prim while in a no-script zone, it won't work. Fly up 50 meters or so and it will start.
// Works only when in the root prim.
default
{
state_entry()
{
llReleaseControls();
llRequestPermissions(llGetOwner(),PERMISSION_TAKE_CONTROLS );
}
run_time_permissions(integer perm)
{
integer hasPerms = llGetPermissions();
llTakeControls( 0 , FALSE, TRUE);
}
attach(key id)
{
if(id)//tests if it is a valid key and not NULL_KEY
{
llRequestPermissions(llGetOwner(),PERMISSION_TAKE_CONTROLS );
}
else
{
llReleaseControls(); // detached
}
}
}